haskell - 向量上的 Haskell 模式匹配

Question

是否可以在向量上使用列表样式模式匹配？

IE

import qualified Data.Vector as V

f :: V.Vector a -> a
f (x:xs) = x 

给出错误

Answer 1

-XViewPatterns 可以让你这样做：

{-# LANGUAGE ViewPatterns #-}
module VecViewPats where

import Data.Vector (Vector)
import qualified Data.Vector as V

uncons :: Vector a -> Maybe (a, Vector a)
uncons v = if V.null v
  then Nothing
  else Just (V.unsafeHead v, V.unsafeTail v)

vsum :: Num a => Vector a -> a
vsum (uncons -> Just (a,av)) = a + vsum av
vsum (uncons -> Nothing) = 0

或者-XLambdaCase

import Control.Category ((>>>))
-- ...
vsum :: Num a => Vector a -> a
vsum = uncons >>> \case
  Just (a,av) -> a + vsum av
  Nothing     -> 0

Vector但老实说，当您使用一个数据结构 ( ) 作为另一个 ( )时，这似乎有点代码味道，[]这表明您选择的数据结构可能是错误的。

如果您真的只是想出于某种算法的目的将其视为列表，为什么不使用toList？

Answer 2

@Cactus 已经指出-XPatternSynonym（在 7.8 中引入）结合-XViewPattern可用于向量的模式匹配。我在这里进一步扩展他的评论。

pattern Empty <- (V.null -> True) 

上面定义了空向量的模式同义词Empty。该Empty模式使用视图模式 ( ) 与空向量匹配V.null -> True。但是，它不能用作其他地方的表达式，即单向同义词，因为系统并不真正知道什么Empty是向量（我们只知道它null v是True，但也可能有其他向量给出True）。

为了解决这个问题，where可以添加一个子句，指定 Empty 实际上是一个空向量，即双向同义词以及类型签名：

pattern Empty :: Vector a
pattern Empty <- (V.null -> True) where Empty = V.empty 

此模式同义词可用于在uncons没有 if 表达式的情况下进行定义：

uncons :: Vector a -> Maybe (a, Vector a)
uncons Empty = Nothing
uncons v     = Just (unsafeHead v, unsafeTail v)

我们uncons用来定义单向同义词。请注意，我不会将其设为双向，因为cons矢量成本很高：

pattern (:<|)  :: a -> Vector a -> Vector a
pattern x :<| xs <- (uncons -> Just (x, xs))

无论如何，我们终于能够像列表一样对向量进行模式匹配：

vsum :: Num a => Vector a -> a 
vsum Empty = 0
vsum (x :<| xs) = x + vsum xs

完整的代码在这里。

Answer 3

向量不是为那种模式匹配而设计的——它们被创建来提供 Haskell O(1) 列表，或者可以从任何点有效访问的列表。

与您写的最接近的内容是这样的：

f v = V.head v

或者，如果您正在寻找递归，则该tail函数将获取列表的其余部分。

但是，如果您尝试做一些沿着这样的列表移动的事情，则有 Vector 等价于函数，例如foldl、find、map等。这取决于你打算做什么。