2

我有一个包含多个子组（变量economist）和日期（变量temps99）的数据集。

我想运行一个tabsplit不接受bysort或不带by前缀的命令。所以我创建了一个宏来将我的tabsplit命令应用于我的数据中的每个子组。

例如：

levelsof economist, local(liste)

foreach gars of local liste {
    display "`gars'"
    tabsplit SubjectCategory if economist=="`gars'", p(;) sort 
    return list
    replace nbcateco = r(r) if economist == "`gars'"
}

对于每个子组，Stata 运行tabsplit命令，我使用变量nbcateco来存储计数结果。

我对日期做了同样的事情，所以我可以随着时间的r(r)推移而演变：

levelsof temps99, local(liste23)

foreach time of local liste23 {
    display "`time'"
    tabsplit SubjectCategory if temps99 == "`time'", p(;) sort
    return list
    replace nbcattime = r(r) if temps99 == "`time'"
}

现在我想economist按日期对每个子组执行此操作temps99。我尝试了多种组合，但我对宏不太擅长（还没有？）。

我想要的是能够r(r)随着时间的推移为我的每个子组拥有我的。

4

2 回答 2

2

这是一个解决方案，它显示了如何计算每个分组中不同出版物类别的数量。这使用runby（来自 SSC）。runby循环遍历每个 by-group，每次将内存中的数据替换为当前 by-group 中的数据。对于每个按组，执行用户程序中包含的命令。当用户的程序终止时，内存中剩下的任何东西都被认为是结果并累积起来。处理完所有组后，这些结果将替换内存中的数据。

我使用该verbose选项是因为我想使用漂亮的格式呈现每个分组的结果。不同类别列表的派生是通过拆分每个列表、转换为长布局并减少每个不同值的一个观察值来完成的。该distinct_categories程序生成一个变量，其中包含按组的不同类别的最终计数。

* create a demontration dataset
* ------------------------------------------------------------------------------
clear all
set seed 12345

* Example generated by -dataex-. To install: ssc install dataex
clear
input str19 economist
"Carmen M. Reinhart" 
"Janet Currie"       
"Asli Demirguc-Kunt" 
"Esther Duflo"       
"Marianne Bertrand"  
"Claudia Goldin"     
"Bronwyn Hughes Hall"
"Serena Ng"          
"Anne Case"          
"Valerie Ann Ramey"  
end

expand 20
bysort economist: gen temps99 = 1998 + _n
gen pubs = runiformint(1,10)
expand pubs
sort economist temps99
gen pubid = _n
local nep NEP-AGR NEP-CBA NEP-COM NEP-DEV NEP-DGE NEP-ECM NEP-EEC NEP-ENE ///
          NEP-ENV NEP-HIS NEP-INO NEP-INT NEP-LAB NEP-MAC NEP-MIC NEP-MON ///
          NEP-PBE NEP-TRA NEP-URE
gen SubjectCategory = ""
forvalues i=1/19 {
    replace SubjectCategory = SubjectCategory + " " + word("`nep'",`i') ///
        if runiform() < .1
}
replace SubjectCategory = subinstr(trim(SubjectCategory)," ",";",.)
leftalign   // from SSC
* ------------------------------------------------------------------------------


program distinct_categories
  dis _n _n _dup(80) "-"
  dis as txt "fille = " as res economist[1] as txt _col(68) " temps = " as res temps99[1]

  // if there are no subjects for the group, exit now to avoid a no obs error
  qui count if !mi(trim(SubjectCategory))
  if r(N) == 0 exit

  // split categories, reshape to a long layout, and reduce to unique values
  preserve
  keep pubid SubjectCategory
  quietly {
    split SubjectCategory, parse(;) gen(cat)
    reshape long cat, i(pubid)
    bysort cat: keep if _n == 1
    drop if mi(cat)
  }

  // show results and generate the wanted variable
  list cat
  local distinct = _N
  dis _n as txt "distinct = " as res `distinct'
  restore
  gen wanted = `distinct'
end

runby distinct_categories, by(economist temps99) verbose
于 2017-10-29T16:10:42.947 回答
1

我认为这是 XY 问题的一个例子。见http://xyproblem.info/

tabsplittab_chi是来自 SSC的包中的命令。正如我写的那样，我对此没有负面情绪，但在这里似乎完全没有必要。

您想计算字符串变量中的类别：分号是您的分隔符。所以数分号并加1。

local SC SubjectCategory
gen NCategory = 1 + length(`SC') - length(subinstr(`SC', ";", "", .))

然后（例如）table或tabstat将让您按兴趣组进一步探索。

要了解计数的想法，请考虑使用 2 个分号的 3 个类别。

. display length("frog;toad;newt")
14

. display length(subinstr("frog;toad;newt", ";", "", .))
12

如果我们将每个分号替换为空字符串，长度的变化就是删除的分号数量。请注意，我们不必更改变量来执行此操作。然后加 1。另见本文。

也就是说，扩展您的方法的一种方法可能是 

egen class = group(economist temps99), label 
su class, meanonly 
local nclass = r(N)
gen result = . 

forval i = 1/`nclass' {
    di "`: label (class) `i''" 
    tabsplit SubjectCategory if class == `i', p(;) sort
    return list
    replace result = r(r) if class == `i'
}

使用statsby会更好。另请参阅此常见问题解答。

于 2017-10-29T07:59:57.643 回答