17

Functor在 Haskell 中，您可以派生Foldable并Traversable自动使用deriving. 但是，没有办法推导出Applicative。考虑到有一种明显的方式来定义一个Applicative实例（这相当于一个压缩的应用程序），没有任何方法可以启用deriving Applicative吗？

4

2 回答 2

18

不，这一点都不明显。比较以下Applicative实例：

  1. []
  2. ZipList
  3. Data.Sequence.Seq，其Applicative实例声明运行到数百行。
  4. IO
  5. (->) r
  6. parsec, attoparsec,regex-applicative中的解析器
  7. 包中的代理pipes。

这里几乎没有统一性，而且大多数情况都是不明显的。

正如David Young 评论的那样，[]和ZipList实例“最终都是两个不同的、同样有效Applicative的列表类型实例”。

于 2015-04-22T03:47:45.737 回答
7

现在DerivingVia已经发布（GHC-8.6 或更新版本），实际上可以在任何确定性数据类型Applicative的帮助下推导出！也就是说，任何只有一个变体的数据类型：DeriveGeneric

data Foo x = Foo x | Fe  -- This is non-deterministic and can't derive Applicative
data Bar x = Bar x x (Bar x) -- This is deterministic and can derive Applicative
data Baz x = Baz (Either Int x) [x] -- This is also ok, since [] and Either Int
                                    -- are both Applicative
data Void x -- This is not ok, since pure would be impossible to define.

要派生Applicative，我们首先需要定义一个用于通过泛型派生的包装器：

{-# LANGUAGE DerivingVia #-}
{-# LANGUAGE DeriveFunctor #-}
{-# LANGUAGE UndecidableInstances #-}
{-# LANGUAGE DeriveGeneric #-}
module Generically1 where

import GHC.Generics

newtype Generically1 f x = Generically1 { generically1 :: f x }

fromg1 :: Generic1 f => Generically1 f a -> Rep1 f a
fromg1 = from1 . generically1

tog1 :: Generic1 f => Rep1 f x -> Generically1 f x
tog1 = Generically1 . to1

instance (Functor f, Generic1 f, Functor (Rep1 f)) 
       => Functor (Generically1 f) where
  fmap f (Generically1 x) = Generically1 $ fmap f x

instance (Functor f, Generic1 f, Applicative (Rep1 f)) 
       => Applicative (Generically1 f) where
  pure = tog1 . pure
  f <*> x = tog1 $ fromg1 f <*> fromg1 x

instance (Functor f, Generic1 f, Monad (Rep1 f)) => Monad (Generically1 f) where
  return = pure
  m >>= f = tog1 $ fromg1 m >>= fromg1 . f

为了使用它，我们首先Generic1为我们的数据类型派生，然后Applicative通过我们的新Generically1包装器派生：

data Foo x = Foo x (Int -> x) (Foo x)
  deriving (Functor, Generic1)
  deriving (Applicative, Monad) via Generically1 Foo

data Bar x = Bar x (IO x)
  deriving (Functor, Generic1)
  deriving (Applicative, Monad) via Generically1 Bar

data Baz f x = Baz (f x) (f x)
  deriving (Show, Functor, Generic1)
  deriving (Applicative, Monad) via Generically1 (Baz f)

如您所见，我们不仅Applicative为我们的数据类型派生，而且还可以派生Monad。

这样做的原因是这些数据类型的表示Applicative和表示都有实例。参见例如产品类型 (:*:)。但是Sum 类型 (:+:)没有实例，这就是为什么我们不能为非确定性类型派生它的原因。MonadGeneric1Applicative

您可以通过在 GHCi 中Generic1编写来查看数据类型的表示。:kind! Rep1 Foo以下是上述类型表示的简化版本（不包括元数据）：

type family Simplify x where
  Simplify (M1 i c f) = Simplify f
  Simplify (f :+: g) = Simplify f :+: Simplify g
  Simplify (f :*: g) = Simplify f :*: Simplify g
  Simplify x = x

λ> :kind! Simplify (Rep1 Foo)
Simplify (Rep1 Foo) :: * -> *
= Par1 :*: (Rec1 ((->) Int) :*: Rec1 Foo)

λ> :kind! Simplify (Rep1 Bar)
Simplify (Rep1 Bar) :: * -> *
= Par1 :*: Rec1 IO

λ> :kind! forall f. Simplify (Rep1 (Baz f))
forall f. Simplify (Rep1 (Baz f)) :: k -> *
= forall (f :: k -> *). Rec1 f :*: Rec1 f

编辑：Generically1包装器也可在此处获得：https ://hackage.haskell.org/package/generic-data-0.7.0.0/docs/Generic-Data.html#t:Genericly1

于 2018-11-09T12:33:07.757 回答