4

我想要求用户输入密码。由于有时在与运行 VCL 的主线程不同的线程中需要密码，因此我尝试向主窗口发送一条消息并询问密码。然后主窗口询问用户。

我如何询问用户：

procedure TMainForm.WMGetPassword(var Msg: TMessage);
var
  Password: String;
begin
  if QueryPassword(Password) then // function QueryPassword(out Password: String): boolean;
  begin
    Password := Password + #0; // Add #0-Terminator
    Move(Password[1], Msg.wParam, Length(Password) * sizeOf(Char)); // Copy the String in my buffer
    Msg.Result := 1;
  end
  else
  begin
    Msg.Result := 0;
  end;
end;

我如何询问主窗口：

var
  PasswordBuffer: PChar;
  Password: String;
begin
  PasswordBuffer := AllocMem(100 * sizeof(Char));
  PasswordResult := SendMessage(MainFormHWND, WM_GetPassword, Integer(PasswordBuffer), 0);
  Result := (PasswordResult <> -1);
  if not Result then
    Exit;

  SetString(Password, PasswordBuffer, 100);
  ShowMessage(Password);
end;

但是Password之后PasswordBuffer是空的。我究竟做错了什么？

4

3 回答 3

3

由于您将 Msg.wParam 作为第二个参数传递，因此它将您的字符串写入该位置，而不是您尝试指向的位置。它将覆盖存储在 Msg.wParam、Msg.lParam、Msg.Result 中的值 + 可能还有堆栈上的其他一些信息。

代替：

Move(Password[1], Msg.wParam, Length(Password) * sizeOf(Char));

你应该使用：

Move(Password[1], PChar(Msg.wParam)^, Length(Password) * sizeOf(Char));

如果要使用指针，请使用 MoveMemory。

于 2012-08-14T10:30:15.657 回答
3

只要线程在同一个进程中（因此它共享相同的地址空间），您的代码就应该可以工作。然而，它不必要地复杂并且有内存泄漏（PasswordBuffer永远不会被释放）。

您可以在线程中使用字符串变量并将地址传递给其内部预分配缓冲区到主线程：

type
  TTestThread = class(TThread)
  private
    fHwnd: HWND;
  protected
    procedure Execute; override;
  public
    constructor Create(AWnd: HWND);
  end;

constructor TTestThread.Create(AWnd: HWND);
begin
  fHwnd := AWnd;
  inherited Create(False);
end;

procedure TTestThread.Execute;
const
  MAXLEN = 1024;
var
  s: string;
begin
  SetLength(s, MAXLEN);
  if SendMessage(fHwnd, WM_GETPASSWORD, MAXLEN, LPARAM(@s[1])) > 0 then begin
    s := PChar(s);
    // don't use VCL here
    Windows.MessageBox(0, PChar('password is "' + s + '"'), 'password',
      MB_ICONINFORMATION or MB_OK);
  end;
end;

在主线程中，密码被放入缓冲区，长度限制为缓冲区大小：

procedure TForm1.WMGetPassword(var AMsg: TMessage);
var
  Pwd: string;
begin
  if InputQuery('Password Entry', 'Please enter the password:', Pwd)
    and (Pwd <> '')
  then begin
    StrPLCopy(PChar(AMsg.LParam), Pwd, AMsg.WParam);
    AMsg.Result := 1;
  end else
    AMsg.Result := -1;
end;
于 2012-08-14T10:33:02.697 回答
2

@Dan 做对了，加上 @mghie 发现了泄漏。

这是不涉及指针的另一种方法：

type
  TMyMessage = class
    msg: string;
  end;

procedure TMainForm.WMGetPassword(var Msg: TMessage);
var
  SMessage: TMyMessage;
  Password: string;
begin
  if QueryPassword(Password) then 
  begin
    SMessage := TMyMessage(msg.WParam);
    SMessage.msg := Password;
    msg.Result := 1;
  end
  else
  begin
    Msg.Result := 0;
  end;
end;


var
  MyMsg: TMyMessage;
begin
  MyMsg := TMyMessage.Create('');
  try
    PasswordResult := SendMessage(FormHandleHWND,WM_GetPassword,WPARAM(MyMsg),0);
    Result := (PasswordResult <> -1);
    if Result
      then Password := MyMsg.msg;
  finally
    MyMsg.Free;
  end;
end;
于 2012-08-14T10:55:44.990 回答