1

我有以下内容：

 <root>
  <html>
   <table
    <tr> 
     <td width="1%" height="20"></td>
     <td width="18%">Book Location </td>
     <td width="81%">Technology (Applied sciences) Circulation</td>
    </tr>

我正在 xslt 下面尝试获取 td 的节点内容为“Book Location”的直接节点内容：

<?xml version="1.0" encoding="utf-8"?>
 <xsl:stylesheet version="1.0"
 xmlns:marc="http://www.loc.gov/MARC21/slim"
 xmlns:xsi="http://www.w3.org/2001/XMLSchema-instance"
 xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
 <xsl:output method="text" indent="yes" />

 <xsl:template match="root">
  <xsl:for-each select="html">
  <xsl:text>START HERE</xsl:text>
  <xsl:text>&#13;&#10;</xsl:text>
  <xsl:text>=LDR  00000nam  2200000Ia 4500</xsl:text>
  <xsl:text>&#13;&#10;</xsl:text>

  <xsl:if test="//*[text()='Book Location ']">
   <xsl:text>=952  \\$cLocation: </xsl:text>
   <xsl:value-of select="following-sibling" />
  </xsl:if> 

  </xsl:for-each>

  </xsl:template>
 </xsl:stylesheet>

我不确定要在这部分中添加什么：或者是否有更好的方法？提前致谢，祝您有美好的一天！

4

2 回答 2

3

您的模板表明您正在像程序语言程序员一样思考。XSLT 可以或多或少地用那个习惯用法来编写，但它不是 XSLT 的自然习惯用法。以这种方式编写的代码往往比更自然的代码更长、更混乱。特别是，虽然它们有很好的用途，但for-each元素通常带有一点代码气味。

这对我来说似乎更自然，并且似乎有效（但我必须测试您输入的修改版本，因为您提供的不是有效的 XML）：

<?xml version="1.0" encoding="utf-8"?>
<xsl:stylesheet version="1.0"
    xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
  <xsl:output method="text" indent="yes" />

  <xsl:template match="/root/html">
    <xsl:text>START HERE</xsl:text>
    <xsl:text>&#13;&#10;</xsl:text>
    <xsl:text>=LDR  00000nam  2200000Ia 4500</xsl:text>
    <xsl:text>&#13;&#10;</xsl:text>
    <xsl:apply-templates select="descendant::td[text() = 'Book Location ']" />
  </xsl:template>

  <xsl:template match="td">
   <xsl:text>=952  \\$cLocation: </xsl:text>
   <xsl:value-of select="following-sibling::*[1]" />
  </xsl:template> 

</xsl:stylesheet>

笔记：

  • 更具体的匹配表达式消除了对for-each原始文件的需要
  • 不是试图将整个转换放入一个模板，而是使用单独的模板来转换单独的元素。这不仅更简洁，而且有助于简化表达式，因为每个模板都与它自己的上下文相关联，关于哪些表达式被评估
  • 要将“following-sibling”用作轴名称，而不是元素名称，您必须附加一个双冒号和至少一个某种节点测试
  • “following-sibling”轴可以包含多个节点，因此如果您只想要紧随其后的一个，那么您需要指定（如上）
  • 我可能选择直接转换td包含位置，而不是通过其 label 的模板间接转换td。这对我来说似乎更干净，但我没有这样做，因为它的语义略有不同。
于 2017-04-05T14:06:44.203 回答
1

你可以使用这个：

<xsl:value-of select="//*[text()='Book Location ']/following-sibling::*[1]" />

代替

<xsl:value-of select="following-sibling" />
于 2017-04-05T09:13:38.760 回答