coldfusion - 基于脚本的组件中的线程不起作用

Question

当我在下面注释掉与线程相关的代码时，向 slack API 的提交按预期工作。但是，当我尝试在线程命令中处理提交时，提交永远不会通过。

难道我做错了什么？在Railo 4中运行

// push to slack!
public function push(options = {}) {

    var http = new http();
    var data = {
        "text": "Default message",
        "channel": "activity"
    };

    structAppend(data, options);

    // thread
    //  action="run" {

        sleep(5000);

        http.setMethod("post");
        http.setUrl(variables.slackWebhookUrl);
        http.addParam(
            type = "formField",
            name = "payload",
            value = serializeJson(data)
        );

        http.send();

    // }

}

Answer 1

感谢 Adam Cameron 为我指明了正确的方向。事实证明，使用 cfthreads 确定范围非常棘手。

为了简洁起见，我只是说我以后在使用线程时会遵循这些规则：

1. 不要从“线程块”之外的范围内引用任何变量
2. 将您需要引用的任何“父范围”数据显式传递给线程
3. 基本上将 cfthread 视为 cfmodule（通过属性传递数据）

这是工作代码：

    // push to slack!   
    public function push(options = {}) {

        var data = {
            "text": "Default message",
            "channel": "activity"
        };

        structAppend(data, options);

        thread
            action="run"
            data="#data#"
            slackUrl="#variables.slackWebhookUrl#" {

            var http = new http();

            http.setMethod("post");
            http.setUrl(attributes.slackUrl);
            http.addParam(
                type = "formField",
                name = "payload",
                value = serializeJson(attributes.data)
            );

            http.send();

        }

    }