-1

我正在创建一个小项目来打动我的朋友，并且很好奇如何仅使用一行来减慢程序上的文本流出速度。

我遇到了一个问题（相信我，我做了我的研究），并且很好奇如何降低批处理速度，而不做echo hi TIMEOUT 5>nul echo hi again等。但是，开始时只有一行，这会减慢整个批处理脚本的文本输出。谢谢！

4

1 回答 1

0

在批处理语言中执行此操作的唯一真正方法是使用call命令来调用函数并工作。这可以放在批处理文档的底部。

此外，由于您在这里的目标和阅读评论并不清楚，我将假设echo hi & TIMEOUT 5>nul echo hi again您希望在 5 秒后显示每一行，但仅从一行或命令。这可以通过call&FOR循环轻松完成。在这种情况下，我们可以使用%*收集所有您希望的内容。"Words Line One""Words Line Two"

将此与简单的语法替换相结合以删除引号，我们很好。

延迟线.bat

@echo off
@setlocal EnableDelayedExpansion

Rem | To use the command, Call :SlowOutput "Desired Line" "Desired Line" "Desired Line"

Call :SlowOutput "Line Number One" "Line Number Two" "Line Number Three"

pause>nul
Goto :EOF

:SlowOutput
for %%A in (%*) do (

    Set "String=%%A"
    Set String=!String:"=%!

    echo !String!

    Rem | Change 5 To How Many (Seconds) You Wish
    Timeout 5 /NoBreak>Nul
)
goto :EOF

如果您的目标是产生打字机效果，我们可以在此线程上使用hackoo的脚本并对其进行修改以在有组织的情况下使用。call

该脚本将逐个字母显示，并为每个call "Word" "Word"新报价换行。所有工作都通过一条线通过call

LetterDelay.bat

@echo off

Rem | To use the command, Call :SlowText "Desired Text"
Rem | To combine two "echo's" on one line we can use the "&"

Call :SlowText "Hello!" & Call :SlowText "How is your day today?"

pause>nul
Goto :EOF

:SlowText
(
echo strText=wscript.arguments(0^)
echo intTextLen = Len(strText^)

echo intPause = 100
echo For x = 1 to intTextLen
echo     strTempText = Mid(strText,x,1^)
echo     WScript.StdOut.Write strTempText
echo     WScript.Sleep intPause
echo Next

)>%tmp%\%~n0.vbs
@cScript.EXE /noLogo "%tmp%\%~n0.vbs" "%~1"

Rem | echo. is optional. It's used as a constant for a newline \n
echo.
goto :EOF

有关任何命令的帮助，请执行以下操作：

  • call /?
  • set /?
  • for /?
  • if /?
  • find /?
  • 很快。
于 2018-12-22T22:00:20.090 回答