0

现在我有一个如下的 XML 文件：

<DM Name="A DM"> 
  <DV  id="SQL:Select something from db" Name="DV 1"> 
    <Sample aid="SQL:Select something from db" /> 
  </DV> 
  <DV  id="SQL:Select something from db" Name="DV 2"> 
    <Sample aid="SQL:Select something from db" name ="DC"> 
      good 
    </Sample> 
  </DV> 
</DM>

我想用一个XSLT来转换它，这个tamplet中有一个参数来确定应该转换哪个DV：如果参数（$dvIndex = 0），那么只需保留所有元素和属性，只需转换attriform属性以“SQL:”开头的值，如果（$dvindext > 0），只需转换特定的DV，（删除其他DV）。现在我写XSLT如下，但它错过了DM的属性，我不知道如何复制DM的属性。不知道有没有更好的解决办法。XML 文件：

<?xml version="1.0" encoding="utf-8"?>
<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
    xmlns:msxsl="urn:schemas-microsoft-com:xslt" exclude-result-prefixes="msxsl"
    xmlns:user="urn:my-scripts"
>
  <xsl:output method="xml" indent="yes"/>
  <msxsl:script language="C#" implements-prefix="user">
    <![CDATA[
     public string UpperCase(string value){
      return value.ToUpper();
     }
      ]]>
  </msxsl:script>

  <xsl:param name="dvIndex" select="2" />

  <xsl:template match="DM" >
    <xsl:copy>
      <xsl:choose>
        <xsl:when test="$dvIndex > 0">
          <xsl:apply-templates select="DV[$dvIndex]"/>
        </xsl:when>
        <xsl:otherwise>
          <xsl:copy>
            <xsl:apply-templates select="@*|node()"/>
          </xsl:copy>
        </xsl:otherwise>
      </xsl:choose>
    </xsl:copy>
  </xsl:template>

  <xsl:template match="@*|node()">
    <xsl:copy>
      <xsl:apply-templates select="@*|node()"/>
    </xsl:copy>
  </xsl:template>

  <!--[starts-with(translate(substring(.,1,4),'SQL:','sql:'),'sql:')]-->
  <xsl:template match="@*[user:UpperCase(substring(.,1,4))='SQL:']">
    <xsl:attribute name="{name()}">
      <xsl:value-of select="'parsedSQL'"/>
    </xsl:attribute>
  </xsl:template>
</xsl:stylesheet>

这个问题也和我的问题2#有关（How to only convert an XML file's attribute using XSLT, and leave the other content?）

非常感谢！

4

2 回答 2

1

这个样式表：

<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
    <xsl:output method="xml" indent="yes"/>
    <xsl:param name="dvIndex" select="2" />
    <xsl:template match="DM" >
        <xsl:copy>
            <xsl:apply-templates select="@*|DV[$dvIndex]"/>
        </xsl:copy>
    </xsl:template>
    <xsl:template match="@*|node()">
        <xsl:copy>
            <xsl:apply-templates select="@*|node()"/>
        </xsl:copy>
    </xsl:template>
    <xsl:template match="@*[starts-with(translate(substring(.,1,4),'SQL:','sql:'),'sql:')]">
        <xsl:attribute name="{name()}">
            <xsl:value-of select="'parsedSQL'"/>
        </xsl:attribute>
    </xsl:template>
</xsl:stylesheet>

结果：

<DM Name="A DM">
<DV id="parsedSQL" Name="DV 2">
<Sample aid="parsedSQL" name="DC">
      good
    </Sample>
</DV>
</DM>

dvIndex使用参数0：

<DM Name="A DM"></DM>

注意：避免脚本：它不是标准的，每次使用它都会强制加载脚本引擎。

编辑：如果你想DV在 $dvIndex 为 0 时处理每个，那么这个样式表：

<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
    <xsl:output method="xml" indent="yes"/>
    <xsl:param name="dvIndex" select="2" />
    <xsl:template match="DM" >
        <xsl:copy>
            <xsl:apply-templates select="@*|DV[$dvIndex]|DV[not($dvIndex)]"/>
        </xsl:copy>
    </xsl:template>
    <xsl:template match="@*|node()">
        <xsl:copy>
            <xsl:apply-templates select="@*|node()"/>
        </xsl:copy>
    </xsl:template>
    <xsl:template match="@*[starts-with(translate(substring(.,1,4),'SQL:','sql:'),'sql:')]">
        <xsl:attribute name="{name()}">
            <xsl:value-of select="'parsedSQL'"/>
        </xsl:attribute>
    </xsl:template>
</xsl:stylesheet>

$dvIndex 为 0 时，输出：

<DM Name="A DM">
<DV id="parsedSQL" Name="DV 1">
<Sample aid="parsedSQL"></Sample>
</DV>
<DV id="parsedSQL" Name="DV 2">
<Sample aid="parsedSQL" name="DC">
      good
    </Sample>
</DV>
</DM>
于 2010-07-21T19:07:16.607 回答
0

以下可能满足您的需求。注意附加<xsl:apply-templates select="@*" />复制属性。

<?xml version="1.0" encoding="utf-8"?>
<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
    xmlns:msxsl="urn:schemas-microsoft-com:xslt" exclude-result-prefixes="msxsl"
    xmlns:user="urn:my-scripts">

  <xsl:output method="xml" indent="yes"/>
  <msxsl:script language="C#" implements-prefix="user">
    <![CDATA[
     public string UpperCase(string value){
      return value.ToUpper();
     } ]]>
  </msxsl:script>

  <xsl:param name="dvIndex" select="0" />

  <xsl:template match="DM" >
    <xsl:copy>
      <xsl:apply-templates select="@*" />
      <xsl:choose>
        <xsl:when test="$dvIndex > 0">
          <xsl:apply-templates select="DV[$dvIndex]"/>
        </xsl:when>
        <xsl:otherwise>
            <xsl:apply-templates select="DV"/>
        </xsl:otherwise>
      </xsl:choose>
    </xsl:copy>
  </xsl:template>

  <xsl:template match="@*|node()">
    <xsl:copy>
      <xsl:apply-templates select="@*|node()"/>
    </xsl:copy>
  </xsl:template>

  <!--[starts-with(translate(substring(.,1,4),'SQL:','sql:'),'sql:')]-->
  <xsl:template match="@*[user:UpperCase(substring(.,1,4))='SQL:']">
    <xsl:attribute name="{name()}">
      <xsl:value-of select="'parsedSQL'"/>
    </xsl:attribute>
  </xsl:template>
</xsl:stylesheet>
于 2010-07-21T17:59:58.673 回答