3

从Think Julia一书中，我编写了以下代码来计算每个字母的单词数：

abc = "abcdef"
letter_count = 0
fin = open("words.txt")
for letter in abc
    for line in eachline(fin)
        if letter in line
            global letter_count += 1
        end
    end
    println("$letter has $letter_count")
    global letter_count = 0
end

但是，该代码仅计算字母“a”的出现次数。我不明白为什么这段代码会失败。

它返回：

56613 have a
0 have b
0 have c
0 have d
0 have e
0 have f
4

1 回答 1

5

你有错误的循环顺序（即外循环应该迭代字母）。你可以像这样修复它（我也稍微简化了代码）：

for letter in "abcdef"
    letter_count = count(x -> letter in x, eachline("words.txt"))
    println("$letter has $letter_count")
end

但是像这样迭代 words.txt 文件会更快：

let counts = zeros(Int, 6)
    for line in eachline("words.txt")
        for (i, letter) in enumerate("abcdef")
            counts[i] += letter in line
        end
    end
    counts
end

您还可以使用这样的广播来实现所需的结果（我报告它，因为我发现它是一个有趣的解决方案）：

julia> letters = "abcdef"
"abcdef"

julia> sum(in.(hcat(letters...), eachline("words.txt")), dims=1)
1×6 Array{Int64,2}:
 56613  16305  30466  30648  76168  11277

编辑：

eachline(fin)和之间的区别eachline("words.txt")如下：

  • eachline("words.txt")每次调用时都会打开（完成后关闭）一个新流；
  • eachline(fin)使用相同的流，这意味着在迭代的第一个循环完成后，我们处于流的末尾，并且没有任何内容可以读取。

eachline(fin)如果您在每次迭代后移动到流的开头，则可以保留该方法，如下所示：

abc = "abcdef"
letter_count = 0
fin = open("words.txt")
for letter in abc
    for line in eachline(fin)
        if letter in line
            global letter_count += 1
        end
    end
    println("$letter has $letter_count")
    global letter_count = 0
    seekstart(fin)
end
close(fin)

请注意，我在您的代码中添加了重要的一行（并且还添加了close(fin)因为您应该始终关闭打开的流）。但是，至少对我来说，这不是一个非常干净的方法，所以我一开始就不想推荐它。

于 2019-02-05T17:38:15.800 回答