2

客户端应用程序和 DataSnap 服务器的原型。我想将TObjectList从服务器传输到客户端。

这是可行的，但我传达的所有对象都保留在服务器和客户端的内存中。

我究竟做错了什么 ？

生命周期 = 会话

TPessoa 对象实现了另一个类（TConta）的 TObjectList：

   TConta = class(TObject)
  private
    FBanco: string;
    FConta: Integer;
    FAgencia: Integer;
    procedure SetAgencia(const Value: Integer);
    procedure SetBanco(const Value: string);
    procedure SetConta(const Value: Integer);
   published
     property Banco : string read FBanco write SetBanco;
     property Agencia : Integer read FAgencia write SetAgencia;
     property Conta : Integer read FConta write SetConta;
   end;

   TContasCollection = TObjectList<TConta>;

   TPessoa = class(TObject)
  private
    FContas: TContasCollection;
    FId: Integer;
    FNome: string;
    procedure SetContas(const Value: TContasCollection);
    procedure SetId(const Value: Integer);
    procedure SetNome(const Value: string);
   published
     property Id : Integer read FId write SetId;
     property Nome : string read FNome write SetNome;
     property Contas : TContasCollection read FContas write SetContas;
   end;

ServerMetodsUnit 中的公共方法：

function getPessoa(id : Integer) : Tpessoa;

function TServerMethods1.getPessoa(id: Integer): Tpessoa;
begin
  result := Tpessoa.create;
  result.id := id;
  result.nome := 'NoName';
  result.contas := getContas;
end;

function TServerMethods1.getContas: TContasCollection;
var conta : TConta;
begin
  conta := TConta.Create;
  conta.Banco := 'CEF';
  conta.Agencia := 1;
  conta.Conta := 123;

  Result := TContasCollection.Create();
  Result.Add(conta);
end;

客户：

procedure TForm2.btn1Click(Sender: TObject);
var pessoa : Tpessoa;
begin
  pessoa := ClientModule1.ServerMethods1Client.getPessoa(1);
  mmo1.Lines.Add(pessoa.Nome);
  mmo1.Lines.Add(pessoa.Contas[0].Banco);
end;

结果正确，但是在服务器和客户端中显示内存泄漏消息（System.ReportMemoryLeaksOnShutdown := true;）：

Unexpected Memory Leak 发生了意外的内存泄漏。意外的小块泄漏是：

1 - 12 字节：TMoveArrayManager x 1，未知 x 1 13 - 20 字节：TConta x 1，UnicodeString x 1 37 - 44 字节：TObjectList x 1

如何解决这种内存泄漏而不影响服务？

4

1 回答 1

1

发生内存泄漏是因为您没有释放正在创建的对象。

对于在客户端部分开始，您正在创建pessoa对象btn1Click作为局部变量，但您没有释放它。

procedure TForm2.btn1Click(Sender: TObject);
var pessoa : Tpessoa;
begin
  pessoa := ClientModule1.ServerMethods1Client.getPessoa(1);
  mmo1.Lines.Add(pessoa.Nome);
  mmo1.Lines.Add(pessoa.Contas[0].Banco);
  pessoa.Free; // you are no longer using pessoa object after that point so release it
end;

TPessoa类有FContas我们看不到如何创建或释放的字段，也许你只是省略了代码，也许它根本不存在。反正FContas也已经在某个时候发布了。如果TPessoa类是FContas字段的所有者（看起来应该是），那么您必须将析构函数添加到TPessoa您可以释放FContas集合的类中。

FContas是TObjectList默认情况下拥有添加的对象，并且这些对象将在释放时FContas被释放。

FContas方法中的对象也可能泄漏SetContas，但是在不知道该代码的外观的情况下，很难判断它是否泄漏。

TPessoa = class(TObject)
....
public
  destructor Destroy; override;
end;

destructor TPessoa.Destroy; 
begin
  FContas.Free;
  inherited;
end;

procedure SetContas(const Value: TContasCollection);
begin
  FContas.Free; // release old FContas collection if there is one
  FContas := Value; // reference FContas grabs ownership here 
end;

基本上，您创建的每个对象都必须在不再需要后将其释放，除非有其他对象实例会获取该对象的所有权并为您执行此操作，就像这样做一样TObjectList。

上面的代码假定该FContas字段是它所持有的集合的所有者，重要的是不要抓住该引用并将其持有超过它的所有者对象 ( TPessoa) 实例的生命周期。

例如，以下代码将是错误的：

procedure TForm2.btn1Click(Sender: TObject);
var 
  pessoa : Tpessoa;
  contas: TContasCollection;
begin
  pessoa := ClientModule1.ServerMethods1Client.getPessoa(1);
  contas := pessoa.Contas;
  pessoa.Free; // <-- after that point contas points to released object
  mmo1.Lines.Add(contas[0].Banco); // <-- dangling pointer use
end;

还有一些引用计数的对象实例在对它们的最后一次引用超出范围后自动释放（通常是TInterfacedObject类的后代），但管理这些是完全不同的故事。您在这里没有使用它们，我只是为了完整性而提及它们。

于 2015-03-23T18:00:15.430 回答