1

下面的数码显微照片函数尝试通过获取图像行的子行中相邻像素的差异来创建图像。第一个像素被替换为由此创建的子行的差值结果的平均值。

例如，如果输入图像是 8 像素宽和 1 行高并且子行大小是 4 - In_img = {8,9,2,4,9,8,7,5} 那么输出图像将是 - Out_img = {均值(8,9,2,4)=5.75,9-8=1,2-9=-7,4-2=2,均值(9,8,7,5)=7.25,8-9= -1,7-8=-1,5-7=-2}

在此处输入图像描述

当我运行此脚本时，第一行的第一个像素是正确的，但其余像素不正确。当我将循环限制设置为只有一个子行和一个行即 x=1 和 y=1 时，脚本可以正常工作。

关于可能发生的事情或脚本可能有什么问题的任何想法？

测试图像在这里，结果在这里。

    // Function to compute the standard deviation (sigma n-1) of an image, or
    // a set of values passed in as pixel values in an image. The
    // number of data points (n) the mean and the sum are also returned.
    // version:20080229
    // D. R. G. Mitchell, adminnospam@dmscripting.com (remove the nospam to make this email address work)
    // v1.0, February 2008
    void StandardDeviation(image arrayimg, number &stddev, number &n, number &mean, number &sum)
    {
        mean=mean(arrayimg)
        number xsize, ysize
        getsize(arrayimg,xsize, ysize)
        n=xsize*ysize
        sum=sum(arrayimg)
        image imgsquared=arrayimg*arrayimg
        number sumofvalssqrd=sum(imgsquared)
        stddev=sqrt(((n*sumofvalssqrd)-(sum*sum))/(n*(n-1)))
    }

image getVectorImage(image refImage, number rowsize)
{
    number fh, fv, fhx
    getsize(refImage, fh, fv)

    fhx=trunc(fh/rowsize)

    //result("ByteSize of refimage = "+refImage.ImageGetDataElementByteSize()+"\n")
    //create image to save std of each row of the ref image.  
    //The std values are saved as pixels of one row.  The row size is same as number of rows.
    //use fhx*rowsize for the new imagesize as fhx is truncated value.
    image retImage:=RealImage("",4,fhx*rowsize,fv)
    image workImage=slice1(refImage,rowsize+1,0,0,0,rowsize-1,1)

    number stddev,nopix,mean,sum

    for ( number y=0;y<fv;y++)
        {
        for (number x=0;x<fhx;x++) 
            {
                //result ("x,y="+x+","+y+"; fhx="+fhx+"; rowsize="+rowsize+"\n")
                workImage=slice1(refImage,x*rowsize+1,y,0,0,rowsize-1,1)-slice1(refImage,x*rowsize,y,0,0,rowsize-1,1)
                showimage(workImage)
                StandardDeviation(workImage,stddev,nopix,mean,sum )
                retImage[y,x*rowsize+1,y+1,x*rowsize+rowsize]=workImage
                retImage[y,x]=mean
                result("mean @ row "+y+" = "+mean+"\n")
            }
        }

    return retImage
}
showimage(getVectorImage(getfrontimage(),rowsize))
4

2 回答 2

1

我在你的脚本中有一些观察：

  • 您可以使用以下方法轻松地从任何图像中获取这些数字，而不是定义的获取图像的均值/总和/标准差/nimg的方法：

    意思是： number m = mean( img )

    和： number s = sum( img )

    标准开发：number sd = sqrt( variance( img ) )

    像素：number n = sum( 0 * img + 1 )

  • 如果您想获得图像与图像“移位一”的差异，则不必遍历行/列，而是可以直接使用slice2()命令；使用icol和irow的 [ ] 符号；或命令 就offset()我个人而言，我更喜欢slice2()命令。

如果我想要一个脚本，它可以为我提供每行与其后一行之间差异的标准偏差，即所有 y < sizeY 的 stdDev( row_(y) - row_(y+1) )，我的脚本将是：

Image img :=  GetFrontImage()
number sx,sy
img.GetSize(sx,sy)
number dy = 1

Image dif = img.Slice2(0,0,0, 0,sx,1, 1,sy-1,1 ) - img.Slice2(0,dy,0, 0,sx,1, 1,sy-1,1)
Image sDevs := RealImage( "Row's stDev", 4, sy-1 )
for ( number y=0; y<sy-1; y++ )
    sDevs[y,0] = SQRT( Variance( dif.Slice1(0,y,0, 0,sx,1) ) )

sDevs.ShowImage()

这就是你想要达到的目标吗？如果没有，请编辑您的问题以进行澄清。

于 2014-11-30T17:16:55.717 回答
1

编辑后，我了解到您想要执行以下操作：

例子

并且这应该对图像的每一行单独执行。

以下脚本执行此操作。（下面的解释。）

image Modify( image in, number subsize )
{
    // Some checking
    number sx,sy
    in.GetSize(sx,sy)
    if ( 0 != sx%subsize )
        Throw( "The image width is not an integer multiplication of the subsize." )

    // Do the means...
    number nTile = sx/subsize
    image meanImg := RealImage( "Means", 4, nTile , sy )
    meanImg = 0
    for ( number i=0; i<subsize; i++ )
        meanImg += in.Slice2( i,0,0, 0,nTile,subsize, 1,sy,1 )

    meanImg *= 1/subsize

    // Do the shifted difference
    image dif := RealImage( "Diff", 4, sx-1, sy )
    dif = in.slice2( 1,0,0, 0,sx-1,1, 1,sy,1) - in.slice2( 0,0,0, 0,sx-1,1, 1,sy,1) 

    // Compile the result
    image out := in.ImageClone()
    out.SetName( in.getName() + "mod" )

    out.slice2( 1,0,0, 0,sx-1,1, 1,sy,1 ) = dif
    out.slice2( 0,0,0, 0,nTile,subsize, 1,sy,1 ) = meanImg

    return out
}


number sx = 8, sy = 4
image img := RealImage( "test", 4, 8, 4 )
img = icol*10 + trunc( Random()*10 )

img.ShowImage()
Modify(img,4).ShowImage()

一些解释：

  • 你想在图像中做两件不同的事情，所以你必须小心不要覆盖你随后将用于计算的像素数据！图像是逐像素处理的，因此如果您首先计算平均值并将其写入第一个像素，则第二个像素的评估将是“9”与刚刚存储的平均值（不是原始“8” ）。因此，您必须拆分计算并使用“缓冲”副本。

  • 该slice2命令非常方便，因为它允许在采样时定义步长。您可以使用它直接处理深灰色像素。

  • 请注意图像表达:=之间的区别。=第一个是内存分配：

    • A := B 表示 A 现在与 B 的内存位置相同。A 基本上是 B 的另一个名称。

    • A = B 表示 A 获取 B 的值（复制）。A 和 B 是两个不同的内存位置，只有值被复制。

于 2014-12-02T13:24:13.450 回答