6

这是否意味着我不能在 delphi 2007 和 2009 之间共享表单？

4

5 回答 5

15

DoubleBuffered 在 TWinControl 中已有一段时间了。Delphi 2009 的不同之处在于它是现在发布的。如果您只能忽略错误（而不是使属性工作），那么这是一个可能的解决方案：

unit Delphi2009Form;

interface

uses
  Windows, Classes, SysUtils, Controls, Forms;

type
{$IFDEF VER200}
  TDelphi2009Form = class(TForm);
{$ELSE}
  TDelphi2009Form = class(TForm)
  private
    procedure ReaderError(Reader: TReader; const Message: string; var Handled: Boolean);
  protected
    procedure ReadState(Reader: TReader); override;
  end;

  TReaderErrorProc = procedure(const Message: string);

var
  ReaderErrorProc: TReaderErrorProc = nil;
{$ENDIF}

implementation

{$IFNDEF VER200}
type
  THackReader = class(TReader);

procedure TDelphi2009Form.ReaderError(Reader: TReader; const Message: string; var Handled: Boolean);
begin
  with THackReader(Reader) do
    Handled := AnsiSameText(PropName, 'DoubleBuffered') or AnsiSameText(PropName, 'ParentDoubleBuffered');
  if Handled and Assigned(ReaderErrorProc) then
    ReaderErrorProc(Message);
end;

procedure TDelphi2009Form.ReadState(Reader: TReader);
begin
  Reader.OnError := ReaderError;
  inherited ReadState(Reader);
end;
{$ENDIF}

end.

然后将项目中的表单声明更改为从 TDelphi2009Form 继承，例如：

type
  TFormMain = class(TDelphi2009Form)
  ...

这将在运行时起作用 - 属性错误将被忽略。为了让它在设计时也能工作，创建一个仅设计包，将 designide.dcp 添加到它的 requires 子句中，并添加以下单元：

unit Delphi2009FormReg;

interface

uses
  Delphi2009Form;

procedure Register;

implementation

uses
  DesignIntf, DesignEditors, ToolsAPI;

procedure ShowReaderError(const Message: string);
begin
  with BorlandIDEServices as IOTAMessageServices do
    AddTitleMessage(Message);
end;

procedure Register;
begin
  RegisterCustomModule(TDelphi2009Form, TCustomModule);
  ReaderErrorProc := ShowReaderError;
end;

initialization

finalization
  ReaderErrorProc := nil;

end.

在 Delphi 2007 IDE 中安装包，在 IDE 中打开表单时，DoubleBuffered 和 ParentDoubleBuffered 属性的属性错误将被自动忽略。当您在 Delphi 2007 中保存表单时，属性的值将丢失，因此您应该在代码中初始化它们。

编辑：我添加了代码以将阅读器错误消息输出到 IDE 消息窗口：

IDE 错误消息

于 2008-11-08T20:32:21.967 回答
6

是的。除非您从 DFM 中删除未在 Delphi 2007 中发布的属性，否则这是不可能的。

于 2008-11-07T12:26:48.093 回答
4

Delphi 项目一直非常容易移植到新版本。您必须更加小心，但是将当前代码与旧编译器一起使用也非常简单。我在 Delphi 2005/2006/2007 中维护了其他人仍然需要在 Delphi 6 和 7 中使用的代码。

如果您从 DFM 中删除不兼容的属性，它们应该可以在旧版本中正常工作，而不会在 Delphi 2009 中弄乱它们。最大的例子是 Delphi 2006 中引入的显式*属性。我有一个自制的“DFM 洗涤器”，可以去除这些出去。请记住，这些属性的存在是有原因的，因此您应该只清理那些打算向后兼容的属性。

您还可以考虑投资静态代码分析工具，例如 CodeHealer 或 Pascal Analyzer。除了指出问题（尤其是 CodeHealer）并帮助您清理代码之外，您还可以选择要分析的 Delphi 版本，从而更容易找到除 DFM 属性之外的不兼容性。它们可以作为构建过程的一部分自动化。

只是一个注释。共享源代码，但为每个版本保留单独的项目。这在 Delphi 2007 和 Delphi 2009 之间尤其重要。较新的 .dproj 文件使用相同的扩展名，但与 Delphi 2007 不兼容。您也可能遇到资源不兼容的问题。

于 2008-11-07T13:06:02.460 回答
2

每个表单都有一个 dfm 文件，其中包含表单及其组件的属性设置。某些属性值具有默认值，因此如果保留默认值，则不会存储它们。只是做了一个小测试：

  • 2009年创建表格
  • 添加几个标准控件
  • 保存
  • 在 2006 年打开它（对不起，这台电脑上没有 2007 年）

它在没有消息的情况下工作。但也许你没那么幸运。

使用 Delphi，在版本之间共享数据通常有点麻烦。升级的可能性很大，但降级很麻烦。所以我建议不要在不同版本之间共享表单文件。

据我所知，不可能在 dfm 文件中添加条件定义。但是话又说回来，我们真的想要那个……我更喜欢一种忽略未知属性的机制。

于 2008-11-07T12:33:42.917 回答
2

您可以安全地在表单的 OnCreate 方法中的代码中添加属性，并在它们周围包裹一个 {$IFDEF VER200} // NEW PROPERTIES {$ENDIF}。您可以将 DoubleBuffered 留在 ifdefs 之外，就像在 Delphi 2007 中一样，只是对属性检查器不可用。

您只需要担心您设置的与默认值不同的属性。对于双缓冲，如果设置为 true，您只需要担心这一点。

在 Delphi 2007 中加载 Delphi 2009 表单时，您将收到一个警告，指出某个属性将被破坏，只需记下这些属性，因为这些是您需要处理的属性。

我正在使用这种方法将我的代码从 Delphi 2006 迁移到 Delphi 2009。我的大多数项目都包含几个共享单元，并且必须在 Delphi 2006 中编译发布版本，在 Delphi 2009 中编译“下一个”版本。我还大量使用 {$IFDEF UNICODE} 定义我需要确保字符串是宽字符串或 ansistring，具体取决于例程。

于 2008-11-07T13:49:33.077 回答