5

我是 SSRS 部署的新手，我一直在四处寻找，但找不到适用于我情况的确切场景。我在 SSRS 2012 的不同子文件夹中部署了多个报告。例如：

  • 销售/销售报告1
  • 销售/销售报告2
  • 财务/finReport1
  • 财务/finReport2
  • 杂项/杂项报告1
  • 杂项/杂项报告2

由于有时 SSRS 不喜欢被覆盖的报告文件，我想在部署任何新报告之前删除实例中的所有报告文件。我可以通过使用 rs.exe 调用此脚本来成功删除文件夹及其内容：

Public Sub Main()  

  rs.Credentials = System.Net.CredentialCache.DefaultCredentials  

  Dim bh As New BatchHeader()  

  bh.BatchID = rs.CreateBatch()  

  rs.BatchHeaderValue = bh 

   'Delete all reports from Main Folder and sub folders.Note:The Folders will be deleted also.  
   'If do not want to delete the folder, we could use rs.CreateFolder(“Folder name”, “/Main     Folder”, “nothing”) to create a new one with nothing.  

 rs.DeleteItem("/Sales")
 rs.DeleteItem("/Finance")
 rs.DeleteItem("/Misc") 

   'Delete all reports from a sub folder, and delete the sub folder  
   'rs.DeleteItem("/Main Folder/Sub Folder ")  

  rs.BatchHeaderValue = bh       

  ' Delete folders using batch header.  

  Try  

     rs.ExecuteBatch()  
     Console.WriteLine("Folders deleted successfully.")  

  Catch e As SoapException  
     Console.WriteLine(e.Detail.InnerXml.ToString())  

  Finally  
      rs.BatchHeaderValue = Nothing 

  End Try  

End Sub 'Main

问题在于，如果这些文件夹中的任何一个不存在，脚本就会停止。我正在尝试确定处理此问题的最佳方法。最好的方法是清空文件夹并将它们留在那里，还是找到一种方法来忽略错误并继续？

根据答案，我将如何在此脚本中调用它？

4

2 回答 2

3

您可以通过遍历父文件夹中的项目并查找具有预期名称的任何子文件夹来检查该文件夹是否存在。然后，仅当它存在时，才尝试删除该文件夹。

这应该可以解决您的问题，即您只有在知道它存在时才删除它。

您的代码可能类似于：

Public Sub Main()

    rs.Credentials = System.Net.CredentialCache.DefaultCredentials

    DeleteFolder("Sales")
    DeleteFolder("Finance")

End Sub

Public Sub DeleteFolder(ByVal folderName As String)

    Dim items() as CatalogItem  
    Dim item As CatalogItem
    Dim folderExists As Boolean = False

    items = rs.ListChildren("/", False)

    For Each item In items

        If item.TypeName = "Folder" And item.Name.Equals(folderName)

            folderExists = True

        End If

    Next

    If folderExists

        Try

            rs.DeleteItem("/" + folderName)
            Console.WriteLine("Deleted folder {0}", folderName)

        Catch e As Exception

            Console.WriteLine(e.Message)

        End Try     

    Else

        Console.WriteLine("Folder {0} does not exist", folderName)

    End If

End Sub

这/仅检查文件夹 - 您可能需要调整以匹配您的设置。

于 2014-09-24T10:07:23.973 回答
1

我完成了接受的支持答案：

  • 删除不在根目录下的文件夹
  • 仅删除文件夹的内容
  • 支持 SSRS 2017
  • 也可以作为 rss 文件在 rs.exe 工具中使用

所以代码是：

Dim TargetRSFolder As String = vTARGETRSFOLDER 
Dim TargetRSRoot As String = vTARGETROOT
Dim DeleteContentOnly As Boolean = vDeleteContentOnly 

Public Sub Main()

    rs.Credentials = System.Net.CredentialCache.DefaultCredentials

    DeleteFolder(TargetRSFolder)

End Sub

Public Sub DeleteFolder(ByVal folderName As String)

    Dim items() as CatalogItem  
    Dim item As CatalogItem
    Dim folderExists As Boolean = False
    Dim path As String = TargetRSRoot

    IF (path = "")
         path = "/"
    END IF


    items = rs.ListChildren(path, False)

    For Each item In items

        If item.Type.ToString() = "Folder" And item.Name.ToLower() = folderName.ToLower()

            folderExists = True

        End If

    Next

    If folderExists

        Try

            IF (DeleteContentOnly = True)   
                    items = rs.ListChildren(TargetRSRoot + "/" + folderName, False)
                     For Each item In items
                          rs.DeleteItem(item.Path)   
                     Next
                     Console.WriteLine("Deleted folder's contetnts : {0}", folderName)
            ELSE
                   rs.DeleteItem(TargetRSRoot + "/" + folderName)
                   Console.WriteLine("Deleted folder :{0}", folderName)
            END IF

        Catch e As Exception

            Console.WriteLine(e.Message)

        End Try     

    Else

        Console.WriteLine("Folder {0} does not exist", folderName)

    End If

End Sub

假设我们在文件中有上述代码DeleteServerReportFolder.rss，并且我们有"/bb/cc"文件夹。

  1. 仅删除cc文件夹的内容：

rs.exe -i DeleteServerReportFolder.rss -s http://server2/ReportServer2017 -v vTARGETRSFOLDER=cc -v vTARGETROOT=/bb -v vDeleteContentOnly=true

  1. 完全删除bb文件夹：

rs.exe -i DeleteServerReportFolder.rss -s http://server2/ReportServer2017 -v vTARGETRSFOLDER=bb -v vTARGETROOT= -v vDeleteContentOnly=false

于 2019-01-07T12:23:26.663 回答