5

使用 Delphi XE7 Update 1 和 Delphi XE8 测试

在 Windows OS (7 SP1 x64)、MACOSX (10.10.3) 和 Android (5.0.2) 上创建订单：

    "class constructor TGlobalClass.Create;" -> "constructor TfmMain.Create;" -> "procedure TfmMain.FormCreate(Sender: TObject);"

Windows OS 和 MACOSX 的发布命令：

    "TfmMain.FormDestroy" -> "destructor TfmMain.Destroy" -> "class destructor TGlobalClass.Destroy;"

Android上的发布顺序：

    "class destructor TGlobalClass.Destroy;" -> "TfmMain.FormDestroy" -> "destructor TfmMain.Destroy"

问题是：为什么在 Android 平台上 CLASS VAR 在主窗体之前发布？

代码示例：

unit uClassVar;

interface

type
  TGlobalClass = class
    class var F1: Integer;

    class constructor Create;
    class destructor Destroy;
  end;

implementation

{ TX }

class constructor TGlobalClass.Create;
begin
  { Breakpoint there }
  F1 := 100;
end;

class destructor TGlobalClass.Destroy;
begin
  { Breakpoint there }
  F1 := 200;
end;

end.

主要单位：

unit ufmMain;

interface

uses
  System.SysUtils, System.Types, System.UITypes, System.Classes, System.Variants,
  FMX.Types, FMX.Controls, FMX.Forms, FMX.Graphics;

type
  TfmMain = class(TForm)
    procedure FormCreate(Sender: TObject);
    procedure FormDestroy(Sender: TObject);
  private
    { Private declarations }
  public
    { Public declarations }
    constructor Create(AOwner: TComponent); override;
    destructor Destroy; override;
  end;

var
  fmMain: TfmMain;
  z: Integer;

implementation

uses
  uClassVar;

{$R *.fmx}

constructor TfmMain.Create;
begin
  { Breakpoint there }
  inherited;
end;

destructor TfmMain.Destroy;
begin
  { Breakpoint there }
  inherited;
end;

procedure TfmMain.FormCreate(Sender: TObject);
begin
  { Breakpoint there }
  TGlobalClass.F1 := -99999;
end;

procedure TfmMain.FormDestroy(Sender: TObject);
begin
  { Breakpoint there }
  z := 200;
end;

end.

项目文件：

program ClassVar;

uses
  System.StartUpCopy,
  FMX.Forms,
  ufmMain in 'ufmMain.pas' {fmMain},
  uClassVar in 'uClassVar.pas';

{$R *.res}

begin
  Application.Initialize;
  Application.CreateForm(TfmMain, fmMain);
  Application.Run;
end.
4

3 回答 3

5

桌面编译器

当应用程序对象销毁其组件时，您的主窗体将被销毁。这发生在FMX.Forms程序中DoneApplication。

procedure DoneApplication;
begin
  if Screen <> nil then
    Screen.ActiveForm := nil;
  Application.DestroyComponents;  <-- this is destroying your main form
end;

并DoneApplication在关机期间作为退出过程调用。该退出过程是TApplication.Run这样注册的：

{$IFNDEF ANDROID}
  AddExitProc(DoneApplication);
{$ENDIF}

类构造函数是从定义它们的单元的初始化部分调用的。因此，TGlobalClass.Create从 的初始化中调用uClassVar。类析构函数是从同一单元的终结部分调用的。

系统关闭由 中的System单元执行_Halt0。它在执行单元完成之前执行所有退出过程。因此，您的表单在调用类析构函数之前被销毁。

移动编译器

请注意，DoneApplication在 Android 上根本不会调用它。

{$IFNDEF ANDROID}
  AddExitProc(DoneApplication);
{$ENDIF}

这意味着主窗体的销毁是从单元完成调用的。随着每个单元的最终确定，它的终结部分被执行，这导致任何全局变量离开范围。最终，不再有对主窗体的引用，因此它的析构函数被执行。

如上所述，类析构函数也从单元终结中调用。由于在 Android 上，您的类析构函数在主窗体被销毁之前执行，因此很明显可以uClassVar在主窗体的最终引用被释放之前完成。

现在，这很有意义，因为uClassVar它是初始化顺序中的最后一个单元，因此是完成顺序中的第一个单元。如果您想确保uClassVar稍后完成，您需要安排它尽快初始化。例如，通过更改 .dpr 文件的 uses 子句，如下所示：

uses
  uClassVar in 'uClassVar.pas',  
  System.StartUpCopy,
  FMX.Forms,
  ufmMain in 'ufmMain.pas' {fmMain};

现在uClassVar是第一个单元初始化，因此最后一个单元完成。

于 2015-06-26T09:54:06.143 回答
0

该程序：

program Destructors;

{$APPTYPE CONSOLE}

{$R *.res}

uses
  System.SysUtils,
  Unit1 in 'Unit1.pas',
  Unit2 in 'Unit2.pas';

var
  X: TUnit1;
begin
  x := TUnit1.Create;
  x.Free;
  Writeln('Begin');
end.

单元1：

unit Unit1;

interface

uses
  System.Classes, Unit2;

type
  TUnit1 = class
  public class var
    X: TUnit2;
  public
    class constructor Create;
    class destructor Destroy;
    destructor Destroy; override;
  end;

implementation

{ TUnit1 }

class constructor TUnit1.Create;
begin
  X := TUnit2.Create;
end;

class destructor TUnit1.Destroy;
begin
  X.Free;
  Writeln('TUnit1.Destroy');
end;

destructor TUnit1.Destroy;
begin
  Writeln('Unit1.Destroy');
  inherited;
end;

end.

单元2：

unit Unit2;

interface

uses
  System.Classes;

type
  TUnit2 = class
  public class var
    X: TComponent;
  public
    class constructor Create;
    class destructor Destroy;
    destructor Destroy; override;
  end;

implementation

{ TUnit2 }

class constructor TUnit2.Create;
begin
  X := TComponent.Create(nil);
  X.Name := ClassName;
end;

class destructor TUnit2.Destroy;
begin
  X.Free;
  Writeln('TUnit2.Destroy');
end;

destructor TUnit2.Destroy;
begin
  Writeln('Unit2.Destroy');
  inherited;
end;

end.

Unit2 包含在项目文件中作为最后一个单元，但它不会首先完成，因为 Unit1 使用 Unit2 - 因此初始化顺序与“预期”不同。

输出如下：

Begin
Unit2.Destroy
TUnit1.Destroy
TUnit2.Destroy

我不确定为什么在这种情况下移动编译器会做一些不同的事情......

于 2015-06-26T10:49:22.730 回答
-1

您正在使用DisposeOf免费组件

不要用作.Free或.Destroy

例子：

Scrollbox1.Components[1].DisposeOf;
于 2015-09-22T06:49:55.487 回答