4

我最初尝试创建一个固定前 5 个元素的生成器（并且在任何使用Prop.forAll前五个元素的测试中总是会运行），但没有这样做。

现在我试图通过在一个范围内使用一个随机数据生成器和一个用于非随机数据（即固定序列）的生成器来简化这一点。它类似于Gen.constant，不同之处在于它不是一个值，而是一个值序列。

我有这个（简化的可重现示例，适用于 NUnit 和 xUnit）：

[<Property(Verbose = true, MaxTest=5)>]
static member MultiplyIdentityCornerCases () =
    Gen.elements [0L; -1L; 1L; Int64.MinValue; Int64.MaxValue]
    |> Arb.fromGen 
    |> Prop.forAll <| fun x -> x = x * 1L

输出是（不知道从哪里来null）：

0:
<null>
9223372036854775807L
1:
<null>
-9223372036854775807L
2:
<null>
-9223372036854775807L
3:
<null>
1L
4:
<null>
-9223372036854775807L
Ok, passed 5 tests.

我希望输出包含序列中的所有五个测试，最好但不一定按顺序。我知道我可以使用 testdata 提供程序使用 NUnit（或任何单元测试系统）来做到这一点，但我想知道我是否可以使用 FsCheck 来做到这一点（或者我是否应该这样做，也许这是一个坏主意）。

我认为使用 FsCheck 很有用，至于有多个函数参数的情况，我希望它能够详尽地测试我给它的极端情况参数的所有组合。这希望使用 FsCheck 比使用测试数据提供者更容易。

4

1 回答 1

7

我不知道这是可能的，但你可以这样做：

open System
open FsCheck
open FsCheck.Xunit

[<Property>]
let MultiplyIdentityCornerCases () =
    Gen.oneof [
        Gen.elements [Int64.MinValue; -1L; 0L; 1L; Int64.MaxValue]
        Arb.generate ]
    |> Arb.fromGen
    |> Prop.forAll <| fun x -> x = x * 1L

将两个生成器传递给Gen.oneof，因此每个生成器将生成大约一半的值。

Gen.elements应该从提供的序列中的所有值中统一选择，因此它会使用例如20% 的时间，但仅用于使用0L时的那一半。Gen.oneofGen.elements

换句话说，这些“特殊”值中的每一个都将在 50% * 20% = 10% 的时间内生成。

默认情况下，一个属性运行 100 个测试用例，因此平均而言，它应该生成 10 个0L值、10 个Int64.MinValue值等等。这通常应该足够好。

如果不是，您可以随时执行以下操作：

open System
open Xunit
open FsCheck
open FsCheck.Xunit
open Swensen.Unquote

[<Theory>]
[<InlineData(Int64.MinValue)>]
[<InlineData(-1L)>]
[<InlineData( 0L)>]
[<InlineData( 1L)>]
[<InlineData(Int64.MaxValue)>]
let MultiplyIdentityCornerCases x = x =! x * 1L

[<Property>]
let MultiplyIdentityCornerCasesProperty x =
    MultiplyIdentityCornerCases x

在这里，您使用 xUnit.net 的[<Theory>]功能定义了一个参数化测试，并将您关心的五个极端情况提供给它。当您运行测试时，测试运行器将运行这五个测试用例。

此外，它会运行，MultiplyIdentityCornerCasesProperty因为它带有注释[<Property>]，并且该函数只是调用另一个函数。

于 2016-12-09T18:26:49.270 回答