5

有人能告诉我如何在 Wikidata 中找到 DBPedia 的同义词属性吗？例如，DBpedia 中的属性“name”在 Wikidata 中是“label”。如何找到所有同义词属性？

4

2 回答 2

8

进一步编辑...

查询 DBpedia 提供了更大的等效映射集，这些映射是通过完全不同但非常相似的查询获得的。

PREFIX       owl:  <http://www.w3.org/2002/07/owl#>
PREFIX      rdfs:  <http://www.w3.org/2000/01/rdf-schema#>

SELECT ?DBpediaProp ?itemLabel ?WikidataProp
WHERE
  {
    ?DBpediaProp  owl:equivalentProperty  ?WikidataProp .
                  FILTER ( CONTAINS ( str(?WikidataProp) , 'wikidata' ) ) .
    ?DBpediaProp  rdfs:label              ?itemLabel .
                  FILTER (lang(?itemLabel) = 'en')
  }
ORDER BY  ?DBpediaProp

编辑来自@Tom Morris 的回答

此查询可以在 Wikidata 端点https://query.wikidata.org/上运行。为了完整性和增加可移植性，我包含了PREFIX声明（即使该端点自动应用它们）。我也FILTER只得到dbpedia等价物；您可以划线以包括来自schema.org和可能的其他本体的等价物。

PREFIX       wdt:  <http://www.wikidata.org/prop/direct/>
PREFIX  wikibase:  <http://wikiba.se/ontology#>
PREFIX        bd:  <http://www.bigdata.com/rdf#>

SELECT ?WikidataProp ?itemLabel ?DBpediaProp
WHERE
  {
    ?WikidataProp  wdt:P1628  ?DBpediaProp .
    FILTER ( CONTAINS ( str(?DBpediaProp) , 'dbpedia' ) ) .
    SERVICE wikibase:label
      { bd:serviceParam  wikibase:language  "en" } .
  }

并且您（在撰写本文时）获得了多达两个这样的等价物。

我的原始答案

我不相信任何地方都可以使用完整的交叉映射，并且由于各种原因（尤其是这些本体没有被设计为完全同义），可能永远不会。

也就是说，您可以查看DBpedia Mapping Wiki。

你可以找到很多讨论......

于 2016-10-04T18:20:44.877 回答
4

它似乎没有很好地填充，但我希望 DBpedia 属性会出现在 Wikidata 的P1628“等效属性”中

SELECT ?item ?itemLabel ?equivProp
WHERE
{
    ?item wdt:P1628 ?equivProp .
    SERVICE wikibase:label { bd:serviceParam wikibase:language "en" }
}

示例结果：

item      itemLabel      equivProp
wd:P200   lake inflows   <http://dbpedia.org/ontology/inflow>
于 2016-10-05T04:49:41.900 回答