2

让 Mathematica 7 或 8 进行积分的最佳方法是什么

NIntegrate[Exp[-x]/Sin[Pi x], {x, 0, 50}]

每个整数都有极点——我们想要柯西原理值。这个想法是为从 0 到无穷大的积分获得一个很好的近似值。

有Integrate选项PrincipleValue -> True。

有了NIntegrate我可以给它选项Exclusions -> (Sin[Pi x] == 0)，或者手动给它杆子

NIntegrate[Exp[-x]/Sin[Pi x], Evaluate[{x, 0, Sequence@@Range[50], 50}]]

原始命令和以上两个NIntegrate技巧给出了结果60980 +/- 10。但他们都吐出错误。在 Mathematica 不想给出错误的情况下，获得快速可靠结果的最佳方法是什么？

4

3 回答 3

7

西蒙，有理由相信你的积分是收敛的吗？

In[52]:= f[k_Integer, eps_Real] := 
 NIntegrate[Exp[-x]/Sin[Pi x], {x, k + eps, k + 1 - eps}]

In[53]:= Sum[f[k, 1.0*10^-4], {k, 0, 50}]

Out[53]= 2.72613

In[54]:= Sum[f[k, 1.0*10^-5], {k, 0, 50}]

Out[54]= 3.45906

In[55]:= Sum[f[k, 1.0*10^-6], {k, 0, 50}]

Out[55]= 4.19199

看起来问题出在 x==0 处。对于 k 的整数值，将被积函数 k+eps 拆分为 k+1-eps：

In[65]:= int = 
 Sum[(-1)^k Exp[-k ], {k, 0, Infinity}] Integrate[
   Exp[-x]/Sin[Pi x], {x, eps, 1 - eps}, Assumptions -> 0 < eps < 1/2]

Out[65]= (1/((1 + 
   E) (I + \[Pi])))E (2 E^(-1 + eps - I eps \[Pi])
     Hypergeometric2F1[1, (I + \[Pi])/(2 \[Pi]), 3/2 + I/(2 \[Pi]), 
     E^(-2 I eps \[Pi])] + 
   2 E^(I eps (I + \[Pi]))
     Hypergeometric2F1[1, (I + \[Pi])/(2 \[Pi]), 3/2 + I/(2 \[Pi]), 
     E^(2 I eps \[Pi])])

In[73]:= N[int /. eps -> 10^-6, 20]

Out[73]= 4.1919897038160855098 + 0.*10^-20 I

In[74]:= N[int /. eps -> 10^-4, 20]

Out[74]= 2.7261330651934049862 + 0.*10^-20 I

In[75]:= N[int /. eps -> 10^-5, 20]

Out[75]= 3.4590554287709991277 + 0.*10^-20 I

如您所见，存在对数奇点。

In[79]:= ser = 
 Assuming[0 < eps < 1/32, FullSimplify[Series[int, {eps, 0, 1}]]]

Out[79]= SeriesData[eps, 0, {(I*(-1 + E)*Pi - 
     2*(1 + E)*HarmonicNumber[-(-I + Pi)/(2*Pi)] + 
          Log[1/(4*eps^2*Pi^2)] - 2*E*Log[2*eps*Pi])/(2*(1 + E)*Pi), 
     (-1 + E)/((1 + E)*Pi)}, 0, 2, 1]

In[80]:= Normal[
  ser] /. {{eps -> 1.*^-6}, {eps -> 0.00001}, {eps -> 0.0001}}

Out[80]= {4.191989703816426 - 7.603403526913691*^-17*I, 
 3.459055428805136 - 
     7.603403526913691*^-17*I, 
 2.726133068607085 - 7.603403526913691*^-17*I}

上面代码的EDIT Out[79] 给出了 eps->0 的级数展开式，如果这两个对数项结合起来，我们得到

In[7]:= ser = SeriesData[eps, 0, 
       {(I*(-1 + E)*Pi - 2*(1 + E)*HarmonicNumber[-(-I + Pi)/(2*Pi)] + 
              Log[1/(4*eps^2*Pi^2)] - 2*E*Log[2*eps*Pi])/(2*(1 + E)*
       Pi), 
         (-1 + E)/((1 + E)*Pi)}, 0, 2, 1]; 

