3

是否可以制作 swfaddress 或任何脚本，以允许 flash 将浏览器中显示的 URL（实际上不切换到新页面）更改为我选择的任何内容？我意识到 swfaddress 使 url 总是引用原始 swf 文件，这很好，但我正在处理的 web 模板将始终加载 swf，无论您在网站上访问什么 URL。不同之处在于立即加载的内容。当您通过 flash 导航到不同的文章时，我希望能够将 URL 更改为文章的 URL，就好像它是一个 html 页面一样，因为我将匹配 html 内容以用于 SEO 目的。这将是一个大型网站，我想对其进行优化以实现共享和可搜索性。

例如，我想要一个 URL 为“site.com/2011/3/news-just-in”，而不是“site.com/#/news-just-in”。

这可能吗？

4

2 回答 2

5

您可以这样做，但只能在支持新HTML5 History API的浏览器中进行。您将需要使用ExternalInterface与 JavaScript 层合作。Flash 方面可能如下所示：

package {
  import flash.display.Sprite;
  import flash.events.MouseEvent;
  import flash.external.ExternalInterface;
  import flash.text.TextField;
  import flash.text.TextFieldAutoSize;

  public class Test extends Sprite {
    protected var _text:TextField;

    function Test() {
      var b:Sprite = new Sprite;
      b.graphics.beginFill(0xff0000);
      b.graphics.drawRect(0, 0, 32, 32);
      b.graphics.endFill();
      b.addEventListener(MouseEvent.MOUSE_DOWN, function(e:MouseEvent):void {
        pushState('/test/foo');
      });
      addChild(b);

      b = new Sprite;
      b.x = 64;
      b.graphics.beginFill(0x0000ff);
      b.graphics.drawRect(0, 0, 32, 32);
      b.graphics.endFill();
      b.addEventListener(MouseEvent.MOUSE_DOWN, function(e:MouseEvent):void {
        pushState('/test/bar');
      });
      addChild(b);

      _text = new TextField();
      _text.autoSize = TextFieldAutoSize.LEFT;
      _text.y = 64;
      addChild(_text);

      if (ExternalInterface.available) {
        ExternalInterface.addCallback('onPopState', onPopState);
        ExternalInterface.call('test.onReady');
      } else {
        _text.text = 'external interface not available';
      }
    }

    protected function onPopState(path:String):void {
      _text.appendText("flash onPopState: " + path + "\n");
    }

    protected function pushState(path:String):void {
      _text.appendText("flash pushState: " + path + "\n");
      ExternalInterface.call('history.pushState', null, null, path);
    }
  }
}

JavaScript 端可能如下所示：

<!DOCTYPE html>
<html>

<body>
  <script type="text/javascript">
  if (!!(window.history && history.pushState)) {
    var test = {
      onPopState: function(event) {
        if (this.embed) {
          this.embed.onPopState(location.pathname);
        }
      },

      onReady: function() {
        var embed = document.getElementById('flash');
        this.embed = embed.getElementsByTagName('object')[0] || embed;
        this.embed.onPopState(location.pathname);
      }
    };

    window.addEventListener('popstate', function(event) {
      test.onPopState(event);
    }, false);
  } else {
    alert('This browser does not support the history API');
  }
  </script>
  <object classid="clsid:D27CDB6E-AE6D-11cf-96B8-444553540000"
          id="flash" width="780" height="420">
    <param name="movie" value="test.swf" />
    <!--[if !IE]>-->
    <object type="application/x-shockwave-flash"
            data="test.swf" width="780" height="420">
    <!--<![endif]-->
      <p>Flash is required</p>
    <!--[if !IE]>-->
    </object>
    <!--<![endif]-->
  </object>
</body>

</html>

在本例中，onPopState每当路径更改时调用，并pushState调用以更改 URL。您可以单击示例中的红色和蓝色框来更改 Flash 中的 URL。

如果您想这样做并且必须支持较旧的浏览器，那么当不支持历史 API 时，您可能希望回退到哈希标签。理想情况下，您可以在 JS 层中对其进行抽象，这样 Flash 代码就不必知道正在使用哪个。我建议使用第三方库，例如History.js，因为它会为您处理哈希回退。

于 2011-03-15T05:03:10.537 回答
0

您可以将哈希标记更改为您想要的任何内容，但需要一个常量字符或字符串才能按预期工作：

/*
Provides the deep linking value without the query string.
*/
public static function getPath():String {
    var value:String = SWFAddress.getValue();
    if (value.indexOf('?') != -1) {
        return value.split('?')[0];
    } else if (value.indexOf('#') != -1) {
        return value.split('#')[0];
    } else {
        return value;
    }

您还必须更改SWFAddress.js和SWFAddressOptimizer.js中的所有“#”实例以匹配您的新字符或字符串值。

请记住，不鼓励更改此值，将其替换为简单值（如“3”）可能会导致问题。

于 2011-03-15T03:12:09.030 回答