5

如何模拟软切I *-> T; ISO Prolog中的E？我有副作用，所以我不能多次调用它。

除了最后一个要求，我认为以下定义有效：

if_(I, T, E) :-
    not(not(I)) ->
    call((I, T));
    call((not(I), E)).

（我实际上正在使用 XSB prolog；XSB 的解决方案对我也很有用。）

4

4 回答 4

4

好的，让我们发挥创意......您基本上需要一种方法来记住（通过回溯）If 条件至少有一个解决方案。动态谓词对我来说是一个禁忌，但还有其他选择吗？好吧，ISO-Prolog 定义了一种匿名对象stream-term，它可以（ab）用于以这种相当优雅的方式实现不可回溯标志：

if(If, Then, Else) :-
    open(., read, S),
    (
        If,
        close(S, [force(true)]),
        Then
    ;
        catch(close(S), error(existence_error(stream,_),_), fail),   % fail if already closed
        Else
    ).

我们关闭流以指示If有解决方案，然后通过 else 分支中的关闭尝试检测到。这在像ECLiPSe这样的系统中完美且无泄漏。然而，许多系统（包括 XSB）重复使用封闭流的标识符（ISO 不禁止），使得该解决方案不可移植。

但是等等，流有一个位置属性，可以设置，并且在回溯过程中保持它的值！使用这个技巧，以下适用于XSB：

if(If, Then, Else) :-
    % open('ReadableAndNonemptyFile', read, S),      % general ISO
    open(atom(a), read, S),                          % XSB (needs no file)
    stream_property(S, position(Zero)),
    get_char(S, _),
    (
        catch(If, Ball, (close(S),throw(Ball))),
        set_stream_position(S, Zero),
        Then

    ; stream_property(S, position(Zero)) ->
        close(S),
        fail
    ;
        close(S),
        Else
    ).

遗憾的是，该open(atom(...),...)功能是特定于 XSB 的，对于严格的 ISO-Prolog，您需要一个虚拟文件...

于 2016-11-17T15:36:53.697 回答
4

是的，我们可以在 ISO Prolog 甚至 XSB 中实现这一点，但效率不高。为了提高效率，您需要一些“选择性切割”。此外，XSB 没有实现符合 ISO 标准的整数，因此必须单独处理溢出。

:- dynamic(if_counter/1).

if_counter(0).

:- dynamic(no_if_answer/1).
if(If_0, Then_0, Else_0) :-
   once(if_counter(Id)),
   Idx is Id+1,
   (  Idx > Id -> true
   ;  throw(error(representation_error(max_integer),
               'XSB misses ISO conforming integers'))
   ),
   retractall(if_counter(_)),
   asserta(if_counter(Idx)),
   asserta(no_if_answer(Id)),
   (  If_0,
      retractall(no_if_answer(Id)),
      Then_0
   ;  retract(no_if_answer(Id)) ->
      Else_0
   ).

效率低下的主要原因是，对于确定的条件If_0，还有一个选择点。几乎不可想象的是，一旦执行，实现可能会得出结论retract(no_if_answer(Id))总是失败，retractall(no_if_answer(Id))但我怀疑实现者会投资于此类优化。编辑：这看起来不太可能的原因是实现必须保证断言的数字总是上升。

请注意，软切割会产生与切割相同的不完整性。考虑：

| ?- if(X = a, T = equal, T = not_equal).

X = a
T = equal;

no

这显然错过了答案！要了解原因，请采取X = b：

| ?- X = b, if(X = a, T = equal, T = not_equal).

X = b
T = not_equal;

no
| ?- if(X = a, T = equal, T = not_equal), X = b.

no % bad!!

连词应该是可交换的（模不终止、错误、副作用）。

如果您对声明性健全的条件句感兴趣，这些条件句也非常有效且通常比不纯的条件句更快，请考虑if_/3. 请参阅library(reif)SICStus，它给出了所有正确答案：

| ?- if_(X = a, T = equal, T = not_equal).
X = a,
T = equal ? ;
T = not_equal,
prolog:dif(X,a) ? ;
no
于 2016-11-16T19:25:53.753 回答
1

问题是，软剪辑应该相当聪明，当它的论点没有留下选择点时，它不应该留下选择点。

SWI-Prolog 中没有选择点：

   Welcome to SWI-Prolog (threaded, 64 bits, version 8.1.4)

   ?- X=1 *-> Y=1; true.
   X = Y, Y = 1.
   ?-

Jekejeke Prolog 中没有选择点：

   Jekejeke Prolog 3, Runtime Library 1.3.6

   ?- X=1 *-> Y=1; true.
   X = 1,
   Y = 1
   ?-

到目前为止，这里公认的创造性解决方案都没有存档，因此它们都不能有效地替代本机实现。

Jekejeke Prolog 进行确定性检查，然后删除析取选择点。否则，它标志着析取选择点。从模块“逻辑”：

:- set_predicate_property(;/2, sys_nobarrier).
A *-> B; C :- sys_local_cut, sys_soft_cond(A, B, C).

:- set_predicate_property(sys_soft_cond/3, sys_nobarrier).
sys_soft_cond(A, B, _) :- sys_safe(A), sys_soft_local_cut, B.                        
sys_soft_cond(_, _, C) :- C.
于 2019-03-30T21:16:33.957 回答
1

您的定义没有实现软切语义：当测试成功时，您可以回溯到它。这是一个有用的控制结构（我用它来实现 Logtalk 中的联合归纳），但不幸的是不能在 Prolog 级别以可移植的方式实现，而且肯定在 ISO Prolog 标准的限制范围内。好消息是越来越多的 Prolog 系统实现了这种控制结构。这些包括，无特定顺序，SWI-Prolog、YAP、SICStus Prolog、GNU Prolog、CxProlog、ECLiPSe、Jekejeke Prolog 和 Ciao。但请注意，虽然有些系统使用*->/2运算符，但少数（SICStus Prolog 和 Ciao）使用运算符if/3谓词（YAP 两者都有）。此外，语义在极端情况下有所不同（Logtalk 发行版包括一个 Prolog 一致性套件，它也检查 *->/2变体）。

于 2016-11-16T02:56:54.873 回答