6

在clojure中，我可以这样写：

(defn wrap-my-header
  [handler]
  (fn [request]
    (let [request (if (get-in request [:headers "my-header"])
                    (assoc request :has-my-header? true)
                    request)]
      (handler request))))

my-header在这个中间件中，我正在检查 in中是否有非零值:headers，如果是，我将在request地图中附加一些数据。这表明我可以将request和response视为有点“有状态”的数据。

我还是 haskell 的新手，想用scotty. 在查看了中间件的类型之后，我可以创建一个这样的中间件：

myMiddleware :: Middleware 
myMiddleware app req respond = app req respond

盯着类型看了半天，还是不知道该怎么做。一些阅读和思考使我认为这是不可能的，Middleware只能使处理程序短路和/或更改生成的响应。这是真的？

4

1 回答 1

5

这也让我困惑了很久！但是弄清楚它给了我一个有用的技术来理解 Haskell 库类型。

首先，我将从未定义的中间件开始：

myMiddleware :: Middleware
myMiddleware = undefined

那么是什么Middleware？关键是看类型的定义：

type Middleware = Application -> Application

让我们从第一层（或抽象层）开始，让中间件获取一个应用程序并返回一个应用程序。我们不知道如何修改应用程序，所以我们现在将准确返回传入的内容。

myMiddleware :: Application -> Application
myMiddleware theOriginalApp = theOriginalApp

但什么是应用程序？再次，让我们转向 Hackage：

type Application = Request -> (Response -> IO ResponseReceived) -> IO ResponseReceived

应用程序是一个函数！我们可能不确切知道每个部分应该做什么或应该是什么，但我们可以找出来。让我们用函数类型替换Application我们的类型签名：

myMiddleware :: (Request -> (Response -> IO ResponseReceived) -> IO ResponseReceived) 
             -> (Request -> (Response -> IO ResponseReceived) -> IO ResponseReceived)
myMiddleware theOriginalApp = theOriginalApp

现在我们可以看到这个类型应该允许我们访问一个Request! 但是我们如何使用它呢？

我们可以theOriginalApp在函数定义中扩展为与返回类型匹配的 lambda 表达式：

myMiddleware :: (Request -> (Response -> IO ResponseReceived) -> IO ResponseReceived) 
             -> (Request -> (Response -> IO ResponseReceived) -> IO ResponseReceived)
myMiddleware theOriginalApp = (\req sendResponse -> undefined)

我们现在可以对请求做任何我们想做的事情：

myMiddleware :: (Request -> (Response -> IO ResponseReceived) -> IO ResponseReceived) 
             -> (Request -> (Response -> IO ResponseReceived) -> IO ResponseReceived)
myMiddleware theOriginalApp = (\req sendResponse ->
  let myModifiedRequest = addSomeHeadersIfMissing req in
    undefined)

现在undefined呢？好吧，我们正在尝试将我们的 lambda 与该返回函数的类型相匹配，该函数接受一个 Request 和一个函数（我们不关心）并返回一个IO ResponseReceived.

所以，我们需要一些可以使用myModifiedRequest和返回IO ResponseReceived. 幸运的是，我们的类型签名表明它theOriginalApp具有正确的类型！为了让它适合，我们只需要给它一个sendResponse函数。

myMiddleware :: (Request -> (Response -> IO ResponseReceived) -> IO ResponseReceived) 
             -> (Request -> (Response -> IO ResponseReceived) -> IO ResponseReceived)
myMiddleware theOriginalApp = (\req sendResponse ->
  let myModifiedRequest = addSomeHeadersIfMissing req in
    theOriginalApp myModifiedRequest sendResponse)

就是这样，这将起作用！我们可以通过将类型注释简化回Middleware，并去掉 lambda 来提高可读性。（我们也可以eta-reduce并从参数和定义中删除该sendResponse术语，但我认为如果保留它会更清楚。）

结果：

myMiddleware :: Middleware
myMiddleware theOriginalApp req sendResponse =
  let myModifiedRequest = addSomeHeadersIfMissing req in
    theOriginalApp myModifiedRequest sendResponse
于 2018-10-15T14:02:01.593 回答