linux - Perl 编写 excel 以创建包含各种工作表中的公式的单元格的图表

Question

是否可以使用 perl 的 Excel::Writer::XLSX 模块并使用包含公式的单元格创建图表？

这是我正在做的事情：

1) 创建了一个包含多个工作表的 xlsx 文件 - 没有问题

2) 在一个工作表中使用其他工作表中的常量值创建图表 - 没有问题

3）创建了一个包含公式的单元格的工作表 - 没有问题（我可以在输出 xlsx 中看到值）

4）尝试从＃3创建一个图表，即使我可以看到上面提到的值，它也是空的

请帮忙！！！

Answer 1

第 4 项应该有效。这是一个例子：

#!/usr/bin/perl

use strict;
use warnings;
use Excel::Writer::XLSX;

my $workbook   = Excel::Writer::XLSX->new( 'chart_column.xlsx' );
my $worksheet1 = $workbook->add_worksheet();
my $worksheet2 = $workbook->add_worksheet();
my $bold       = $workbook->add_format( bold => 1 );

# Add the worksheet data that the charts will refer to.
my $headings = [ 'Number', 'Batch 1', 'Batch 2' ];
my $data = [
    [ 2,  3,  4,  5,  6,  7 ],
    [ 10, 40, 50, 20, 10, 50 ],
    [ 30, 60, 70, 50, 40, 30 ],
];

# Add the data to worksheet2.
$worksheet2->write( 'A1', $headings, $bold );
$worksheet2->write( 'A2', $data );


# Add formulas in worksheet1 to refer to the data in worksheet2.
for my $row (1 .. 7) {
    $worksheet1->write( $row -1, 0, '=Sheet2!A' . $row );
    $worksheet1->write( $row -1, 1, '=Sheet2!B' . $row );
    $worksheet1->write( $row -1, 2, '=Sheet2!C' . $row );
}


# Create a new chart object. In this case an embedded chart.
my $chart = $workbook->add_chart( type => 'column', embedded => 1 );

# Configure the series.
$chart->add_series(
    name       => '=Sheet1!$B$1',
    categories => '=Sheet1!$A$2:$A$7',
    values     => '=Sheet1!$B$2:$B$7',
);
$chart->add_series(
    name       => '=Sheet1!$C$1',
    categories => '=Sheet1!$A$2:$A$7',
    values     => '=Sheet1!$C$2:$C$7',
);

# Insert the chart into the worksheet (with an offset).
$worksheet1->insert_chart( 'D2', $chart, 25, 10 );

$workbook->close();

__END__

这是输出：

所以它看起来像在 Excel 中工作。但是，它可能不适用于某些不计算公式结果的电子表格应用程序。