39

我有一个带有数字的长电子表格。

我需要将它们放在一个由 ; 分隔的字符串中 例如。4364453;24332432;2342432

我知道我可以做到：

=concat(A1:A2000)

但这会将它合并到一个没有分隔符的字符串中 - 当您指定范围时，我似乎无法找到分隔符的选项。

谢谢

4

4 回答 4

68

使用 TEXTJOIN() 代替：

=TEXTJOIN(";",TRUE,A1:A2000)

对于那些没有 OFFICE 365 Excel 的人，请使用这个模仿 TEXTJOIN 函数的 UDF。

把它放在一个附加到工作簿的模块中，并使用上面的公式来调用。

Function TEXTJOIN(delim As String, skipblank As Boolean, arr)
    Dim d As Long
    Dim c As Long
    Dim arr2()
    Dim t As Long, y As Long
    t = -1
    y = -1
    If TypeName(arr) = "Range" Then
        arr2 = arr.Value
    Else
        arr2 = arr
    End If
    On Error Resume Next
    t = UBound(arr2, 2)
    y = UBound(arr2, 1)
    On Error GoTo 0

    If t >= 0 And y >= 0 Then
        For c = LBound(arr2, 1) To UBound(arr2, 1)
            For d = LBound(arr2, 1) To UBound(arr2, 2)
                If arr2(c, d) <> "" Or Not skipblank Then
                    TEXTJOIN = TEXTJOIN & arr2(c, d) & delim
                End If
            Next d
        Next c
    Else
        For c = LBound(arr2) To UBound(arr2)
            If arr2(c) <> "" Or Not skipblank Then
                TEXTJOIN = TEXTJOIN & arr2(c) & delim
            End If
        Next c
    End If
    TEXTJOIN = Left(TEXTJOIN, Len(TEXTJOIN) - Len(delim))
End Function
于 2017-02-10T17:22:19.883 回答
1

使用转置功能：

=TRANSPOSE(A1:A200)

选择公式并点击F2，您将得到一个带有默认分隔符的长字符串','，可以将其替换为您所需的分隔符。

于 2019-08-18T15:37:56.937 回答
0

如果您像我一样，并且您的工作计算机具有没有 TEXTJOIN 的旧版 Excel，则可以使用宏。这是我模拟的一些快速的东西，可以做单列或单行。只需单击要放置结果字符串的位置，然后运行宏。

请注意，这只会处理一行或一列，就像您的示例数据一样。如果你想做像连接 A1:C3 这样的事情，你需要不同的逻辑。

Sub ConcatenateRange()

Dim resultCell As Range
    Set resultCell = Selection

Dim concatRange As Range
    Set concatRange = Application.InputBox("Select a range", "Obtain Range Object", Type:=8)

Dim optionalSeparator As String
    optionalSeparator = Chr(34) & InputBox("Any Separator?") & Chr(34)

Dim outputString As String
    outputString = "=TRIM(CONCATENATE("

Dim rangeSize As Integer
    rangeSize = concatRange.Columns.count + concatRange.Rows.count

For Each item In concatRange
    outputString = outputString & item.Address(RowAbsolute:=False, ColumnAbsolute:=False)

    rangeSize = rangeSize - 1

    If (rangeSize > 1) Then
        outputString = outputString & ", " & optionalSeparator & ", "
    Else
        outputString = outputString & "))"
    End If
Next

resultCell.formula = outputString

End Sub
于 2017-02-10T17:49:50.830 回答
0

适当的搜索会为大家省去很多麻烦......有一个“MyConCat（）”，我从 2012 年在这里写的，更简单但非常有效......

于 2021-10-28T21:41:59.060 回答