我是 Thrust 的新手。我看到所有 Thrust 演示文稿和示例仅显示主机代码。
我想知道是否可以将 device_vector 传递给我自己的内核？如何？如果是，内核/设备代码中允许的操作是什么？
问问题
20878 次
4 回答
54
正如最初编写的那样，Thrust 纯粹是一个主机端抽象。它不能在内核中使用。您可以将封装在 a 中的设备内存传递thrust::device_vector给您自己的内核，如下所示：
thrust::device_vector< Foo > fooVector;
// Do something thrust-y with fooVector
Foo* fooArray = thrust::raw_pointer_cast( fooVector.data() );
// Pass raw array and its size to kernel
someKernelCall<<< x, y >>>( fooArray, fooVector.size() );
并且您还可以通过使用裸 cuda 设备内存指针实例化推力::device_ptr 来使用推力算法中未由推力分配的设备内存。
四年半后编辑添加，根据@JackOLantern 的回答，推力 1.8 添加了顺序执行策略，这意味着您可以在设备上运行推力算法的单线程版本。请注意，仍然无法将推力设备向量直接传递给内核，并且设备向量不能直接在设备代码中使用。
请注意，thrust::device在某些情况下，也可以使用执行策略让内核作为子网格启动并行推力执行。这需要单独的编译/设备链接和支持动态并行的硬件。我不确定这是否实际上在所有推力算法中都受支持，但肯定适用于某些算法。
于 2011-04-01T09:03:35.303 回答
16
这是对我之前答案的更新。
从 Thrust 1.8.1 开始，CUDA Thrust 原语可以与执行策略相结合，利用 CUDA动态并行thrust::device性在单个 CUDA 线程中并行运行。下面，报告一个例子。
#include <stdio.h>
#include <thrust/reduce.h>
#include <thrust/execution_policy.h>
#include "TimingGPU.cuh"
#include "Utilities.cuh"
#define BLOCKSIZE_1D 256
#define BLOCKSIZE_2D_X 32
#define BLOCKSIZE_2D_Y 32
/*************************/
/* TEST KERNEL FUNCTIONS */
/*************************/
__global__ void test1(const float * __restrict__ d_data, float * __restrict__ d_results, const int Nrows, const int Ncols) {
const unsigned int tid = threadIdx.x + blockDim.x * blockIdx.x;
if (tid < Nrows) d_results[tid] = thrust::reduce(thrust::seq, d_data + tid * Ncols, d_data + (tid + 1) * Ncols);
}
__global__ void test2(const float * __restrict__ d_data, float * __restrict__ d_results, const int Nrows, const int Ncols) {
const unsigned int tid = threadIdx.x + blockDim.x * blockIdx.x;
if (tid < Nrows) d_results[tid] = thrust::reduce(thrust::device, d_data + tid * Ncols, d_data + (tid + 1) * Ncols);
}
/********/
/* MAIN */
/********/
int main() {
const int Nrows = 64;
const int Ncols = 2048;
gpuErrchk(cudaFree(0));
// size_t DevQueue;
// gpuErrchk(cudaDeviceGetLimit(&DevQueue, cudaLimitDevRuntimePendingLaunchCount));
// DevQueue *= 128;
// gpuErrchk(cudaDeviceSetLimit(cudaLimitDevRuntimePendingLaunchCount, DevQueue));
float *h_data = (float *)malloc(Nrows * Ncols * sizeof(float));
float *h_results = (float *)malloc(Nrows * sizeof(float));
float *h_results1 = (float *)malloc(Nrows * sizeof(float));
float *h_results2 = (float *)malloc(Nrows * sizeof(float));
float sum = 0.f;
for (int i=0; i<Nrows; i++) {
h_results[i] = 0.f;
for (int j=0; j<Ncols; j++) {
h_data[i*Ncols+j] = i;
h_results[i] = h_results[i] + h_data[i*Ncols+j];
}
}
TimingGPU timerGPU;
float *d_data; gpuErrchk(cudaMalloc((void**)&d_data, Nrows * Ncols * sizeof(float)));
float *d_results1; gpuErrchk(cudaMalloc((void**)&d_results1, Nrows * sizeof(float)));
float *d_results2; gpuErrchk(cudaMalloc((void**)&d_results2, Nrows * sizeof(float)));
gpuErrchk(cudaMemcpy(d_data, h_data, Nrows * Ncols * sizeof(float), cudaMemcpyHostToDevice));
timerGPU.StartCounter();
test1<<<iDivUp(Nrows, BLOCKSIZE_1D), BLOCKSIZE_1D>>>(d_data, d_results1, Nrows, Ncols);
gpuErrchk(cudaPeekAtLastError());
gpuErrchk(cudaDeviceSynchronize());
printf("Timing approach nr. 1 = %f\n", timerGPU.GetCounter());
gpuErrchk(cudaMemcpy(h_results1, d_results1, Nrows * sizeof(float), cudaMemcpyDeviceToHost));
for (int i=0; i<Nrows; i++) {
if (h_results1[i] != h_results[i]) {
printf("Approach nr. 1; Error at i = %i; h_results1 = %f; h_results = %f", i, h_results1[i], h_results[i]);
return 0;
}
}
timerGPU.StartCounter();
test2<<<iDivUp(Nrows, BLOCKSIZE_1D), BLOCKSIZE_1D>>>(d_data, d_results1, Nrows, Ncols);
gpuErrchk(cudaPeekAtLastError());
gpuErrchk(cudaDeviceSynchronize());
printf("Timing approach nr. 2 = %f\n", timerGPU.GetCounter());
gpuErrchk(cudaMemcpy(h_results1, d_results1, Nrows * sizeof(float), cudaMemcpyDeviceToHost));
for (int i=0; i<Nrows; i++) {
if (h_results1[i] != h_results[i]) {
printf("Approach nr. 2; Error at i = %i; h_results1 = %f; h_results = %f", i, h_results1[i], h_results[i]);
return 0;
}
}
printf("Test passed!\n");
}
上面的示例执行矩阵行的归约，其意义与使用 CUDA 的归约矩阵行相同，但它的完成方式与上述帖子不同，即直接从用户编写的内核调用 CUDA Thrust 原语。此外，上面的示例用于比较使用两个执行策略（即thrust::seq和）完成相同操作时的性能thrust::device。下面是一些显示性能差异的图表。
该性能已在 Kepler K20c 和 Maxwell GeForce GTX 850M 上进行了评估。
于 2015-07-24T07:17:04.473 回答
13
我想为这个问题提供一个更新的答案。
从 Thrust 1.8 开始，CUDA Thrust 原语可以与thrust::seq执行策略相结合，在单个 CUDA 线程中按顺序运行（或在单个 CPU 线程中按顺序运行）。下面，报告一个例子。
如果您想在线程内并行执行，那么您可以考虑使用CUB，它提供可以从线程块内调用的缩减例程，前提是您的卡启用动态并行性。
这是推力的例子
#include <stdio.h>
#include <thrust/reduce.h>
#include <thrust/execution_policy.h>
/********************/
/* CUDA ERROR CHECK */
/********************/
#define gpuErrchk(ans) { gpuAssert((ans), __FILE__, __LINE__); }
inline void gpuAssert(cudaError_t code, char *file, int line, bool abort=true)
{
if (code != cudaSuccess)
{
fprintf(stderr,"GPUassert: %s %s %d\n", cudaGetErrorString(code), file, line);
if (abort) exit(code);
}
}
__global__ void test(float *d_A, int N) {
float sum = thrust::reduce(thrust::seq, d_A, d_A + N);
printf("Device side result = %f\n", sum);
}
int main() {
const int N = 16;
float *h_A = (float*)malloc(N * sizeof(float));
float sum = 0.f;
for (int i=0; i<N; i++) {
h_A[i] = i;
sum = sum + h_A[i];
}
printf("Host side result = %f\n", sum);
float *d_A; gpuErrchk(cudaMalloc((void**)&d_A, N * sizeof(float)));
gpuErrchk(cudaMemcpy(d_A, h_A, N * sizeof(float), cudaMemcpyHostToDevice));
test<<<1,1>>>(d_A, N);
}
于 2014-11-06T16:29:20.983 回答
6
如果您打算使用推力分配/处理的数据，您可以，只需获取分配数据的原始指针。
int * raw_ptr = thrust::raw_pointer_cast(dev_ptr);
如果您想在内核中分配推力向量，我从未尝试过，但我认为它不会起作用，而且如果它起作用，我认为它不会提供任何好处。
于 2011-04-01T09:02:26.673 回答