In[8]:= Collect[Normal[PowerExpand //@ (ser + O[eps])], 
 Log[eps], FullSimplify]

Out[8]= -(Log[eps]/\[Pi]) + (
 I (-1 + E) \[Pi] - 
  2 (1 + E) (HarmonicNumber[-((-I + \[Pi])/(2 \[Pi]))] + 
     Log[2 \[Pi]]))/(2 (1 + E) \[Pi])

显然，-Log[eps]/Pi 来自 x==0 处的极点。因此，如果减去此值，就像原则值方法对其他极点执行此操作一样，您最终会得到一个有限值：

In[9]:= % /. Log[eps] -> 0

Out[9]= (I (-1 + E) \[Pi] - 
 2 (1 + E) (HarmonicNumber[-((-I + \[Pi])/(2 \[Pi]))] + 
    Log[2 \[Pi]]))/(2 (1 + E) \[Pi])

In[10]:= N[%, 20]

Out[10]= -0.20562403655659928968 + 0.*10^-21 I

当然，这个结果很难用数字来验证，但你可能知道我对你的问题所做的更多。

编辑 2

此编辑是为了证明计算原始正则化积分的 In[65] 输入的合理性。我们在计算

Sum[ Integrate[ Exp[-x]/Sin[Pi*x], {x, k+eps, k+1-eps}], {k, 0, Infinity}] ==  
  Sum[ Integrate[ Exp[-x-k]/Sin[Pi*(k+x)], {x, eps, 1-eps}], {k, 0, Infinity}] ==
  Sum[ (-1)^k*Exp[-k]*Integrate[ Exp[-x]/Sin[Pi*x], {x, eps, 1-eps}], 
       {k, 0, Infinity}] == 
  Sum[ (-1)^k*Exp[-k], {k, 0, Infinity}] * 
     Integrate[ Exp[-x]/Sin[Pi*x], {x, eps, 1-eps}]

在第三行中，使用整数 k 的 Sin[Pi*(k+x)] == (-1)^k*Sin[Pi*x]。

于 2011-04-07T05:34:14.500 回答
4

西蒙，我没有花太多时间处理您的积分，但您应该尝试查看固定相近似。您所拥有的是一个平滑函数 (exp) 和一个高度振荡函数 (sine)。所涉及的工作现在正在敲打1/sin(x)形式exp(if(x))

或者，您可以使用cosecant（在极点处无效）的级数展开：

In[1]:=Series[Csc[x], {x, 0, 5}]
(formatted) Out[1]=1/x + x/6 + 7/360 x^3 + 31/15120 x^5 +O[x]^6

请注意，对于 all m>-1，您有以下内容：

In[2]:=Integrate[x^m Exp[-x], {x, 0, Infinity}, Assumptions -> m > -1]
Out[2]=Gamma[1+m]

但是，将系列与余割系数（来自维基百科）相加，不包括1/x Exp[-x]不收敛于[0,Infinity].

c[m_] := (-1)^(m + 1) 2 (2^(2 m - 1) - 1) BernoulliB[2 m]/Factorial[2 m];
Sum[c[m] Gamma[1 + 2 m - 1], {m, 1, Infinity}]

也不收敛……

因此，我不确定您是否可以计算出无穷大积分的近似值，但是如果您对某个大 N 的解决方案感到满意，我希望这些对您有所帮助。

于 2011-04-07T08:08:11.587 回答
4

我必须同意Sasha的观点，积分似乎并不收敛。但是，如果您将x == 0积分排除并分解成碎片

Integrate[Exp[-x]/Sin[Pi x], {x, n + 1/2, n + 3/2}, PrincipalValue -> True]

在哪里n >= 0 && Element[n, Integers]，那么您似乎可能会得到一个交替的系列

I Sum[ (-1/E)^n, {n, 1, Infinity}] == - I / (1 + E )

现在，我只把它拿出来n == 4，但它看起来很合理。然而，对于上述与Assumptions -> Element[n, Integers] && n >= 0Mathematica 的积分给出

If[ 2 n >= 1, - I / E, Integrate[ ... ] ]

这不符合个别情况。作为附加说明，如果极点位于积分区域的边界，即您的极限是{x, n, n + 1}，您只会得到DirectedInfinitys。快速查看该图意味着您在限制条件{x, n, n + 1}下只有一个严格的正或负被积函数，因此无限值可能是由于缺乏{x, n + 1/2, n + 3/2}给您的补偿。用 进行检查{x, n, n + 2}，但它只会吐出未评估的积分。

于 2011-04-07T16:29:39.997 回答