2

我正在尝试生成内联 javascript，但我必须将 parenscript 代码放入其中(:script)并(str)使用 cl-who 标记。ps, ps*,ps-inline并且ps-inline*似乎对生成的 js 没有太大的影响。

是编写宏以避免代码重复的常用方法，还是有更好的方法？

这是我的程序：

(in-package #:ps-test)

(defmacro standard-page ((&key title) &body body)
  `(with-html-output-to-string (*standard-output* nil :prologue t :indent t)
     (:html 
      :lang "en"
      (:head 
       (:meta :http-equiv "Content-Type" 
          :content    "text/html;charset=utf-8")
       (:title ,title)
           (:link :type "text/css" 
              :rel "stylesheet"
              :href "/style.css"))
      (:body 
       ,@body))))     

(defun main ()
  (with-html-output (*standard-output* nil :indent t :prologue nil)
    (standard-page (:title "Parenscript test")
      (:div (str "Hello worldzors"))
        (:script :type "text/javascript"
             (str (ps (alert "Hello world as well")))))))

(define-easy-handler (docroot :uri "/") ()
  (main))

(defun start-ps-test ()
  (setf (html-mode) :html5)
  (setf *js-string-delimiter* #\")
  (start (make-instance 'hunchentoot:easy-acceptor :port 8080)))

(defun stop-ps-test ()
  (stop *server*))

(defvar *server* (start-ps-test))
4

1 回答 1

2

宏在这个用例中很好。诀窍是宏以特定顺序展开。假设您定义了一个js宏：当遇到宏扩展时 with-html-output，对宏的内部调用(js (alert "Ho Ho Ho"))看起来像一个函数调用，并且在生成的代码中保持原样。如果您的js宏随后扩展为(:script ...)，那么系统将抱怨这:script是一个未知函数（假设您实际上没有命名这样的函数）。(who:htm ...)您应该使用 CL-WHO 的 code walker发出一个封闭的表达式来解释代码。

(defmacro js (code)
  `(who:htm
     (:script :type "text/javascript" (who:str (ps:ps ,code)))))

这仅适用于封闭的上下文with-html-output。

对于内联 Javascript，您不希望在其<script>周围有标签，您通常可以简单地使用ps-inline：

(who:with-html-output (*standard-output*)
  (:a :href (ps:ps-inline (void 0))
    "A link where the usual HREF behavior is canceled."))

;; prints:
;; 
;; <a href='javascript:void(0)'>A link where the usual HREF behavior is canceled.</a>

但是，如果您经常做同样的事情，请随意使用宏：

(defmacro link (&body body)
  `(who:htm (:a :href #.(ps:ps-inline (void 0)) ,@body)))

(who:with-html-output (*standard-output*) (link "Link"))

;; prints:
;;
;; <a href='javascript:void(0)'>Link</a>
于 2017-12-21T14:16:16.180 回答