4

远程变量声明如何工作？我尝试使用Chapel 语言规范第 26.2.1 节中所述的 on 子句来增加普通变量声明，但它似乎不起作用。例如，这行代码：

on Locales[1] var x: [0..10] real;

编译失败，报错syntax error: near 'var'。

4

1 回答 1

5

简而言之，语法已指定，但当前尚未实现。不幸的是，语言规范目前没有指出它是未来的功能。

感谢您指出问题。这个可以说是针对 Chapel 项目的 GitHub 问题更好，所以我创建了一个问题来跟踪问题。

典型的解决方法是选择以下之一：

  1. 使用嵌套on语句达到想要的效果
  2. on在语句中分配一个类实例
  3. 使用分布式数组

在这里，我将描述每一个。

首先，我们需要一个稍长的例子。假设你试图写：

on Locales[1] var A: [0..10] real; // declare array stored on Locales[1]
A = 1; // on Locale 0, set every element of A to 1
writeln(A); // on Locale 0, print out the array

// print out the locale storing each element
for x in A {
  write(x.locale.id, " ");
}
writeln();

使用嵌套on语句编写它的等效方法是：

on Locales[1] {
  var A: [0..10] real;
  on Locales[0] {
    A = 1;
    writeln(A);
    for x in A {
      write(x.locale.id, " ");
    }
    writeln();
  }
}
// result, when run on 2 locales:
// from printing array elements:
// 1.0 1.0 1.0 1.0 1.0 1.0 1.0 1.0 1.0 1.0 1.0
// from printing element locales:
// 1 1 1 1 1 1 1 1 1 1 1

请注意，在示例中，我们知道分配将发生在 Locale 0 上。如果我们不知道正在运行的 Locale 是什么，我们可以将它保存到第一个之前的变量中on（例如var fromLocale = here;）并在第二on。

on在某些情况下，使用该语句来指定变量的初始化位置而不更改它的声明位置可能更方便。现在，这可以通过类实例来完成。请注意，这些不是垃圾收集 - 您需要使用 Owned/Shared 或确保delete调用。

本着对问题的更简单答案的精神，我将展示一个调用delete.

class MyArrayWrapper {
  var A: [0..10] real;
}
var myObject: MyArrayWrapper; // starts out as nil
on Locales[1] {
  // set myObject to a new instance
  // since we do that on Locales[1], it is allocated there
  // and the contained array is stored there too.
  myObject = new MyArrayWrapper();
}
myObject.A = 1;
writeln(myObject.A);
for x in myObject.A {
  write(x.locale.id, " ");
}
writeln();
delete myObject;
// result, when run on 2 locales:
// from printing array elements:
// 1.0 1.0 1.0 1.0 1.0 1.0 1.0 1.0 1.0 1.0 1.0
// from printing element locales:
// 1 1 1 1 1 1 1 1 1 1 1

现在，我们如何使用分布式阵列来实现相同的目标？首先，考虑这个例子，它将 11 个元素分布在运行 Chapel 程序的任何语言环境中。

use BlockDist;

const MyDom = {0..10}; // this domain represents the index set 0..10
// declare a Block-distributed index set 0..10
// by default, this is distributed over all available Locales
const MyBlockDistributedDomain = MyDom dmapped Block(boundingBox=MyDom);
// declare an Block-distributed array
var BlockDistributedA: [MyBlockDistributedDomain] real;
BlockDistributedA = 1;
writeln(BlockDistributedA);
for x in BlockDistributedA {
  write(x.locale.id, " ");
}
writeln();
// result, when run on 2 locales:
// from printing array elements:
// 1.0 1.0 1.0 1.0 1.0 1.0 1.0 1.0 1.0 1.0 1.0
// from printing element locales:
// 0 0 0 0 0 0 1 1 1 1 1

这将数组分布在可用的语言环境中，但这种行为只是 Block 分布的默认值。我们可以指定要与 Block 构造函数的参数一起使用的语言环境，如下例所示：

use BlockDist;

const MyDom = {0..10};
// This time, specify the target locales for the Block distribution to use.
// Here we pass in an anonymous array storing just Locales[1], so that
// the resulting array only stores elements on Locales[1].
const MyDistributedDomain = MyDom dmapped Block(boundingBox=MyDom,
                                                targetLocales=[Locales[1]]);
var DistributedA: [MyDistributedDomain] real;
DistributedA = 1;
writeln(DistributedA);
for x in DistributedA {
  write(x.locale.id, " ");
}
writeln();
// result, when run on 2 locales:
// from printing array elements:
// 1.0 1.0 1.0 1.0 1.0 1.0 1.0 1.0 1.0 1.0 1.0
// from printing element locales:
// 1 1 1 1 1 1 1 1 1 1 1
于 2017-11-01T14:05:19.427 回答