4

想象有一个重复的组件模式（例如，动态管道），它具有一个参数（例如，长度），该参数将根据其所在模式的位置而改变。我建议可以通过在感兴趣的参数之前省略“每个”前缀来实现。

例如。让我们通过以下方式获取管道并将它们添加到模型中：

parameter Integer n;
Modelica.Fluid.Pipes.DynamicPipe[n] pipe;

对于一个非常简单的示例，让我们指定我们希望模式中第一个管道的长度具有某个长度（length_1），而所有其他管道的长度都具有 length_n。我的想法是，可以在以下列方式定义参数时放置一个 if 语句，以便将 length_1 分配给 n=1 管道组件，而将所有其他组件分配给 length_n：

parameter Integer n;
Modelica.Fluid.Pipes.DynamicPipe[n] pipe(
length=if n<2 then length_1 else cat(1,length_1,fill(length_n,n-1)));

上述框架中的一个简单模型如下所示：

model Test

  parameter Integer n(min=1);
  parameter Modelica.SIunits.Length length_1 = 0.1;
  parameter Modelica.SIunits.Length length_n = 0.2;

  Modelica.Fluid.Pipes.DynamicPipe[n] pipe(
    redeclare each package Medium = Modelica.Media.Water.StandardWater,
    each modelStructure=Modelica.Fluid.Types.ModelStructure.av_b,
    each diameter=1,
    length=if n==1 then length_1 else cat(1,length_1,fill(length_n,n-1)));

  Modelica.Fluid.Sources.Boundary_pT boundary(
    nPorts=1,
    redeclare package Medium = Modelica.Media.Water.StandardWater,
    p=100000,
    T=293.15);

  Modelica.Fluid.Sources.MassFlowSource_T boundary1(
    nPorts=1,
    redeclare package Medium = Modelica.Media.Water.StandardWater,
    m_flow=1,
    T=293.15);

  inner Modelica.Fluid.System system(m_flow_start=1, T_start=293.15);

equation 
if n == 1 then
  connect(boundary1.ports[1], pipe[1].port_a);
  connect(boundary.ports[1], pipe[1].port_b);

else

  connect(boundary1.ports[1], pipe[1].port_a);
  for i in 1:n-1 loop
    connect(pipe[i].port_b, pipe[i+1].port_a);
  end for;

  connect(boundary.ports[1], pipe[n].port_b);
end if;

end Test;

就目前而言，该模型不起作用。我不确定 if 语句的构造方式是否错误，或者这是否根本不允许（如果我对“每个”前缀的解释有误，可能就是这种情况）。

有什么想法吗？

4

1 回答 1

2

首先感谢 matth 将我指向 Mike Tiller 书中的钟摆示例。

下面是修改代码以实现重复组件模式的两种可能方法，其中参数以某种预定方式发生变化。该错误与定义长度数组的方式有关。

选项1：

更换

length=if n==1 then length_1 else cat(1,length_1,fill(length_n,n-1))

和

length={if i==1 then length_1 else length_n for i in 1:n}

选项#2：

已插入

final parameter Modelica.SIunits.Length[n] 
                lengths_pipe = {if i==1 then length_1 else length_n for i in 1:n};

并更换

... length=lengths_pipe

下面是使用第二个选项的完整工作代码：

model Test

  parameter Integer n(min=1)=2;
  parameter Modelica.SIunits.Length length_1 = 0.1;
  parameter Modelica.SIunits.Length length_n = 0.2;

  final parameter Modelica.SIunits.Length[n] lengths_pipe = {if i==1 then length_1 else length_n for i in 1:n};

  Modelica.Fluid.Pipes.DynamicPipe[n] pipe(
    redeclare each package Medium = Modelica.Media.Water.StandardWater,
    each modelStructure=Modelica.Fluid.Types.ModelStructure.av_b,
    each diameter=1,
    length=lengths_pipe);

  Modelica.Fluid.Sources.Boundary_pT boundary(
    nPorts=1,
    redeclare package Medium = Modelica.Media.Water.StandardWater,
    p=100000,
    T=293.15);

  Modelica.Fluid.Sources.MassFlowSource_T boundary1(
    nPorts=1,
    redeclare package Medium = Modelica.Media.Water.StandardWater,
    m_flow=1,
    T=293.15);

  inner Modelica.Fluid.System system(m_flow_start=1, T_start=293.15);

equation 
if n == 1 then
  connect(boundary1.ports[1], pipe[1].port_a);
  connect(boundary.ports[1], pipe[1].port_b);

else

  connect(boundary1.ports[1], pipe[1].port_a);
  for i in 1:n-1 loop
    connect(pipe[i].port_b, pipe[i+1].port_a);
  end for;

  connect(boundary.ports[1], pipe[n].port_b);
end if;

  annotation (uses(Modelica(version="3.2.1")));
end Test;
于 2016-03-14T13:41:13.377 回答