1

简介：我认为 Nape 是一个相对较新的引擎，所以你们中的一些人可能不知道它。据说它比 box2d 快，我喜欢有不错的文档。这是网站：http ://code.google.com/p/nape/

我对编程比较陌生。我很擅长 AS3 的基本功能，但每次我尝试实现某种引擎或框架时，我似乎都无法让它工作。有了 Nape，我觉得我比以前走得更远了，但我仍然卡住了。

我的问题：我使用的是 Adob​​e CS5，我设法导入了此处描述的 SWC 文件。接下来，我尝试复制其中一个演示的源代码，并使其正常工作，但我不断收到错误消息。我创建了一个新的类文件，将演示源复制到其中，并尝试将其添加到舞台上。

我的阶段代码基本上是这样的：

import flash.Boot; // these 2 lines are as described in the tutorial
new Boot(); 

var demo = new Main(); // these 2 are me guessing what I'm supposed to do
addChild(demo);

好吧，似乎源代码甚至没有被 Flash 识别为有效的类文件。我尝试对其进行编辑，但即使我得到了识别（给出一个包名并添加大括号），但我仍然得到一堆错误。是伪代码还是什么？到底是怎么回事？

我的目标：我可以想象我会以错误的方式解决这个问题。所以让我解释一下我想要实现的目标。我基本上想从一个可以编辑和弄乱的简单基本示例开始学习如何使用引擎。如果我什至无法获得一个有效的示例，那么我将无法学到任何东西。最好我不想开始使用 FlashDevelop 之类的东西（因为我必须学习如何使用该程序），但如果无法帮助，那么我可以试一试。

4

1 回答 1

4

该站点上的代码示例是 Haxe，而不是 ActionScript，它解释了您在添加“包”时遇到的错误。

这是 ActionScript 类的修改版本：

package{ 

import flash.display.Graphics; 
import flash.display.Sprite; 
import flash.events.Event; 
import flash.events.MouseEvent; 
import flash.display.StageQuality; 

import nape.space.Space; 
import nape.space.UniformSleepSpace; 
import nape.util.Tools; 
import nape.geom.Vec2; 
import nape.geom.GeomPoly; 
import nape.phys.PhysObj; 
import nape.phys.Material; 
import nape.geom.AABB; 

//- - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - -  

public class Main extends Sprite
{ 
        private var space:Space; 

        private var g:Graphics; 
        private var vl:Array; 
        private var px:Number; private var py:Number; 

        //- - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - -  

        private function mouseDown(ev:MouseEvent):void { 
                var x = stage.mouseX; 
                var y = stage.mouseY; 

                g.lineStyle(1, 0, 0.5); 
                vl.push(new Vec2(x, y)); 
                g.moveTo(x, y); 
                px = x; py = y; 
        } 

        private function mouseUp(ev:MouseEvent):void { 
                if (vl.length >= 3) { 
                        var poly = new GeomPoly(vl); 
                        poly.simplify(50, 4); 
                        if (!poly.selfIntersecting()) { 
                                if (!poly.cw()) poly.points.reverse(); 

                                var p = Tools.createConcave(poly, 0, 0, 0, false, Material.Wood); 
                                space.addObject(p); 
                                addChild(p.graphic); 
                        } 
                } 
                g.clear(); 
                vl = new Array(); 
                px = -100; 
        } 

        //- - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - -  

        public function init(ev:Event = null)
        { 
                var s = new Sprite(); 
                g = s.graphics; 
                addChild(s); 
                s.cacheAsBitmap = true; 
                vl = new Array(); 
                px = -100; 

                space = new UniformSleepSpace(new AABB(0,0, 800,600), 30, new Vec2(0, 250)); 

                var p:PhysObj; 
                space.addObject(p = Tools.createBox(-20, 300, 50, 600, 0, 0, 0, true, Material.Wood)); 
                addChild(p.graphic); 
                space.addObject(p = Tools.createBox(820, 300, 50, 600, 0, 0, 0, true, Material.Wood)); 
                addChild(p.graphic); 
                space.addObject(p = Tools.createBox(400, -20, 800, 50, 0, 0, 0, true, Material.Wood)); 
                addChild(p.graphic); 
                space.addObject(p = Tools.createBox(400, 620, 800, 50, 0, 0, 0, true, Material.Wood)); 
                addChild(p.graphic); 

                stage.quality = StageQuality.MEDIUM; 
                stage.addEventListener(MouseEvent.MOUSE_DOWN, mouseDown); 
                stage.addEventListener(MouseEvent.MOUSE_UP,   mouseUp); 
                stage.addEventListener(Event.ENTER_FRAME,     enterFrame); 
        } 

        //- - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - -  

    private function enterFrame(ev:Event) { 
                graphics.clear(); 
                graphics.lineStyle(1, 0, 1); 
                if (px != -100) { 
                        var x = stage.mouseX; 
                        var y = stage.mouseY; 
                        var dx = x - px; var dy = y - py; 
                        if (dx * dx + dy * dy > 5) { 
                                vl.push(new Vec2(x, y)); 
                                px = x; py = y; 
                                g.lineTo(x, y); 
                        }else { 
                                graphics.moveTo(px, py); 
                                graphics.lineTo(x, y); 
                        } 
                } 

        space.step(1/60, 6, 6); 
        } 
}
}

这是时间线代码：

import flash.Boot; 
new Boot();

var m:Main = new Main();
m.addEventListener(Event.ADDED_TO_STAGE, m.init);
addChild(m)

对于此设置，您的 fla 应为 800x600，frameRate 为 60。另外，请注意我已将构造函数更改为 init 方法。这是因为在此访问阶段，并且在将 Main 的实例添加到阶段之前，对阶段的引用将为空。

对于刚接触编程的人来说，混合 AS3 和 Haxe 并不容易。如果你对 Haxe 感兴趣，那就去吧，否则，为了更简单的 2D 物理，我建议你试试Box2D World Construction Kit。它允许您直接在 IDE 中使用组件定义轻松地对世界进行原型制作，并且它应该比直接 AS3 端口快一点，因为它使用的是 Alchemy。

世界建筑套件

此外，在gotoAndLearn上还有一个免费的介绍性视频教程可以帮助您入门。

祝你好运！

于 2011-01-10T01:42:40.123 回答