perl - 在 Perl 中使用 XML::Simple 检索数据

Question

我创建了以下XML用于检索数据的文件。

输入：

<?xml version="1.0" encoding="UTF-8" standalone="no"?>
<ExecutionLogs>
    <category cname='Condition1' cid='T1'>
        <log>value1</log>
        <log>value2</log>
        <log>value3</log>
    </category>
    <category cname='Condition2' cid='T2'>
        <log>value4</log>
        <log>value5</log>
        <log>value6</log>
    </category>
        <category cname='Condition3' cid='T3'>
        <log>value7</log>
    </category>
</ExecutionLogs>

我想要如下的输出，

Condition1 -> value1,value2,value3
Condition2 -> value4,value5,value6
Condition3 -> value7

我试过下面的代码，

use strict;
use XML::Simple;
my $filename = "input.xml";
$config = XML::Simple->new();
$config = XMLin($filename);
@values = @{$config->{'category'}{'log'}};

请帮助我。提前致谢。

Answer 1

一种使用 XML::Twig 的方法：

#!/usr/bin/perl

use strict;
use warnings;

use XML::Twig;

XML::Twig->new( twig_handlers => { 
                   category => sub { print $_->att( 'cname'), ': ', 
                                           join( ',', $_->children_text( 'log')), "\n";
                               },
                },
              )

         ->parsefile( 'my.xml');

每次category解析元素时都会调用处理程序。$_是元素本身。

Answer 2

我会做什么：

use strict; use warnings;
use XML::Simple;
my $config = XML::Simple->new();
$config = XMLin($filename, ForceArray => [ 'log' ]);
#   we want an array here  ^---------------------^ 

my @category = @{ $config->{'category'} };
#              ^------------------------^
# de-reference of an ARRAY ref  

foreach my $hash (@category) {
    print $hash->{cname}, ' -> ', join(",", @{ $hash->{log} }), "\n";
}

输出

Condition1 -> value1,value2,value3
Condition2 -> value4,value5,value6
Condition3 -> value7

笔记

ForceArray => [ 'log' ]是否可以确保处理相同的类型，{category}->[@]->{log] 除非我们尝试取消引用ARRAYlast 的字符串上的 ref "Condition3"。

检查XML::Simple#ForceArray

和

• perldoc perlreftut
• perldoc 参考
• perldoc perlref