sas - SAS 是否具有与 R 中的 all() 或 any() 等效的功能

Question

在 R 中，您可以使用 all() 或 any() 函数对列变量中的所有行执行条件。SAS中有等效的方法吗？

如果 x 列中的任何行都是负数，我想要条件，这应该返回 TRUE。

或者，如果 y 列中的所有行都是负数，则应该返回 TRUE。

例如

x   y
-1  -2
2   -4
3   -4
4   -3

在 R 中：

• all(x<0)将给出输出 FALSE
• all(y<0)会给输出 TRUE

我希望在 SAS 中复制相同的按列操作。

Answer 1

为了完整起见，这里是 SAS-IML 解决方案。当然，这很简单，因为anyandall函数以相同的名称存在……我还包括一个使用loc来识别正元素的示例。

data have ;
  input x y @@;
cards;
1 2 
2 4 
3 -4 
4 -3 
;
run;

proc iml;
    use have;
    read all var {"x" "y"};
    print x y;
    x_all = all(x>0);
    x_any = any(x>0);
    y_all = all(y>0);
    y_any = any(y>0);
    y_pos = y[loc(y>0)];

    print x_all x_any y_all y_any;
    print y_pos;
quit;

Answer 2

如果您想对所有可能最容易使用 SQL 汇总函数的观察结果进行操作。

SAS 将布尔表达式评估为 1 为真，0 为假。因此，要找出任何观察是否具有您想要测试的条件是否MAX( condition )为真（即等于 1）。找出是否所有观察都具有您想要测试的条件是否MIN( condition )为真。

data have ;
  input x y @@;
cards;
-1 -2 2 -4 3 -4 4 -3 
;

proc sql ;
create table want as 
  select 
     min(x<0) as ALL_X
   , max(x<0) as ANY_X
   , min(y<0) as ALL_Y
   , max(y<0) as ANY_Y
  from have
;
quit;

结果

Obs    ALL_X    ANY_X    ALL_Y    ANY_Y
 1       0        1        1        1

Answer 3

SQL 可能是最类似的方法，但数据步骤同样有效，并且更适合任何类型的修改 - 坦率地说，如果你想学习 SAS，可能是简单地从学习如何以 SAS 方式做事的角度来看。

data want;
  set have end=eof;
  retain any_x all_x;         *persist the value across rows;
  any_x = max(any_x, (x>0));  *(x>0) 1=true 0=false, keep the MAX (so keep any true);
  all_x = min(all_x, (x>0));  *(x>0) keep the MIN (so keep any false);
  if eof then output;         *only output the final row to a dataset;
  *and/or;
  if eof then do;             *here we output the any/all values to macro variables;
    call symputx('any_x',any_x); *these macro variables can further drive logic;
    call symputx('all_x',all_x); *and exist in a global scope (unless we define otherwise);
  end;
run;