jenkins - 将 Jenkins 管道中的交互式输入读取到变量中

Question

在 Jenkins 管道中，我想为用户提供一个选项，以便在运行时提供交互式输入。我想了解我们如何在 groovy 脚本中读取用户输入。请求帮助我们提供示例代码：

我指的是以下文档： https ://jenkins.io/doc/pipeline/steps/pipeline-input-step/

编辑-1：

经过一些试验，我得到了这个工作：

 pipeline {
    agent any

    stages {

        stage("Interactive_Input") {
            steps {
                script {
                def userInput = input(
                 id: 'userInput', message: 'Enter path of test reports:?', 
                 parameters: [
                 [$class: 'TextParameterDefinition', defaultValue: 'None', description: 'Path of config file', name: 'Config'],
                 [$class: 'TextParameterDefinition', defaultValue: 'None', description: 'Test Info file', name: 'Test']
                ])
                echo ("IQA Sheet Path: "+userInput['Config'])
                echo ("Test Info file path: "+userInput['Test'])

                }
            }
        }
    }
}

在这个例子中，我能够回显（打印）用户输入参数：

echo ("IQA Sheet Path: "+userInput['Config'])
echo ("Test Info file path: "+userInput['Test'])

但我无法将这些参数写入文件或将它们分配给变量。我们怎样才能做到这一点？

Answer 1

要保存到变量和文件，请根据您拥有的内容尝试以下操作：

pipeline {

    agent any

    stages {

        stage("Interactive_Input") {
            steps {
                script {

                    // Variables for input
                    def inputConfig
                    def inputTest

                    // Get the input
                    def userInput = input(
                            id: 'userInput', message: 'Enter path of test reports:?',
                            parameters: [

                                    string(defaultValue: 'None',
                                            description: 'Path of config file',
                                            name: 'Config'),
                                    string(defaultValue: 'None',
                                            description: 'Test Info file',
                                            name: 'Test'),
                            ])

                    // Save to variables. Default to empty string if not found.
                    inputConfig = userInput.Config?:''
                    inputTest = userInput.Test?:''

                    // Echo to console
                    echo("IQA Sheet Path: ${inputConfig}")
                    echo("Test Info file path: ${inputTest}")

                    // Write to file
                    writeFile file: "inputData.txt", text: "Config=${inputConfig}\r\nTest=${inputTest}"

                    // Archive the file (or whatever you want to do with it)
                    archiveArtifacts 'inputData.txt'
                }
            }
        }
    }
}

Answer 2

这是 input() 用法的最简单示例。

• 在阶段视图中，当您将鼠标悬停在第一阶段时，您会注意到“您要继续吗？”的问题。
• 运行作业时，您会在控制台输出中注意到类似的注释。

在您单击继续或中止之前，该作业会在暂停状态下等待用户输入。

pipeline {
    agent any

    stages {
        stage('Input') {
            steps {
                input('Do you want to proceed?')
            }
        }

        stage('If Proceed is clicked') {
            steps {
                print('hello')
            }
        }
    }
}

还有更高级的用法来显示参数列表并允许用户选择一个参数。根据选择，您可以编写 groovy 逻辑以继续并部署到 QA 或生产环境。

以下脚本呈现一个下拉列表，用户可以从中选择

stage('Wait for user to input text?') {
    steps {
        script {
             def userInput = input(id: 'userInput', message: 'Merge to?',
             parameters: [[$class: 'ChoiceParameterDefinition', defaultValue: 'strDef', 
                description:'describing choices', name:'nameChoice', choices: "QA\nUAT\nProduction\nDevelop\nMaster"]
             ])

            println(userInput); //Use this value to branch to different logic if needed
        }
    }

}

您还可以使用StringParameterDefinition,TextParameterDefinition或BooleanParameterDefinition链接中提到的许多其他人

Answer 3

解决方案：为了在 jenkins 管道上设置、获取和访问用户输入作为变量，您应该使用ChoiceParameterDefinition，并附上一个快速工作片段：

    script {
            // Define Variable
             def USER_INPUT = input(
                    message: 'User input required - Some Yes or No question?',
                    parameters: [
                            [$class: 'ChoiceParameterDefinition',
                             choices: ['no','yes'].join('\n'),
                             name: 'input',
                             description: 'Menu - select box option']
                    ])

            echo "The answer is: ${USER_INPUT}"

            if( "${USER_INPUT}" == "yes"){
                //do something
            } else {
                //do something else
            }
        }