1

比如说，我有一个超过 GF(2) 的多项式 p(x) 和一个超过 GF(4) 的多项式 g(x)。例如，

gf2 = gf(2, 1);
gf4 = gf(2, 2);

p2 = Polrev(vector(5, i, random(gf2)));
p4 = Polrev(vector(7, i, random(gf4)));

p2 * p4
>> ***   at top-level: p2*p4
>> ***                   ^---
>> *** _*_: inconsistent multiplication t_FFELT * t_FFELT.

在这种情况下，pari-gp 是否提供任何东西来进行？如果不是，我该如何进行所需的嵌入？

4

1 回答 1

2

不幸的是，解决方案是你自己的。PARI/GP 没有为有限域嵌入提供任何东西。出于我的目的，我为有限域嵌入开发了以下函数：

get_gf_embedding(f: t_FFELT, g: t_FFELT) =
{
    if(f.p != g.p,
        error("** get_gf_embedding: fields are of different characterisitics")
    );
    if(f.p != g.p || poldegree(g.mod) % poldegree(f.mod) != 0,
        error("** get_gf_embedding: finite fields are not embeddable")
    );

    my (smaller_field_min_poly = subst(f.mod, variable(f.mod), 'x));
    my (larger_field_min_poly = subst(g.mod, variable(g.mod), 'y));
    my (subfield_prim =
        g^0 *
        subst(
            polrootsff(smaller_field_min_poly, f.p, larger_field_min_poly)[1].pol,
            'y,
            g
        )
    );
    embedding(elt) =
        subfield_prim^0 * subst((f^0 * elt).pol, variable((f^0 * elt).pol), subfield_prim)
};

有关算法的详细信息，请参阅http://johnkerl.org/doc/ffcomp.pdf（第 5.11 节）。使用上面的代码你必须重写你的代码如下：

embed = get_gf_embedding(gf2, gf4);
Polrev(apply(embed, Vecrev(p2))) * p4
于 2016-02-17T22:40:24.373 回答