3

在 url 中有 xml 文件：

<response>
<sum>0</sum>
<result>0</result>
<comment>sel*1.9488|buy*1.9453</comment>
</response>

现在想要存储过程，我可以在其中从 url 解析这个 xml 文件并更新到列值，这是<comment>sel*1.9488|buy*1.9453</comment>想要将buy*1.9453添加到我的表中。怎么做？

4

2 回答 2

12

要从 URL 获取 XML，您需要执行以下操作：

启用Ole 自动化程序

sp_configure 'show advanced options', 1;
GO
RECONFIGURE;
GO
sp_configure 'Ole Automation Procedures', 1;
GO
RECONFIGURE;
GO

然后要从 url 获取 XML，（答案基于此处的更新版本），以下创建一个临时表来存储值，以便您可以使用 xpath 和子字符串处理结果。

这是一个使用谷歌地图 xml 的工作示例，您需要根据您的特定要求更新 url 和 xpath。

USE tempdb
GO

IF OBJECT_ID('tempdb..#xml') IS NOT NULL DROP TABLE #xml
CREATE TABLE #xml ( yourXML XML )
GO

DECLARE @URL VARCHAR(8000) 

DECLARE @QS varchar(50)

-- & or ? depending if there are other query strings
-- Use this for when there is other query strings:
SELECT @QS = '&date='+convert(varchar(25),getdate(),126)
-- Use this for when there is NO other query strings:
-- SELECT @QS = '?date='+convert(varchar(25),getdate(),126)
SELECT @URL = 'http://maps.google.com/maps/api/geocode/xml?latlng=10.247087,-65.598409&sensor=false'  + @QS

DECLARE @Response varchar(8000)
DECLARE @XML xml
DECLARE @Obj int 
DECLARE @Result int 
DECLARE @HTTPStatus int 
DECLARE @ErrorMsg varchar(MAX)

EXEC @Result = sp_OACreate 'MSXML2.XMLHttp', @Obj OUT 

EXEC @Result = sp_OAMethod @Obj, 'open', NULL, 'GET', @URL, false
EXEC @Result = sp_OAMethod @Obj, 'setRequestHeader', NULL, 'Content-Type', 'application/x-www-form-urlencoded'
EXEC @Result = sp_OAMethod @Obj, send, NULL, ''
EXEC @Result = sp_OAGetProperty @Obj, 'status', @HTTPStatus OUT 

INSERT #xml ( yourXML )
EXEC @Result = sp_OAGetProperty @Obj, 'responseXML.xml'--, @Response OUT 

SELECT  yourXML.value('(//GeocodeResponse/status)[1]','VARCHAR(MAX)') from #xml

为了插入子字符串，您需要执行以下操作以返回管道后的所有内容并添加到您的表中：

INSERT tableDestination (valueDestination)
SELECT  substring(yourXML.value('(//response/comment)[1]','VARCHAR(MAX)'),charindex('|',yourXML.value('(//response/comment)[1]','VARCHAR(MAX)'),1)+1,len(yourXML.value('(//response/comment)','VARCHAR(MAX)'))) from #xml
于 2013-08-05T10:13:10.617 回答
2

像这样的东西怎么样

DECLARE @xml XML = 
'<response>
<sum>0</sum>
<result>0</result>
<comment>sel*1.9488|buy*1.9453</comment>
</response>'

SELECT  @xml.value('(//response/comment)[1]','VARCHAR(MAX)')

从value() 方法（xml 数据类型）

针对 XML 执行 XQuery 并返回 SQL 类型的值。此方法返回一个标量值。

您通常使用此方法从存储在 xml 类型列、参数或变量中的 XML 实例中提取值。通过这种方式，您可以指定将 XML 数据与非 XML 列中的数据组合或比较的 SELECT 查询。

SQL 小提琴演示

于 2013-08-05T09:28:13.410 回答