3

我正在寻找通过引用传递的教堂的例子。这个例子有效，但它似乎是错误的形式，因为我正在“返回”输入。这会浪费内存吗？有没有明确的方法来操作一个类？

class PowerPuffGirl {
  var secretIngredients: [1..0] string;
}

var bubbles = new PowerPuffGirl();
bubbles.secretIngredients.push_back("sugar");
bubbles.secretIngredients.push_back("spice");
bubbles.secretIngredients.push_back("everything nice");

writeln(bubbles.secretIngredients);

proc kickAss(b: PowerPuffGirl) {
  b.secretIngredients.push_back("Chemical X");
  return b;
}

bubbles = kickAss(bubbles);
writeln(bubbles.secretIngredients);

它产生输出

sugar spice everything nice
sugar spice everything nice Chemical X

使用函数修改气泡的最有效方法是什么？

4

1 回答 1

5

Chapel 是否通过引用传递参数可以由参数意图控制。例如，整数通常按值传递，但我们可以通过引用传递一个：

proc increment(ref x:int) { // 'ref' here is an argument intent
  x += 1;
}
var x:int = 5;
increment(x);
writeln(x);                 // outputs 6

当您不指定参数时，类型传递的方式称为默认意图。Chapel 默认通过引用传递记录、域和数组；但是在这些函数中，只有数组是可修改的。（记录和域传递const ref——意味着它们通过引用传递，但传递给它们的函数不能修改它们。数组传递ref或const ref取决于函数对它们的作用——参见数组默认意图）。

现在，具体到您的问题，类实例默认通过“值”传递，但 Chapel 认为类实例的“值”是一个指针。这意味着不是允许一个字段（比如说）被改变，而是通过一个类实例来传递一个类实例，ref这意味着它可以被一个不同的类实例替换。目前没有办法说类实例的字段不应在函数中修改（除了使它们成为显式不可变的数据类型）。

鉴于所有这些，我认为您在问题中提供的代码示例没有任何效率低下。特别是，这里：

proc kickAss(b: PowerPuffGirl) {
  b.secretIngredients.push_back("Chemical X");
  return b;
}

接受的参数b将收到指向实例的指针的副本，并且return b将返回该指针的副本。实例的内容（特别是secretIngredients数组）将保持存储在原来的位置，并且不会在该过程中被复制。

还有一件事：

这个例子有效，但它似乎是错误的形式，因为我正在“返回”输入。

正如我所说，这对于类实例或整数来说并不是真正的问题。数组呢？

proc identity(A) {
  return A;
} 
var A:[1..100] int;
writeln(identity(A));

在此示例中，return Ainidentity()实际上确实会生成数组的副本。将数组传递到 时未创建该副本identity()，因为该数组是const ref有意传递的。但是，由于该函数返回一些作为引用的“按值”，因此有必要将其复制为返回的一部分。另请参阅语言演变文档中的数组默认按值返回。

在任何情况下，如果想通过引用返回一个数组，可以使用reforconst ref返回意图，例如：

proc refIdentity(ref arg) ref {
  return arg;
}
var B:[1..10] int;
writeln(refIdentity(B));

现在没有数组的副本，一切都只是指同一个B。

请注意，目前可以编写返回对不再存在的变量的引用的程序。编译器包括对该区域的一些检查，但它并不完整。希望该领域的改进很快就会到来。

于 2017-11-29T17:36:53.570 回答