3

我有一些我正在使用电源查询处理的报告，我有一个解决方案，但我希望这里的向导有更好的方法。

在下面的示例中，我当前的方法是拆分为 3 个查询，仅连接，具有名称和记录号，以及单个项目和值（删除 .1、.2、.3 以便标题记录相同) 然后我会将它们一起附加到一个查询中，旋转数据，然后加载到一个表中。对于某些文件，我会这样做很多次，为了回收查询，我必须分别复制每个文件（我不擅长调用函数）。有没有更好的方法在一个查询中执行此操作，最好是通过界面，以便我可以与比我更新的队友分享？我知道分组功能有潜力，但我不擅长使用这些工具（还）。请参阅下面的带有示例表的谷歌表：

https://docs.google.com/spreadsheets/d/14f-7GjUMwwzcUj9sAFBxaPjLnOW_1hKBYPtelRHfr70/edit?usp=sharing

4

2 回答 2

1

有趣的问题。经过几次试验，我设法在一个查询中做到了。

询问：

let
    Source = Table.FromRows(Json.Document(Binary.Decompress(Binary.FromText("ZY49D4MgEIb/C7MLYL9m07GNadwMw9UwmKLXACb67z1sbaAMR9477rk8bcuafmAF45zTW+ux6w0FSVWB6SYDHm34p2r07J+IL4pHpooUfUxG74sVDm9wjpIInYUFRwrnDLqj19+LYfNqwW1Hyo/LNg7MDewSGiFiyfJfUqSSp5zdLUViKWPLS05FmjLWPPw0JVNqBQ==", BinaryEncoding.Base64), Compression.Deflate)), let _t = ((type text) meta [Serialized.Text = true]) in type table [Name = _t, Record = _t, Item.1 = _t, Value.1 = _t, Item.2 = _t, Value.2 = _t, Item.3 = _t, Value.3 = _t]),
    #"Changed Type" = Table.TransformColumnTypes(Source,{{"Name", type text}, {"Record", Int64.Type}, {"Item.1", type text}, {"Value.1", Int64.Type}, {"Item.2", type text}, {"Value.2", Int64.Type}, {"Item.3", type text}, {"Value.3", Int64.Type}}),
    #"Unpivoted Columns" = Table.UnpivotOtherColumns(#"Changed Type", {"Name", "Record", "Value.1", "Value.2", "Value.3"}, "Attribute", "Value"),
    #"Renamed Columns" = Table.RenameColumns(#"Unpivoted Columns",{{"Attribute", "ItemKey"}, {"Value", "Item"}}),
    #"Unpivoted Columns1" = Table.UnpivotOtherColumns(#"Renamed Columns", {"Name", "Record", "ItemKey", "Item"}, "Attribute", "Value"),
    #"Renamed Columns1" = Table.RenameColumns(#"Unpivoted Columns1",{{"Attribute", "ValueKey"}}),
    #"Filtered Rows" = Table.SelectRows(#"Renamed Columns1", each Text.EndsWith([ItemKey], Text.End([ValueKey], 1))),
    #"Removed Columns" = Table.RemoveColumns(#"Filtered Rows",{"ItemKey", "ValueKey"}),
    #"Pivoted Column" = Table.Pivot(#"Removed Columns", List.Distinct(#"Removed Columns"[Item]), "Item", "Value", List.Sum)
in
    #"Pivoted Column"

结果：

结果

一点解释：

  • 取消透视所有项目列
  • Unpivot 所有值列（所以在这里它将创建 nxn 行记录）
  • 过滤 ItemKey 与 ValueKey 匹配的记录（例如 Item.1 = Value.1 等）
  • 删除 ItemKey 和 ValueKey 列
  • 将项目列作为标题，将值作为值

不是最好的解决方案，因为它会创建额外的记录，但涉及的手动工作要少得多，这应该可以解决您的问题。

PS #"Filtered Rows" 包含一些 UI 中不可用的内置函数，如果您的实际数据中每条记录的项值对超过 9 个，您可能需要对其进行自定义。（因为我只比较键的最后一个字符）

于 2017-03-25T04:55:11.553 回答
0

这就是我的看法：

let
    Source = Excel.CurrentWorkbook(){[Name="Table1"]}[Content],

//Add index for each row of source column. Use Add Index Column
    #"Added Index" = Table.AddIndexColumn(Source, "Index", 1, 1), 
//Unpivot table 
    #"Unpivoted Other Columns" = Table.UnpivotOtherColumns(#"Added Index", {"Index", "Name", "Record"}, "Attribute", "Value"),

//At this step I corrected default column names in formula editor. 
// Also, it is important to have only 1 dot in column names. 
    #"Split Column by Delimiter" = Table.SplitColumn(#"Unpivoted Other Columns","Attribute",Splitter.SplitTextByEachDelimiter({"."}, QuoteStyle.Csv, false),{"ColumnName", "ColumnIndex"}), 
//As a result we get old column names clean of numbers in one column, and index of each column in another

//Next we combine row index and column index in order to generate identifier for new row. Add custom column, write Text.From([Index]) & Text.From([ColumnIndex]) in formula window
    #"Added Custom" = Table.AddColumn(#"Split Column by Delimiter", "Idx", each Text.From([Index]) & Text.From([ColumnIndex])), 

//some cleanup
    #"Removed Other Columns" = Table.SelectColumns(#"Added Custom",{"Idx", "Name", "Record", "ColumnName", "Value"}), 

// Pivot columns back. Without row identifier this won't work! 
    #"Pivoted Column" = Table.Pivot(#"Removed Other Columns", {"Item", "Value"}, "ColumnName", "Value"), //Step on ColumnNames, select Pivot, Value as values column, Don't Aggregate as function.
    #"Removed Columns" = Table.RemoveColumns(#"Pivoted Column",{"Idx"}),
//Finally, Pivot to the desired look. 
    #"Pivoted Column1" = Table.Pivot(#"Removed Columns", List.Distinct(#"Removed Columns"[Item]), "Item", "Value", List.Sum) //Step on Item, select Pivot, Value as values column, Sum or Don't Aggregate as function.
in
    #"Pivoted Column1"

这将需要在“添加自定义”步骤中编写一些公式。

这将适用于任何合理数量的 item.x-value.x 列对。

于 2017-03-27T15:53:00.700 回答