2

我有一个属于用户的帖子列表。这些帖子被构造为属于给定用户的链表。

我在保留数据结构的同时删除了给定的节点。

这是结构的示意图。

在此处输入图像描述

在我的列表尝试中，我编写了下面的查询，但是它不起作用，因为 MATCH 没有在子查询中返回任何内容。

我曾考虑在子查询中使用 OPTIONAL MATCH，但这会导致异常。

MATCH(node:Post)
WHERE ID(node) = 2749
WITH node
MATCH(user:User)-[:OWNS]->(node)-[:PREV]->(nextNode:Post)
CREATE(user)-[:OWNS]->(nextNode)
WITH node
MATCH(prevNode:Post)-[:PREV]->(node)-[:PREV]->(nextNode:Post)
CREATE(prevNode)-[:PREV]->(nextNode)
WITH node
DETACH DELETE node

我假设如果子查询中的模式失败，则将跳过其余的子查询，并且下一个子查询仍将执行。但似乎整个事情并没有得到执行。

我们如何在不停止执行的情况下在子查询中执行以下操作。

IF pattern matches
THEN 
   CREATE EDGE 
IF pattern matches
THEN
   Do something else

解决方案

stdob--的答案最接近正确的解决方案，但是它无法删除列表末尾的节点并引发异常，因为它不检查 nextNode 是否存在于第二个 FOREACH 语句中。

它需要调整才能工作：

MATCH(node:Post) WHERE ID(node) = 2813

OPTIONAL MATCH (user:User)-[:OWNS]->(node)
OPTIONAL MATCH (node)-[:PREV]->(nextNode:Post)
OPTIONAL MATCH (prevNode:Post)-[:PREV]->(node)

FOREACH (ith in CASE 
    WHEN user IS NOT NULL AND nextNode IS NOT NULL 
    THEN [1] 
    ELSE [] 
    END | CREATE (user)-[:OWNS]->(nextNode) 
)

FOREACH (ith in CASE WHEN 
    prevNode IS NOT NULL AND nextNode IS NOT NULL 
    THEN [1] ELSE [] 
    END | CREATE (prevNode)-[:PREV]->(nextNode)
)

DETACH DELETE node
4

2 回答 2

2

您可以使用OPTIONAL MATCH,FOREACH和的组合CASE：

MATCH(node:Post) WHERE ID(node) = 2749

OPTIONAL MATCH (user:User)-[:OWNS]->(node)
OPTIONAL MATCH (node)-[:PREV]->(nextNode:Post)
OPTIONAL MATCH (prevNode:Post)-[:PREV]->(node)

FOREACH (ith in CASE WHEN 
                     NOT user IS NULL AND 
                     NOT nextNode IS NULL 
                THEN [1] ELSE [] END |
    CREATE (user)-[:OWNS]->(nextNode) 
)

FOREACH (ith in CASE WHEN 
                     NOT prevNode IS NULL AND
                     NOT nextNode IS NULL
                THEN [1] ELSE [] END |
    CREATE (prevNode)-[:PREV]->(nextNode)
)

DETACH DELETE node

更新：您也可以使用条件查询执行中apoc.do.when的过程。apoc.library

于 2017-12-30T01:41:28.833 回答
1

我使用以下查询重新创建了您的数据集：

CREATE
  (u:User {name: 'Alice'})-[:OWNS]->
  (p1:Post {number: 1})-[:PREV]->
  (p2:Post {number: 2})-[:PREV]->
  (p3:Post {number: 3})-[:PREV]->
  (p4:Post {number: 4})-[:PREV]->
  (p5:Post)

正如您所提到的，使用OPTIONAL MATCH可能会导致异常，类似于：

预计会在 prevNode 找到一个节点，但什么也没找到 Some(NO_VALUE)

但是，您可以通过首先执行DELETE, 然后使用子句传递值WITH并仅运行if子句CREATE引入的变量来解决此问题。OPTIONAL MATCHIS NOT NULL

MATCH (user:User)-[:OWNS]->(node)-[:PREV]->(nextNode:Post)
WHERE node.number = 1
CREATE (user)-[:OWNS]->(nextNode)
WITH node, nextNode
OPTIONAL MATCH (prevNode:Post)-[:PREV]->(node)
DETACH DELETE node
WITH prevNode, nextNode
WHERE prevNode IS NOT NULL
CREATE (prevNode)-[:PREV]->(nextNode)
于 2017-12-30T01:48:16.903 回答