4

我每时每刻都在阅读按钮的状态（无论是否按下）：

readButton :: IO Boolean
readButton = ...

main = do
    (add, fire) <- newAddHandler
    network <- compile (desc add)
    actuate network
    forever $ do
        buttonState <- readButton
        fire buttonState

desc addButtonEvent = do
    eButtonState <- fromAddHandler addButtonEvent
    ...

所有读取状态都存储eButtonState在网络描述中desc。

当前时刻的状态1与前一时刻的状态相同时，该按钮被认为是新按下的0。因此，如果事件序列是一个列表，则函数将这样编写：

f :: [Bool] -> Bool
f (True:False:_) = True
f _              = False

我想应用这个功能，eButtonState所以我会知道按钮是否是新按下的。

有可能吗？你会怎么做？如果有更好或更常见的想法或方法来实现这一目标，我将不胜感激。

4

1 回答 1

3

这是一种方法（这是一个可运行的演示）：

import Reactive.Banana
import Reactive.Banana.Frameworks
import Control.Monad
import Control.Applicative -- Needed if you aren't on GHC 7.10.

desc addDriver = do
    -- Refreshes the button state. Presumably fired by external IO.
    eButtonDriver <- fromAddHandler addDriver
    let -- Canonical repersentation of the button state.
        bButtonState = stepper False eButtonDriver
        -- Observes the button just before changing its state.
        ePreviousState = bButtonState <@ eButtonDriver
        -- Performs the test your f function would do.
        newlyPressed :: Bool -> Bool -> Bool
        newlyPressed previous current = not previous && current
        -- Applies the test. This works because eButtonDriver and
        -- ePreviousState are fired simultaneously.
        eNewlyPressed = unionWith newlyPressed
            ePreviousState eButtonDriver
        -- The same but more compactly, without needing ePreviousState.
        {-
        eNewlyPressed = newlyPressed <$> bButtonState <@> eButtonDriver
        -}
    reactimate (print <$> eNewlyPressed)

main = do
    (addDriver, fireDriver) <- newAddHandler
    network <- compile (desc addDriver)
    actuate network
    -- Demo: enter y to turn the button on, and any other string to
    -- turn it off.
    forever $ do
        buttonState <- (== "y") <$> getLine
        fireDriver buttonState

笔记：

  • 事件是暂时的，行为是永久的，这是决定您是否需要行为或事件流的一个很好的一般规则。在这种情况下，您需要查看更新前的按钮状态，以确定它是否是新更新的。因此，很自然的做法是用行为 ( bButtonState) 来表示按钮状态，该行为由外部触发的事件 ( eButtonDriver) 更新。
  • 有关组合器在做什么的详细信息，请参阅Reactive.Banana.Combinators。
  • 有关响应式香蕉中事件和行为更新时间的详细信息，请参阅此问题。
  • 根据您要执行的操作，该changes功能可能很有用。请注意文档中提到的与之相关的警告。
于 2015-07-27T19:54:29.320 回答