prolog - 在 Prolog 中计算确定子句语法递归

Question

我有以下 Prolog 定句语法：

s-->[a],s,[b].
s-->[].

这将导致像 [a,a,b,b] 这样的单词被接受，而不是像 [a,b,a,b] 这样的单词。简而言之，语法显然是 a^nb^n。现在我想将 n 返回给用户。我如何计算n？

Answer 1

s(X)-->[a],s(Y),[b],{X is Y+1}.
s(0)-->[].

需要给DCG非终端参数。请注意平等与命令式编程语言的分配并不完全相同，因此使用了 X is Y + 1。

一些示例输出：

s(X,[a,b,b,b],[]).
false.

s(X,[a,a,a,b,b,b],[]).
X = 3 ;
false.

Answer 2

s(N, M) --> [a], {N1 is N + 1}, s(N1, M), [b].
s(N, N) --> [].
s(N) --> s(0, N).

用法：

?- phrase(s(N), [a,a,a,b,b,b]).
N = 3

Answer 3

@thequark和@LittleBobbyTables的答案在与接地字符串一起使用时效果很好。

但是，如果它们的长度没有限制，比如下面的查询，该怎么办？

?- phrase(s(3),_).               % expected: success   
%                                  observed: no answer(s)

?- phrase(s(-10),_).             % expected: failure
%                                  observed: no answer(s)

我们当然希望像上面这样的查询普遍终止！让我们使用clpfd并编写：

:- use_module(library(clpfd)).

s(0) --> [].
s(N) --> {N#>0,N#=N0+1},[a],s(N0),[b].

示例查询：

?- phrase(s(N),[a,a,a,a,b,b,b,b]).
N = 4 ;                          % works like in the other answers
false.

?- phrase(s(3),Xs).
Xs = [a,a,a,b,b,b] ;             % now, this works too!
false.                           % (terminates universally)

?- phrase(s(-10),_).             % fails, like it should
false.