5

我正在尝试gperf从cmake文件中运行。

我在下面创建了一个非常小的CMakeLists.txt。

当我运行它时

$ cmake .
$ make

它不创建example.hpp文件

下面可能有什么问题CMakeLists.txt？

cmake_minimum_required( VERSION 2.6 )

function(gperf_generate_new source target)

        add_custom_target(${target} echo "Creating ${target}")

        add_custom_command(
                SOURCE ${source}
                TARGET ${target}
                COMMAND gperf -L c++ ${source} > ${target}
                OUTPUTS ${target}
                DEPENDS ${source}
                )

endfunction()

gperf_generate_new(command_options.new.gperf example.hpp)
4

1 回答 1

3

由源文件生成器（如gpref）生成的文件很少需要单独使用。相反，这些源文件通常用于在项目中创建可执行文件或库。

因此，在 CMake 中使用源文件生成器的标准模式如下所示：

# Call add_custom_command() with appropriate arguments for generate output file
# Note, that *gperf* will work in the build tree,
# so for file in the source tree full path should be used.
function(gperf_generate_new input output)
    add_custom_command(
        OUTPUT ${output}
        COMMAND gperf -L c++ ${input} > ${output}
        DEPENDS ${input}
        COMMENT "Generate ${output}" # Just for nice message during build
    )
endfunction()

# Generate *example.hpp* file ...
gperf_generate_new(${CMAKE_CURRENT_SOURCE_DIR}/command_options.new.gperf example.hpp)

# ... for use it in executable
add_executable(my_program ${CMAKE_CURRENT_BINARY_DIR}/example.hpp <other sources>)

如果您只想测试是否example.hpp正在生成，而不是add_executable()使用

add_custom_target(my_target
    ALL # Force target to be built with default build target.
    DEPENDS ${CMAKE_CURRENT_BINARY_DIR}/example.hpp
)

请注意， 和 之间的链接add_custom_command在其和选项中相应add_custom_target地使用相同的文件名表示。这些命令的这种链接顺序是微不足道的（但应该从同一个脚本调用这两个命令）。OUTPUTDEPENDSCMakeLists.txt

于 2015-10-13T07:59:11.423 回答