2

我正在尝试在 Fortran 中生成两个一维数组的交集。

目的是使用这个交集作为掩码，maxloc以便我可以将一个数组中的最多几个元素拉到另一个数组中（类似于在最大堆中重复根删除的行为）。

目前，在将索引处的maxloc值插入第二个数组后，我只是将找到的索引处的值设置为零，但我希望 Fortran 有一个聪明的掩码相关方法。（在这个最大检索过程中保持原始数组完好无损也很好）

4

1 回答 1

6

我不太确定你的意思。如果要按索引比较两个数组，只需使用 即可==，如下所示：

INTEGER :: a(4), b(4)
LOGICAL :: inter(4)

a = (/ 1, 2, 3, 4 /)
b = (/ 4, 2, 3, 1 /)
inter = (a == b)  ! (/ F, T, T, F /)

这在技术上不是一个交集，但MASKinMAXLOC需要是一个数组LOGICAL，所以我认为这就是你想要的。

如果要测试 的值是否在 中a的任何位置b，则必须使用至少一个DO循环，我认为：

DO j = 1, size(a)
    inter(j) = any(a(j) == b)
END DO

如果你想找到最大的，比如 n 值，你可以使用这样的东西：

function largest(vars, n)
    implicit none
    integer, intent(in) :: n
    real, dimension(:), intent(in) :: vars
    real, dimension(n) :: largest
    integer :: i
    logical, dimension(size(vars)) :: m
    integer :: mloc

    m = .TRUE.

    do i = 1, n
       mloc = maxloc(vars, DIM=1, MASK=m)
       m(mloc) = .FALSE.
       largest(i) = vars(mloc)
    end do
    return
end function largest

基本上它使用一个全为真的掩码，然后每次将最高掩码恢复为假，以便在下一次迭代中不再获得该值。

当然，这是有序的 (n*size(var))，所以如果 n 很大，那么进行冒泡排序可能会更快，直到最后累积 n 个最大值，然后将它们拾取。

于 2015-05-15T05:20:08.117 回答