4

我试图让Router::Resource在函数的参数不是字面匿名 subs 而是前面定义的 coderefs 的情况下工作。我这样做是为了减少代码重复。

这是大纲中的代码，以最小但有效的方式。这行得通。

# app.psgi
use 5.024;
use Router::Resource qw(resource router GET POST);
my $app = sub {
    my ($env) = @_;
    my $router = router {
        resource '/' => sub {
            GET { [200, [], ['get /']] };
        };
        resource '/blog/{year}/{month}' => sub {
            GET  { [200, [], ['get /blog']] };
            POST { [200, [], ['post /blog']] };
        };
    };
    $router->dispatch($env);
}
__END__
$ plackup &
$ http -b :5000
127.0.0.1 - - [17/Apr/2017:14:25:28 +0200] "GET / HTTP/1.1" 200 5 "-" "HTTPie/0.9.2"
get /
$ http -b :5000/blog/2017/4
127.0.0.1 - - [17/Apr/2017:14:26:15 +0200] "GET /blog/2017/4 HTTP/1.1" 200 9 "-" "HTTPie/0.9.2"
get /blog
$ http -b POST :5000/blog/2017/4
127.0.0.1 - - [17/Apr/2017:14:26:28 +0200] "POST /blog/2017/4 HTTP/1.1" 200 10 "-" "HTTPie/0.9.2"
post /blog
$ pkill -f plackup

在将内部 PSGI 代码从文字匿名更改为 coderef 之后，因此：

my $get_root = sub { [200, [], ['get /']] };
⋮
        resource '/' => sub {
            GET $get_root;
        };

然后程序将不再编译：

$ perl -c app.psgi
Type of arg 1 to Router::Resource::GET must be block or sub {} (not private variable) at app.psgi line 8, near "$get_root;"

函数原型是GET(&). 当&是第一个位置时，它允许调用者使用缩写语法，有点像用sort { … } @list和map { … }代替sort sub { … }, @list等，请参阅perlsub#Prototypes：

An&需要一个匿名子例程，如果作为第一个参数传递，则不需要sub关键字或后续逗号。

当有原型时，如何使用 coderefs 而不是文字 subs？

4

2 回答 2

4

选项：

  • 绕过原型。

    &GET($get_root)

  • BLOCK按照错误消息的要求提供一个。

    GET { $get_root->(@_) }

  • sub { }按照错误消息的要求提供一个。

    GET(sub { $get_root->(@_) })

  • 使用以 . 开头的东西\&。（无证）

    GET(\&$get_root)
于 2017-04-17T16:52:07.730 回答
3

GET \&$get_root似乎工作。

对于您在评论中引用的更复杂的表达式，您可以使用

GET \&{$get_generic->('get /')}

该\&{...}操作将其内容强制转换为适用于&原型的代码引用。同样，您可以在要解决 a或原型的上下文中使用@{[...]}and 。%{{...}}\@\%

于 2017-04-17T14:32:31.480 回答