0

所以我创建了一个具有多个属性的对象类型。

我还从那个对象创建了一个集合类型。比方说：

create or replace type employees as table of employee;

现在想用集合对象来执行GetAllEmployees()、GetEmployeesByJobType()等方法。这样我就可以在其他地方调用对象类型并执行该方法：

v_list := employees.GetAllEmployees(); 就像你从一个包中调用一样，但我想调用一个对象而不是一个包。

但是，我尝试像在对象中那样指定和创建方法，但它不会编译。

现在我知道我可以执行包中方法的逻辑，但我想将其分开。

所以我的问题是：是否可以在对象集合中执行逻辑？

4

1 回答 1

2

这可能是您正在寻找的示例：

create or replace type employeeObj as object (id number, name varchar2(100));

create or replace type employeeList is table of employeeObj;

create or replace type employeeListObj as object
(
    listOfEmployees employeeList,
    member procedure GetAllEmployees
); 

create or replace type body employeeListObj is
    member procedure GetAllEmployees is
    begin
        for i in listOfEmployees.first .. listOfEmployees.last loop
            dbms_output.put_line('Emp: ' || listOfEmployees(i).name );
        end loop;
    end;
end;

这个怎么运作：

SQL> declare
  2      vListEmp    employeeList;
  3      vListEmpObj employeeListObj;
  4  begin
  5      vListEmp := employeeList();
  6      vListEmp.extend(2);
  7      vListEmp(1) := employeeObj(1, 'John Smith');
  8      vListEmp(2) := employeeObj(2, 'Steve James');
  9
 10      vListEmpObj := new employeeListObj(vListEmp);
 11
 12      vListEmpObj.GetAllEmployees();
 13  end;
 14  /
Emp: John Smith
Emp: Steve James

PL/SQL procedure successfully completed.
于 2018-06-25T08:23:42.763 回答