8

我有这个程序可以交换 Word 变量的字节（低/高）（它的作用与 System.Swap 函数相同）。该过程在编译器优化关闭时有效，但在它打开时无效。有人可以帮我吗？

procedure SwapWord(VAR TwoBytes: word);   
asm
  Mov EBX, TwoBytes
  Mov AX, [EBX]
  XCHG AL,AH
  Mov [EBX], AX
end;
4

5 回答 5

11

最快的：

function ReverseWord(w: word): word;
asm
   {$IFDEF CPUX64}
   mov rax, rcx
   {$ENDIF}
   xchg   al, ah
end;

如果您也想反转 DWORD：

function ReverseDWord(dw: cardinal): cardinal;
asm
  {$IFDEF CPUX64}
  mov rax, rcx
  {$ENDIF}
  bswap eax
end;
于 2011-02-27T17:41:26.097 回答
8

如果不保存/恢复它，就不能在 ASM 代码中使用 EBX 寄存器。您的代码的更正版本是

procedure SwapWord_Working(VAR TwoBytes: word);   
asm
  PUSH EBX     // save EBX
  Mov EBX, TwoBytes
  Mov AX, [EBX]
  XCHG AL,AH
  Mov [EBX], AX
  POP EBX     // restore EBX
end;
于 2011-02-27T15:33:35.387 回答
7

我有点惊讶，没有人提到absolute已经存在了十多年但没有引起太多关注的“黑客”……无论如何，这是我的两分钱

function SwapWordBytes(const Value: Word): Word;
var
  // shares memory with Value parameter
  LMemValue: array[0..1] of Byte absolute Value;
  // shares memory with Result
  LMemResult: array[0..1] of Byte absolute Result;
begin
  LMemResult[0] := LMemValue[1];
  LMemResult[1] := LMemValue[0];
end;
于 2011-02-28T01:01:52.510 回答
5

您是否考虑过使用编译器的Swap功能？

procedure TForm1.FormCreate(Sender: TObject);
var
  a: word;
begin
  a := $1234;
  a := Swap(a);
  Caption := IntToHex(a, 4)
end;

如果没有，您就不需要 ASM （并且 ASM 在 64 位 Delphi 中可能不可用）。你可以做

procedure MySwap(var a: word);
var
  tmp: byte;
begin
  tmp := PByte(@a)^;
  PByte(@a)^ := PByte(NativeUInt(@a) + sizeof(byte))^;
  PByte(NativeUInt(@a) + sizeof(byte))^ := tmp;
end;

procedure TForm1.FormCreate(Sender: TObject);
var
  a: word;
begin
  a := $123456;
  MySwap(a);
  Caption := IntToHex(a, 4)
end;

当然，这个主题有“一百万”种变化。

procedure MySwap(var a: word);
var
  tmp: byte;
type
  PWordRec = ^TWordRec;
  TWordRec = packed record
    byte1, byte2: byte;
  end;
begin
  with PWordRec(@a)^ do
  begin
    tmp := byte1;
    byte1 := byte2;
    byte2 := tmp;
  end;
end;

并且，非常简单地说，

procedure MySwap(var a: word);
begin
  a := word(a shl 8) + byte(a shr 8);
end;

或者

procedure MySwap(var a: word);
begin
  a := lo(a) shl 8 + hi(a);
end;
于 2011-02-27T15:20:35.860 回答
1

尽管 Serg 的回答肯定是正确的，正如对 Serg 回答的评论中所指出的那样，它效率不高。最快的显然是 Gabr 的答案中提供的代码，但是由于您明确需要一个过程，而不是一个函数，因此以下将是 Serg 例程的首选版本：

procedure SwapWord_Working2 (VAR TwoBytes: word);
asm
  mov dx, [TwoBytes]  ;//[TwoBytes] = [eax] on x86 *[Note1]
  xchg dl, dh
  mov [TwoBytes], dx
end;

[注1：] Serg 的函数版本很可能不适用于即将推出的 x64 Delphi 编译器。假设 Embarcadero 坚持他们使用 Win64 调用约定（@TwoBytes将通过哪里传递RCX）的计划（Allen Bauer 在某处提到），则此答案中提供的版本仍应适用于 x64。

于 2011-06-20T06:51:03.953 回答