2

我正在学习 Common Lisp，想玩 lisp 和 Web 开发。我目前的问题来自一个简单的想法，即遍历我想要包含的所有 javascript 文件。我使用 SBCL 和 Quicklisp 来快速启动。问题可能与cl-who我正在使用的包有关。

所以我已经声明了我的包裹并开始这样：

(defpackage :0xcb0
  (:use :cl :cl-who :hunchentoot :parenscript))
(in-package :0xcb0)

为了简单起见，我减少了问题函数。所以我有这个page功能：

(defun page (test)
  (with-html-output-to-string
    (*standard-output* nil :prologue nil :indent t)
    (:script
     (:script :type "text/javascript" :href test))))

这将产生所需的输出

*(0xcb0::page "foo")

<script>
   <script type='text/javascript' href='foo'></script>
</script>

现在我创建了一个生成:script标签的宏。

(defmacro js-source-file (filename)
  `(:script :type "text/javascript" :href ,filename)))

这按预期工作：

*(macroexpand-1 '(0XCB0::js-source-file "foo"))

(:SCRIPT :TYPE "text/javascript" :HREF "foo")

但是，如果我将其包含在我的page函数中：

(defun page (test)
  (with-html-output-to-string
    (*standard-output* nil :prologue nil :indent t)
    (:script
     (js-source-file "foo"))))

undefined function: :SCRIPT...定义新page函数时，它会给我一个样式警告（ ）。此外，该page函数在执行时会产生此错误：

*(0xcb0::page "foo")

The function :SCRIPT is undefined.
   [Condition of type UNDEFINED-FUNCTION]

为什么嵌入式宏js-source-file按预期工作，因为它产生所需的输出，但在另一个函数中调用时失败？

PS 我知道对于像我这样的初学者来说，Lisp 中的宏主题可能会让人筋疲力尽。但目前我无法理解这应该有效但没有用的事实！

4

2 回答 2

8

问题是宏按从外到内的顺序被直观地扩展了一点。例如：

(defmacro foobar (quux)
  (format t "Foo: ~s~%" quux))

(defmacro do-twice (form)
  `(progn
     ,form
     ,form))

(foobar (do-twice (format t "qwerty")))

输出将是

Foo: (DO-TWICE (FORMAT T "qwerty"))

foobar永远看不到do-twice. macroexpand你可以通过调用自己来避免这个问题foobar：

(defmacro foobar (quux)
  (format t "Foo: ~s~%" (macroexpand quux)))

(foobar (do-twice (format t "qwerty")))
; => Foo: (PROGN (FORMAT T "qwerty") (FORMAT T "qwerty"))

由于您使用的是第三方宏，这可能不是一个好的解决方案。我认为最好的选择是自己在js-source-file. 我不熟悉cl-who，但这似乎在我的快速测试中有效：

(defun js-source-file (filename stream)
  (with-html-output (stream nil :prologue nil :indent t)
    (:script :type "text/javascript" :href filename))))

(defun page (test)
  (with-output-to-string (str)
    (with-html-output (str nil :prologue nil :indent t)
      (:script
       (js-source-file test str)))))
于 2016-01-30T15:22:43.770 回答
4

除了其他好的答案，我将介绍with-html-output. 这源自cl-who手册的语法和语义部分。

首先，请注意，如果您自己对调用进行宏扩展，您可以看到它with-html-output建立了macrolet诸如str, htm, ftm, esc... 之类的绑定htm。macrolet 不接受任何参数（主体除外）并扩展为with-html-output具有相同参数的形式具有词法封闭的with-html-output宏. 为了修复您的代码，您可以按如下方式修改宏：

(defmacro js-source-file (filename)
  `(htm (:script :type "text/javascript" :href ,filename)))

然后：

  1. with-html-output被扩展成一棵树，其中包含(js-source-file ...)
  2. 您的宏被扩展并产生一个(htm (:script ...))表格。
  3. 然后，宏程序被扩展以产生内部(with-html-output ...)形式。
  4. 内部with-html-output被扩展和处理(:script ...)。

您必须选择是否更喜欢在此处使用宏或函数。函数通常不是内联的，并且可以在运行时轻松地重新定义。宏理论上也可以在运行时扩展，但在大多数实现（和默认配置）中，您必须重新编译依赖于宏的任何函数。您也可以让宏调用辅助函数。

于 2016-01-30T16:45:42.043 回答