1

我有的

我正在尝试制作一个测试台，其中包含一行文件，其中可能的字符是“1”和“0”。我必须全部阅读它们，并在我的 DUT 中一一使用作为输入。

因此，在我的 TB 中，我定义了一个如下所示的过程，以便读取文件并将其值传递给我的 DUT。

stim_proc: process

 file input_file: TEXT is in "DatosEntrada.dat";

 variable rdline : LINE;
 variable line_content : string ( 1 to 4);
 variable readed_char : character;

 variable j : integer := 0;

begin       

 while not endfile(input_file) loop

   readline(input_file, rdline);

   --read(rdline, line_content);

   for j in 1 to rdline'length-1 loop

     readed_char := line_content(j);

     if (readed_char = '1') then
       input <= '1';
     else
       input <= '0'; 
     end if;

     wait for clk_period;

   end loop;

 end loop;

end process;

我认为正在发生的事情

我正在第一次readline执行时读取文件的第一行（也是唯一一行）。在此之后，此循环不应再次执行。

然后，文件中的数据应该在里面rdline。所以我必须处理它。为了做到这一点，我试图循环rdline长度，但这个循环不执行。

for j in 1 to rdline'length-1 loop

所以我想我需要阅读这一行以便循环它，并试图将它的数据移动到一个stringvar。问题是 vector var like string 需要有一个定义的大小，我不知道文件行大小。

我试过什么

我尝试了不同的方法来完成它，比如每次将 4 个字符从rdline一个字符串中读取，处理它，然后重复。但是，我无法让它工作。

我在 Google 上找到了很多关于使用 VHDL 读取文件的示例，但它们都非常相似，并且都定义了行格式，例如列或预期的整数，其中我只有一行的未知文本。

我想这可以通过rdline以某种方式读取 var 来实现，但我无法实现。你能帮我写代码吗？

先感谢您

4

1 回答 1

3

您的示例不是MCVE。

当 line_content 未加载时，这readed_char := line_content(j);不起作用。否则，您读取值的尝试基本上是合理的。

行尾不包含在读取的 LINE 缓冲区中，没有理由不读取 rdline 的最后一个字符。行尾由一个或多个除水平制表符之外的格式效应器发出信号，并且仅存在行内容。

还有一个推论是，您与时钟边沿有某种关系，而不仅仅是时钟周期。下面的例子说明了这一点。请注意，您还可以使用wait for time_value.

在循环语句中声明了一个循环常量。j您声明的变量与j循环使用的变量不同。循环语句隐藏j在外部声明区域（过程语句中的变量声明）。

您的代码将字符串缓冲区中除“1”以外的任何其他字符视为“0”。我没有改变它，做演示它。您应该意识到影响。

LINE 是一个分配的字符串，其长度取决于读取文件中行的长度。每次调用 readline 时，都会更新 rdline 指向的字符串。它不会泄漏内存，先前的缓冲区 rdline 指向已释放。您可以使用 'RIGHT 属性读取长度，或者在本例中简单地使用所有字符。

VHDL 工具实现中可能存在行长度限制。除了字符串的最大长度（POSITIVE'RIGHT）之外，标准中没有定义。

一个 MCVE：

library ieee;
use ieee.std_logic_1164.all;
use std.textio.all;

entity foo is
end entity;

architecture fum of foo is
    signal input:           std_logic ;
    signal clk:             std_logic := '0';
    constant clk_period:    time := 10 ns;
begin

stim_proc: 
    process
        file input_file: TEXT is in "DatosEntrada.dat";
            variable rdline:    LINE;
            -- variable line_content : string ( 1 to 4);
            -- variable readed_char : character;
            -- variable j:         integer := 0;
    begin       
        while not endfile(input_file) loop
            readline(input_file, rdline);
            --read(rdline, line_content);
            -- for j in 1 to rdline'length - 1 loop -- EOL not in rdline
            for j in rdline'range loop
                -- readed_char := line_content(j);
                -- if readed_char = '1' then
                if rdline(j) = '1' then   -- changed
                    input <= '1';
                else
                    input <= '0'; 
                end if;
                -- wait for clk_period;  -- sync to edge instead
                wait until falling_edge(clk); -- input related to clk edge
            end loop;
        end loop;
        wait;     -- added prevents needless loops
    end process;

CLOCK:
    process
    begin
        wait for clk_period/2;
        clk <= not clk;
        if now > 32 * clk_period then
            wait;
        end if;
    end process;

end architecture;

对于 DatosEntrada.dat 包含：

11011110001你好11230000

这会产生：

foo.png

您可以看到所有非“1”字符都被解释为“0”。

于 2016-02-04T20:21:33.997 回答