0

我喜欢Enlive，但是当我观察到以下内容时让我有些困惑。

考虑以下 Clojure 代码（也可在 github 上找到）：

(ns enlivetest.core
  (:require [net.cgrand.enlive-html :refer [deftemplate defsnippet] :as html]))

(deftemplate page "index.html"
  [ctx]
  [:.foobar] (html/content (do (println "GENERATING FOOBAR")
                               "===FOOBAR===")))

这个 HTML 模板（resources/index.html）在这里：

<!DOCTYPE html>
<html>
    <body>
    </body>
</html>

在调用page模板时，我希望它完全忽略其规则的右侧（转换），因为没有与规则的 selector 匹配的 HTML 标记:.foobar。

然而，事实证明，规则的右侧确实得到了评​​估：

user=> (require '[enlivetest.core :as c])
nil
user=> (c/page {})
GENERATING FOOBAR
GENERATING FOOBAR
("<!DOCTYPE html>\n" "<" "html" ">" "\n    " "<" "body" ">" "\n    " "</" "body" ">" "\n\n" "</" "html" ">")

（显然，它甚至会被评估两次 - 看起来模板中的每个根 HTML 元素一次）。

但是，尽管没有与选择器匹配的元素，为什么还要对其进行评估呢？这是正确的行为吗？我在这里遗漏了一些明显的东西吗？

这个例子使用 Enlive 1.1.6，正如它的 README 所建议的那样。

澄清非常感谢。

编辑＃1：

事实证明（感谢@leetwinski），我对事情如何运作的假设是不正确的：

我假设deftemplate宏只会在规则的选择器与给定 HTML 中的元素匹配时评估规则的右侧（转换部分）。

但正确的是：

在调用定义的模板函数（例如 ）期间，规则的右侧总是page会被评估，并且预计会评估一个函数，该函数将反过来评估所需的内容（例如“===FOOBAR===”在这个例子中）当被调用时。只有匹配选择器的元素才会调用此函数。

这意味着 eghtml/content评估这样的功能（而不是直接评估所需的内容）。

为了使事情按我最初的预期工作，我可以这样写：

(deftemplate page "index.html"
  [ctx]
  [:.foobar] #((html/content (do (println "GENERATING FOOBAR")
                                 "===FOOBAR===")) %))

这将导致以下输出：

user=> (c/page {})
("<!DOCTYPE html>\n" "<" "html" ">" "\n    " "<" "body" ">" "\n    " "</" "body" ">" "\n\n" "</" "html" ">")

或者在向<div class="foobar"></div>HTML 模板添加 a 时：

user=> (c/page {})
GENERATING FOOBAR
("<!DOCTYPE html>\n" "<" "html" ">" "\n    " "<" "body" ">" "\n\t\t" "<" "div" " " "class" "=\"" "foobar" "\"" ">" "===FOOBAR===" "</" "div" ">" "\n    " "</" "body" ">" "\n\n" "</" "html" ">")

编辑＃2：

已经有几个星期了，但我仍在为如何在 Enlive 中实现这一点而苦苦挣扎。#((html/content ...) %)我看到自己一遍又一遍地包装规则的转换部分。

有没有人解释为什么 Enlive 会评估转换（全部甚至多次），即使它们甚至与当前的渲染过程无关？

我可能忽略了一些东西，因为我真的很惊讶这似乎并没有打扰到除了我之外的任何人。

4

1 回答 1

2

原因是enlive的deftemplate宏的本质：

它需要成对的选择器到功能。在您的情况下，该函数是在此处动态生成的：

(html/content (do (println "GENERATING FOOBAR") "===FOOBAR==="))

content只需创建函数，在匹配的情况下将调用该函数。

user> ((html/content "this" "is" "fine") {:content []})
{:content ("this" "is" "fine")}

content不是宏，所以它应该评估它的参数。所以，你看到的不是错误的匹配函数调用，而是对在匹配情况下调用的一代函数的调用。

您可以通过 deftemplate 表单的宏展开轻松地看到它：

(def page
 (let*
   [opts__8226__auto__
    (merge (html/ns-options (find-ns 'user)) {})
    source__8227__auto__
    "index.html"]
   (html/register-resource! source__8227__auto__)
   (comp
     html/emit*
     (let*
       [nodes29797
        (map
          html/annotate
          (html/html-resource
            source__8227__auto__
             opts__8226__auto__))]
       (fn*
         ([ctx]
           (doall
             (html/flatmap
               (fn*
                 ([node__8199__auto__]
                    (html/transform
                      (html/as-nodes node__8199__auto__)
                     [:.foobar]
                     (html/content
                       (do
                         (println "GENERATING FOOBAR")
                         "===FOOBAR===")))))
               nodes29797))))))))

所以 println 中的正确字符串是：

(deftemplate page "index.html"
  [ctx]
  [:.foobar] (html/content (do (println "GENERATING FUNCTION SETTING FOOBAR AS THE NODE CONTENT")
                               "===FOOBAR===")))

您期望的行为可以通过这种方式实现：

user> 
(deftemplate page "index.html"
  [ctx]
  [:.foobar] (fn [node] (assoc node :content
                               (do (println "GENERATING FOOBAR" node)
                                   "===FOOBAR==="))))
#'ttask.core/page

user> (page {})
("<!DOCTYPE html>\n" "<" "html" ">" "\n    " "<" "body" ">" "\n    " "</" "body" ">" "\n\n" "</" "html" ">")

如果您在 index.html 中将类“foobar”添加到正文中，它会这样做（不要忘记deftemplate在更改 html 后重新运行）：

user> (page {})
GENERATING FOOBAR {:tag :body, :attrs {:class foobar}, :content []}
("<!DOCTYPE html>\n" "<" "html" ">" "\n    " "<" "body" " " "class" "=\"" "foobar" "\"" ">" "=" "=" "=" "F" "O" "O" "B" "A" "R" "=" "=" "=" "</" "body" ">" "\n\n" "</" "html" ">")
于 2016-08-05T17:08:06.600 回答