1

我根本不熟悉 XML/XSLT。我只是想学习足够的知识来将此 XML 文件转换为我的 Access 数据库可以使用的东西。XML 数据以属性格式输出，Access 只喜欢元素格式。我已经完成了基本的转换，但我似乎无法对嵌套数据进行元素化。

我希望最终结果是所有元素。目前我的 XSLT 脚本正在尝试在子元素的名称中包含 parental name 属性，但这可能不是必需的。如果我可以在列表元素的名称中编号，那就太棒了。如“AuthorList1”、“AuthorList2”或“Author1”、“Author2”。

这是我正在处理的 XML 类型（缩写）：

XML

<Result>
<DocSum>
<Id>25587056</Id>
<Item Name="PubDate" Type="Date">2015 Jan 13</Item>
<Item Name="EPubDate" Type="Date">2015 Jan 13</Item>
<Item Name="Source" Type="String">Invest Ophthalmol Vis Sci</Item>
<Item Name="AuthorList" Type="List">
    <Item Name="Author" Type="String">Wang Q</Item>
    <Item Name="Author" Type="String">Tuten WS</Item>
    <Item Name="Author" Type="String">Lujan BJ</Item>
</Item>
<Item Name="Title" Type="String">Adaptive optics microperimetry</Item>
<Item Name="Volume" Type="String">56</Item>
<Item Name="ArticleIds" Type="List">
    <Item Name="pubmed" Type="String">25587056</Item>
    <Item Name="pii" Type="String">iovs.14-15576</Item>
    <Item Name="doi" Type="String">10.1167/iovs.14-15576</Item>
</Item>
<Item Name="References" Type="List"></Item>
<Item Name="HasAbstract" Type="Integer">1</Item>
</DocSum>
</Result

我在 XSLT 方面已经取得了相当大的进展，但我还没有走到那一步。不断出现的一个问题是空元素（如引用）获得不允许的空名称。当我尝试使用“Item[@Type='List']”的匹配模式执行命令时，就会发生这种情况。此外，我似乎无法让列表的子节点（元素？）成为他们自己的元素。

XSLT

<xsl:stylesheet xmlns:xsl="http://www.w3.org/1999/XSL/Transform" version="1.0">
<xsl:output method="xml" indent="yes"/>
<xsl:strip-space elements="*"/>

<xsl:template match="@*" >
    <xsl:element name="{name()}">
        <xsl:value-of select="."/>
    </xsl:element>
</xsl:template>

<xsl:template match="node()">
    <xsl:copy>
        <xsl:apply-templates select="@* | node()"/>
    </xsl:copy>
</xsl:template>

<xsl:template match="Item">
    <xsl:element name="{@Name}">
        <xsl:value-of select="."/>
    </xsl:element>
</xsl:template>

<xsl:template match="child::Item">
    <xsl:variable name="Parent" select="TEST"/>
        <xsl:element name="{$Parent}{@Name}">
            <xsl:value-of select="."/>
        </xsl:element>
</xsl:template>
</xsl:stylesheet>

我希望这有某种意义。我真的不想成为这方面的专家，因为我怀疑我是否会在很长一段时间内再次处理 XML 转换。我将不胜感激即将到来的任何帮助。

4

1 回答 1

0

您遇到的一个问题是匹配的模板Item

<xsl:template match="Item">
    <xsl:element name="{@Name}">
        <xsl:value-of select="."/>
    </xsl:element>
</xsl:template>

通过xsl:value-of在这里使用，它不会继续处理任何子节点，因此您不会对任何子Item元素进行任何匹配。您需要在xsl:apply-templates此处使用，以允许模板应用于子级

<xsl:template match="Item">
    <xsl:element name="{@Name}">
        <xsl:apply-templates />
    </xsl:element>
</xsl:template>

另一个问题是与匹配的其他模板有关child::Item。我认为这也将匹配父元素，因此有效地与其他模板Item具有相同的优先级。Item你可能需要用这个替换匹配：

<xsl:template match="Item[@Type='List']/Item">

最后，您Parent在此模板中定义变量，如下所示：

<xsl:variable name="Parent" select="TEST"/>

这将设置Parent为名为 的元素的值，而TEST您可能只需要“Test”的字面值。所以，你应该像这样定义它

<xsl:variable name="Parent" select="'TEST'"/>

试试这个 XSLT

<xsl:stylesheet xmlns:xsl="http://www.w3.org/1999/XSL/Transform" version="1.0">
<xsl:output method="xml" indent="yes"/>
<xsl:strip-space elements="*"/>

<xsl:template match="@*" >
    <xsl:element name="{name()}">
        <xsl:value-of select="."/>
    </xsl:element>
</xsl:template>

<xsl:template match="node()">
    <xsl:copy>
        <xsl:apply-templates select="@* | node()"/>
    </xsl:copy>
</xsl:template>

<xsl:template match="Item">
    <xsl:element name="{@Name}">
        <xsl:apply-templates />
    </xsl:element>
</xsl:template>

<xsl:template match="Item[@Type='List']/Item">
    <xsl:variable name="Parent" select="'TEST'"/>
        <xsl:element name="{$Parent}{@Name}">
            <xsl:value-of select="."/>
        </xsl:element>
</xsl:template>
</xsl:stylesheet>
于 2015-06-11T19:06:28.217 回答