4

我想通过 FFI 接口从 Haskell 提供 PETSc库（的一个子集），以便对用户隐藏内存和错误管理；

  • 使用如下所示的命令使用共享库构建 PETSc 3.5.3，测试套件成功运行
  • 准备了一个 .hsc 文件 #2，其中包含头文件导入、类型和两个示例外部函数接口
  • 准备了一个 Makefile #3 来自动化构建；make test1使用加载的模块传递并启动 GHCi。

由于该库在 MPI 和完全分布式数据结构支持的并行操作上大放异彩，因此不应期望在大多数操作期间使用 Haskell 进行大量数据流量（所有数据组装、计算和解除分配都应由库原语完成），但只能在“数据就绪”。PETSc 相关的 Haskell 函数大多在 IO monad 中有值，因为我们不能保证纯度（例如，返回的 C 错误代码可能因程序外部原因而变化）

  • unsafePerformIO将需要包装内存alloca和错误管理。这种思路正确吗？馊主意
  • 可以使用 GHC 编译的二进制文件执行mpirun吗？是的

我对所有建议和评论持开放态度。先感谢您

-- 注意：我们希望 GHC 生成mpirun可以执行的二进制文件：由于可以将选项从 GHC 命令行传递到带有-optl标志的链接器（在此处参考），因此有人建议我使用ghc -optl-static -lmpich. 我会尽快尝试添加更多关于此的内容。

1）配置命令：

$ ./configure --with-cc=gcc --with-cxx=g++ --with-fc=gfortran --with-shared-libraries=1 --download-mpich --download-fblaslapack

2) PETSC.hsc

{-# LANGUAGE CPP, ForeignFunctionInterface, EmptyDataDecls #-}
module PETSc where

import Foreign
import Foreign.Ptr
import Foreign.C.Types
import Foreign.C.String

#include <petscksp.h>
#include <petscsys.h>

newtype PetscErrCode = PetscErrCode {unPetscErrCode :: CInt} deriving (Eq, Show)
newtype PetscInt = PetscInt {unPetscInt :: CInt} deriving (Eq, Show)

data Petsc
-- PetscErrorCode PetscInitialize(int *argc,char ***args,const char file[],const char help[])
foreign import ccall unsafe "petscsys.h PetscInitialize"
  c_petscInitialize :: Ptr CInt -> Ptr (Ptr CString) -> CString -> CString -> IO PetscErrCode

-- PetscErrorCode PetscFinalize(void)
foreign import ccall unsafe "petscsys.h PetscFinalize"
  c_petscFinalize :: IO PetscErrCode

3) 生成文件

PETSC_DIR_ARCH = ${PETSC_DIR}/arch-darwin-c-debug

PETSc.hs: 
    hsc2hs PETSc.hsc -I ${PETSC_DIR}/include -I ${PETSC_DIR_ARCH}/include

test1: PETSc.hs 
    ghci -dynamic PETSc.hs -L${PETSC_DIR_ARCH}/lib
4

1 回答 1

2

雄心勃勃！我很想使用 C2HS 而不是 hsc2hs，因为它可以为您生成一些外国进口的样板。（我是 C2HS 的维护者，所以你可以对我说的话持保留态度！）

例如，您可以PetscInitialize像PetscFinalize这样绑定：

-- This is in PETSc.chs
module PETSc (initialize, finalize) where

import Foreign
import Foreign.Ptr
import Foreign.C.Types
import Foreign.C.String
import System.Environment (getArgs)

#include <petscksp.h>
#include <petscsys.h>

-- Marshalling helpers for PETSc error codes.

newtype ErrCode = ErrCode { unErrCode :: Int }
                deriving (Eq, Show)

convErrCode :: CInt -> ErrCode
convErrCode = ErrCode . fromIntegral

{#typedef PetscErrorCode CInt#}
{#default out `ErrCode' [PetscErrorCode] convErrCode#}


-- Marshalling helpers for "char ***" argument to PetscInitialize.

withCStrings :: [String] -> ([CString] -> IO a) -> IO a
withCStrings ss f = case ss of
  [] -> f []
  (s:ss') -> withCString s $ \cs -> do
    withCStrings ss' $ \css -> f (cs:css)

withCStringArray :: [String] -> (Ptr CString -> IO a) -> IO a
withCStringArray ss f = withCStrings ss $ \css -> withArray css f

withCStringArrayPtr :: [String] -> (Ptr (Ptr CString) -> IO a) -> IO a
withCStringArrayPtr ss f = withCStringArray ss $ \css -> with css f


-- Low-level function hooks.

{#fun PetscInitialize as internal_initialize
    {`Int', withCStringArrayPtr* `[String]', `String', `String'}
    -> `ErrCode'#}
{#fun PetscFinalize as finalize {} -> `ErrCode'#}


-- Better API for initialization.

initialize :: String -> String -> IO ErrCode
initialize file help = do
  args <- getArgs
  internal_initialize (length args) args file help

对于 C2HS，这实际上是一个非常困难的例子，因为管理char ***参数的编组PetscInitialize有点尴尬，但你明白了。大多数其他编组案例应该更简单——处理指针和数组非常容易，编组 C 字符串也是如此。（如果您决定使用它，我很乐意帮助您解决 C2HS 问题。）

一旦你有了这个，你可以这样称呼它：

-- This is Tst.hs or something...
module Main where

import PETSc

main :: IO ()
main = do
  res1 <- initialize "" ""
  print res1
  res2 <- finalize
  print res2

还不是很有用，但这是一个开始！像这样编译它：

c2hs -C -I/opt/petsc/arch-linux2-cxx-opt/include PETSc.chs
ghc --make Tst.hs PETSc.hs -L/opt/petsc/arch-linux2-cxx-opt/lib/ -lpetsc

（根据需要调整路径，obvs）。

要回答您的其他问题：

  • 不要使用unsafePerformIO，除非你真的确定你调用的函数是“有效纯的”——PetscInitialize当然不满足那个条件。如果您不想将所有内容直接包含在monad 中，则可以将PETScmonad 作为一种受限包装器来编写，但是您所做的大部分 PETSc 方式实际上都在monad 中，因为您要通过调用 API 函数来设置内部 PETSc 状态，你需要在你的 Haskell 函数类型中捕捉到这种有效性。IOIOIO

  • 运行 GHC 生成的二进制文件mpirun应该不是问题。

我也不会写makefile。您应该可以使用 Cabal 轻松完成这一切！

于 2015-03-29T16:56:42.997 回答