1

我想知道插入的元素是否重复。

这是我正在寻找的简单示例：

在第一次运行时应该返回 false。

check_duplicate("user", "hi").

但在第二次运行中应该返回 true。

check_duplicate("user", "hi").
4

1 回答 1

3

函数式编程的最佳特性之一是纯函数。甚至还有像 Haskell 这样的函数式语言，你不能编写不纯的函数。纯函数总是为相同的参数返回相同的值。不纯函数具有副作用，并且可以为相同的参数返回不同的结果。这意味着必须更改一些您无法将其视为函数参数的状态。你只是为了它。Erlang 允许你这样做。你有很多选择如何做到这一点。最干净的是发送消息并从另一个进程接收消息。（无论如何它是不纯的，但在 Erlang 中是惯用的。以下代码非常简单，不适合生产使用。您应该使用 OTP 行为和设计原则。）

has_dupes(Jid, Text) ->
    Ref = make_ref(),
    seen ! {Ref, self(), {Jid, Text}},
    receive {Ref, Result} -> Result end.

start_seen() ->
    spawn(fun()-> register(seen, self()), loop_seen([]) end).

loop_seen(Seen) ->
    receive {Ref, From, Term} ->
        case lists:member(Term, Seen) of
            true  ->
                From ! {Ref, true},
                loop_seen(Seen);
            false ->
                From ! {Ref, false},
                loop_seen([Term|Seen])
        end
    end.

另一种是从ets（Erlang Term Storage）中存储和读取。

has_dupes(Jid, Text) ->
    (catch ets:new(seen, [set, named_table])),
    not ets:insert_new(seen, {{Jid, Text}}).

但是有一个问题！该表由进程拥有，并在进程终止时被删除。它的名字是全局的等等。另一个更脏的方法是从进程字典中存储和读取值。

has_dupes(Jid, Text) ->
    case get({Jid, Text}) of
        undefined ->
            put({Jid, Text}, seen),
            false;
        seen ->
            true
    end.

但这很讨厌，你几乎不应该使用这样的代码。在大多数情况下，您应该使用显式状态

new_seen() -> [].

has_dupes(Jid, Text, Seen) ->
    Term = {Jid, Text},
    case lists:member(Term, Seen) of
        true  -> {true, Seen};
        false -> {false, [Term|Seen]}
    end.

这是大多数时候最好的解决方案，因为它是一个纯函数。当您需要查看更多术语时，您可以使用更好的数据结构，例如sets并获得更好的性能。maps

于 2016-03-12T18:45:43.267 回答