0

我正在编写 chrome DEPS 文件解析器。如何匹配 rightexpr 的以下任一语法规则定义之一。我的语法如下：

grammar Depsgrammar;

prog:   expr+ EOF;

expr:   varline
   ;
   
varline:  
   ID EQ  rightexpr  
    ;

rightexpr :  
    basicvalue | bentukonejsonval| bentuktwojsonval  
   ;
   
bentukonejsonval :
   '[' string?  (COMMA string )* COMMA? ']'
    ;
   
bentuktwojsonval :
    '{' singledictexpr?  (COMMA singledictexpr )* COMMA? '}'
   ;
   
singledictexpr :
    string ':' basicvalue
   ;
   
basicvalue :
 True
| False
| string
| NUM
| varfunc
;


varfunc :
 Var '(' string ')'
 ;

string :
 SIMPLESTRINGEXPRDOUBLEQUOTE
| SIMPLESTRINGEXPRSINGLEQUOTE
;

Var : 'Var' ;
COMMA : ',' ;
NUM : [0-9]+;
ID : [a-zA-Z0-9_]+;
True : [tT] [Rr] [Uu] [Ee];
False: [Ff] [Aa] [Ll] [Ss] [Ee];

fragment SIMPLESTRINGEXPRDOUBLEQUOTEBASE :   ~ ( '\n' | '\r' | '"' )*  ;
SIMPLESTRINGEXPRDOUBLEQUOTE: '"' SIMPLESTRINGEXPRDOUBLEQUOTEBASE '"' ;
fragment SIMPLESTRINGEXPRSINGLEQUOTEBASE :   ~ ( '\n' | '\r' | '\'' )* ;
SIMPLESTRINGEXPRSINGLEQUOTE : '\'' SIMPLESTRINGEXPRSINGLEQUOTEBASE '\'' ;
EQ : '=';
COMMENT:
  '#' ~ ( '\n' | '\r' )* '\n' -> skip ;

WS : [ \n\t\r]+ -> skip ;

我希望用户可以输入此输入

#adas21 #FS;SFD33
_as= Var('das') # somelongth comment
_as_0= FALSE # somelongth comment
_as_0= 'as!' # somelongth comment
gclient_gn_args = [

#ad as!~;
'checkout_libaom',
'checkout_nacl',
'"{cros_board}" == "amd64-generic"',
'checkout_oculus_sdk',
 ]


 vars = {
 'checkout_libaom':1,
 'checkout_nacl': "SS",
 'checkout_oculus_sdk': FalSe,
 'checkout_oculus_sdk':'',
  }

 s=[
 ]

每当我在 grun 中输入简单语法时

sa=true

总是给我第 1:3 行不匹配的输入 'true' 期待 blah..(rightexpr def)。我缺少对基本 antlr4 选择匹配决策的理解。你能教我吗？谢谢

4

1 回答 1

1

每当您遇到预期令牌列表似乎包含意外令牌的错误时，最好列出生成的令牌。您可以通过将-tokens选项传递给grun. 如果您对输入执行此操作，您会看到它true被解释为一个ID标记，而不是一个True标记。

这样做的原因是，当多个词法分析器规则将在当前输入上匹配并产生相同大小的匹配时，会选择语法中前面定义的那个。所以因为ID是之前定义的True，所以优先。通常，所有关键字都应在ID规则之前定义，以防止出现此问题。

换句话说，将TrueandFalse规则移到之前ID将解决您的问题。

于 2018-08-12T08:37:51.127 回答