1

我已经看到了一些使用 Prolog 的 clfpd 库的 cyrptarithmetic 谜题求解器的例子。例如，如果我有一个谜题 AM + PM = DAY，它可以将不同的值集从 0 到 9 分配给不同的字母，这样 A*10+M + P*10+M = D*100+A*10+Y . 我正在尝试编写它的通用版本。请注意，我对 Prolog 或 clfpd 的经验都很少。

我打算根据输入生成约束。例如 A*10+M + P*10+M = D*100+A*10+Y 将根据输入拼图 1([A,M]+[P,M]=[D,A,Y ]）。但我不知道该怎么做。我编写了一个基于输入创建约束的 Prolog 函数（称为转换）。但它不工作，我不断收到错误 

clpfd_expression' expected, found `convert([_818,_894])

:- use_module(library(clpfd)).
%calculate correct multiplier
%For example if AM, multipler of A is 10 and of M is 1 
multiple(1,10). 
multiple(N,F) :-  
    N#>0, 
    N1 #= N-1, 
    multiple(N1,F1), 
    F #= 10 * F1.
%convert accepts input as a list. For instance [A,M]
%outputs a constraint of the form A*10 + M*1
convert([H|T], Ans):-
    length(T, Len),
    Len #= 0,
    Ans #= H * 1.

convert([H|T], Ans):-
    length([H|T], Len1),
    Len2 #= Len1-1,
    multiple(Len2,Multiplier),
    convert(T, Ans1),
    Ans #= Ans1 + H * Multiplier.

%add should imply constraint A*10+M+P*10+M=D*100+A*10+Y.
add(Exp1, Exp2, Exp3):-
    Exp1 + Exp2 #= Exp3.

puzzle1(As + Bs = Cs) :- 
   append([As,Bs,Cs],Ds),
   term_variables(Ds,Var),   %% this will get all Var
   Var ins 0..9, 
   all_different(Var), 
   Exp01 #= convert(As),
   Exp02 #= convert(Bs),
   Exp03 #= convert(Cs),
   add(Exp01, Exp02, Exp03),
   %add constraint first member of each list cant be asigned a value 0
   As #= [H1|_],
   Bs #= [H2|_],
   Cs #= [H3|_],
   H1 #\=0,
   H2 #\=0,
   H3 #\=0.

有人可以引导我走向正确的方向。

4

2 回答 2

2

您的代码中有两个错误。首先， convert/2 是一个带有两个参数的谓词——你不能将它用作函数。所以，而不是

Exp01 #= convert(As)

简单地写

convert(As, Exp01)

另一个错误是

As #= [H1|_]

在这里，您要在结构上分解列表As并提取其第一个元素。做到这一点的方法是简单的统一，即

As = [H1|_]

不同之处在于#=实现（整数）算术相等（意味着它将两边解释为算术表达式），而=纯符号操作，这就是你想要的。

您可以在http://eclipseclp.org/examples/cryptarith.ecl.txt找到与您类似的程序

于 2019-04-08T09:14:59.873 回答
0

工作代码：

:- use_module(library(clpfd)).
%calculate correct multiplier
%For example if AM, multipler of A is 10 and of M is 1 
multiple(1,10). 
multiple(N,F) :-  
    N>0, 
    N1 is N-1, 
    multiple(N1,F1), 
    F is 10 * F1.
%convert accepts input as a list. For instance [A,M]
%outputs a constraint of the form A*10 + M*1
convert([H|T], Ans):-
    length(T, Len),
    Len = 0,
    Ans = H * 1.
convert([H|T], Ans):-
    length([H|T], Len1),
    Len2 is Len1-1,
    multiple(Len2,Multiplier),
    convert(T, Ans1),
    Ans = Ans1 + H * Multiplier.


puzzle1(As + Bs = Cs) :- 
   append([As,Bs,Cs],Ds),
   term_variables(Ds,Var),   %% this will get all Var
   Var ins 0..9, 
   all_different(Var),
   convert(As, Ans1),
   convert(Bs, Ans2),
   convert(Cs, Ans3),
   %Generates a constraint depending on the input
   %For instance if input is puzzle1([A,M] + [P,M] = [D,A,Y])
   %Output constraint = A*10 + M + P*10 + M  = D*100 + A*10 + Y 
   Ans1 + Ans2 #= Ans3,
   As = [H1|_],
   Bs = [H2|_],
   H1 #\=0,
   H2 #\=0,
   label(Var),
   write("Solution: "),
   write(As + Bs = Cs).


%puzzle1([A,M]+[P,M]=[D,A,Y]).
%puzzle1([A,M]+[I]=[O,K]).
%puzzle1([Y,O,U]+[A,R,E]=[D,O,N,E]).
%puzzle1([S,E,N,D]+[M,O,R,E]=[M,O,N,E,Y]).
%puzzle1([R,O,A,D]+[I,N]=[U,S,A]).
%puzzle1([B,I,K,E]+[F,O,R]=[R,I,D,E]).
于 2019-04-08T17:54:32.657 回答